Debian Codegraph @

src/csky/sysv.S

raw
1 /* -----------------------------------------------------------------------
2 sysv.S
3
4 CSKY Foreign Function Interface
5
6 Permission is hereby granted, free of charge, to any person obtaining
7 a copy of this software and associated documentation files (the
8 ``Software''), to deal in the Software without restriction, including
9 without limitation the rights to use, copy, modify, merge, publish,
10 distribute, sublicense, and/or sell copies of the Software, and to
11 permit persons to whom the Software is furnished to do so, subject to
12 the following conditions:
13
14 The above copyright notice and this permission notice shall be included
15 in all copies or substantial portions of the Software.
16
17 THE SOFTWARE IS PROVIDED ``AS IS'', WITHOUT WARRANTY OF ANY KIND,
18 EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
19 MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
20 NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
21 HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
22 WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
23 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
24 DEALINGS IN THE SOFTWARE.
25 ----------------------------------------------------------------------- */
26
27 #define LIBFFI_ASM
28 #include <fficonfig.h>
29 #include <ffi.h>
30
31 .macro CSKY_FUNC_START name
32 .text
33 .align 2
34 .globl \name
35 .type \name, @function
36 \name:
37 .endm
38
39 #ifdef __CSKYABIV2__
40
41 /*
42 * a0: fn
43 * a1: &ecif
44 * a2: cif->bytes
45 * a3: fig->flags
46 * sp+0: ecif.rvalue
47 */
48 CSKY_FUNC_START ffi_call_SYSV
49 /* Save registers */
50 .cfi_startproc
51 subi sp, 28
52 .cfi_def_cfa_offset 28
53 stw a0, (sp, 0x0)
54 .cfi_offset 0, -28
55 stw a1, (sp, 0x4)
56 .cfi_offset 1, -24
57 stw a2, (sp, 0x8)
58 .cfi_offset 2, -20
59 stw a3, (sp, 0xC)
60 .cfi_offset 3, -16
61 stw l0, (sp, 0x10)
62 .cfi_offset 4, -12
63 stw l1, (sp, 0x14)
64 .cfi_offset 5, -8
65 stw lr, (sp, 0x18)
66 .cfi_offset 15, -4
67
68 mov l0, sp
69 .cfi_def_cfa_register 4
70
71 /* Make room for all of the new args. */
72 subu sp, sp, a2
73
74 /* Place all of the ffi_prep_args in position */
75 mov a0, sp
76 /* a1 already set */
77
78 /* Call ffi_prep_args(stack, &ecif) */
79 jsri ffi_prep_args
80
81 /* move first 4 parameters in registers */
82 ldw a0, (sp, 0x0)
83 ldw a1, (sp, 0x4)
84 ldw a2, (sp, 0x8)
85 ldw a3, (sp, 0xC)
86
87 /* and adjust stack */
88 subu lr, l0, sp /* cif->bytes == l0 - sp */
89 cmphsi lr, 16
90 movi l1, 16
91 movt lr, l1
92 addu sp, sp, lr
93
94 ldw l1, (l0, 0) /* load fn() in advance */
95
96 /* call (fn) (...) */
97 jsr l1
98
99 /* Remove the space we pushed for the args */
100 mov sp, l0
101
102 /* Load r2 with the pointer to storage for the return value */
103 ldw a2, (sp, 0x1C)
104
105 /* Load r3 with the return type code */
106 ldw a3, (sp, 0xC)
107
108 /* If the return value pointer is NULL, assume no return value. */
109 cmpnei a2, 0
110 bf .Lepilogue
111
112 cmpnei a3, FFI_TYPE_STRUCT
113 bf .Lepilogue
114
115 /* return INT64 */
116 cmpnei a3, FFI_TYPE_SINT64
117 bt .Lretint
118 /* stw a0, (a2, 0x0) at .Lretint */
119 stw a1, (a2, 0x4)
120
121 .Lretint:
122 /* return INT */
123 stw a0, (a2, 0x0)
124
125 .Lepilogue:
126 ldw a0, (sp, 0x0)
127 ldw a1, (sp, 0x4)
128 ldw a2, (sp, 0x8)
129 ldw a3, (sp, 0xC)
130 ldw l0, (sp, 0x10)
131 ldw l1, (sp, 0x14)
132 ldw lr, (sp, 0x18)
133 addi sp, sp, 28
134 rts
135 .cfi_endproc
136 .size ffi_call_SYSV, .-ffi_call_SYSV
137
138
139 /*
140 * unsigned int FFI_HIDDEN
141 * ffi_closure_SYSV_inner (closure, respp, args)
142 * ffi_closure *closure;
143 * void **respp;
144 * void *args;
145 */
146 CSKY_FUNC_START ffi_closure_SYSV
147 .cfi_startproc
148 mov a2, sp
149 addi a1, sp, 16
150 subi sp, sp, 24
151 .cfi_def_cfa_offset 40
152 stw a1, (sp, 0x10)
153 .cfi_offset 1, -24
154 stw lr, (sp, 0x14)
155 .cfi_offset 15, -20
156 stw sp, (sp, 0x8)
157 addi a1, sp, 8
158 jsri ffi_closure_SYSV_inner
159 ldw a0, (sp, 0x0)
160 /*
161 * if FFI_TYPE_SINT64, need a1.
162 * if FFI_TYPE_INT, ignore a1.
163 */
164 ldw a1, (sp, 0x4)
165
166 ldw lr, (sp, 0x14)
167 addi sp, sp, 40
168 rts
169 .cfi_endproc
170 .size ffi_closure_SYSV, .-ffi_closure_SYSV
171
172 CSKY_FUNC_START ffi_csky_trampoline
173 subi sp, sp, 16
174 stw a0, (sp, 0x0)
175 stw a1, (sp, 0x4)
176 stw a2, (sp, 0x8)
177 stw a3, (sp, 0xC)
178 lrw a0, [.Lctx]
179 lrw a1, [.Lfun]
180 jmp a1
181 .Lctx:
182 mov a0, a0
183 mov a0, a0
184 .Lfun:
185
186 .size ffi_csky_trampoline, .-ffi_csky_trampoline
187
188 CSKY_FUNC_START ffi_csky_cacheflush
189 mov t0, r7
190 movi r7, 123
191 trap 0
192 mov r7, t0
193 rts
194
195 .size ffi_csky_cacheflush, .-ffi_csky_cacheflush
196
197 #else /* !__CSKYABIV2__ */
198
199 /*
200 * a0: fn
201 * a1: &ecif
202 * a2: cif->bytes
203 * a3: fig->flags
204 * a4: ecif.rvalue
205 */
206 CSKY_FUNC_START ffi_call_SYSV
207 /* Save registers */
208 .cfi_startproc
209 subi sp, 32
210 subi sp, 8
211 .cfi_def_cfa_offset 40
212 stw a0, (sp, 0x0)
213 .cfi_offset 2, -40
214 stw a1, (sp, 0x4)
215 .cfi_offset 3, -36
216 stw a2, (sp, 0x8)
217 .cfi_offset 4, -32
218 stw a3, (sp, 0xC)
219 .cfi_offset 5, -28
220 stw a4, (sp, 0x10)
221 .cfi_offset 6, -24
222 stw a5, (sp, 0x14)
223 .cfi_offset 7, -20
224 stw l0, (sp, 0x18)
225 .cfi_offset 8, -16
226 stw l1, (sp, 0x1C)
227 .cfi_offset 9, -12
228 stw lr, (sp, 0x20)
229 .cfi_offset 15, -8
230
231 mov l0, sp
232 .cfi_def_cfa_register 8
233
234 /* Make room for all of the new args. */
235 subu sp, sp, a2
236
237 /* Place all of the ffi_prep_args in position */
238 mov a0, sp
239 /* a1 already set */
240
241 /* Call ffi_prep_args(stack, &ecif) */
242 jsri ffi_prep_args
243
244 /* move first 4 parameters in registers */
245 ldw a0, (sp, 0x0)
246 ldw a1, (sp, 0x4)
247 ldw a2, (sp, 0x8)
248 ldw a3, (sp, 0xC)
249 ldw a4, (sp, 0x10)
250 ldw a5, (sp, 0x14)
251
252 /* and adjust stack */
253 mov lr, l0
254 subu lr, sp /* cif->bytes == l0 - sp */
255 movi l1, 24
256 cmphs lr, l1
257 movt lr, l1
258 addu sp, sp, lr
259
260 ldw l1, (l0, 0) /* load fn() in advance */
261
262 /* call (fn) (...) */
263 jsr l1
264
265 /* Remove the space we pushed for the args */
266 mov sp, l0
267
268 /* Load r2 with the pointer to storage for the return value */
269 ldw a2, (sp, 0x10)
270
271 /* Load r3 with the return type code */
272 ldw a3, (sp, 0xC)
273
274 /* If the return value pointer is NULL, assume no return value. */
275 cmpnei a2, 0
276 bf .Lepilogue
277
278 cmpnei a3, FFI_TYPE_STRUCT
279 bf .Lepilogue
280
281 /* return INT64 */
282 cmpnei a3, FFI_TYPE_SINT64
283 bt .Lretint
284 /* stw a0, (a2, 0x0) at .Lretint */
285 stw a1, (a2, 0x4)
286
287 .Lretint:
288 /* return INT */
289 stw a0, (a2, 0x0)
290
291 .Lepilogue:
292 ldw a0, (sp, 0x0)
293 ldw a1, (sp, 0x4)
294 ldw a2, (sp, 0x8)
295 ldw a3, (sp, 0xC)
296 ldw a4, (sp, 0x10)
297 ldw a5, (sp, 0x14)
298 ldw l0, (sp, 0x18)
299 ldw l1, (sp, 0x1C)
300 ldw lr, (sp, 0x20)
301 addi sp, sp, 32
302 addi sp, sp, 8
303 rts
304 .cfi_endproc
305
306 .size ffi_call_SYSV, .-ffi_call_SYSV
307
308
309 /*
310 * unsigned int FFI_HIDDEN
311 * ffi_closure_SYSV_inner (closure, respp, args)
312 * ffi_closure *closure;
313 * void **respp;
314 * void *args;
315 */
316 CSKY_FUNC_START ffi_closure_SYSV
317 .cfi_startproc
318 mov a2, sp
319 mov a1, sp
320 addi a1, 24
321 subi sp, sp, 24
322 .cfi_def_cfa_offset 48
323 stw a1, (sp, 0x10)
324 .cfi_offset 3, -32
325 stw lr, (sp, 0x14)
326 .cfi_offset 15, -28
327 stw sp, (sp, 0x8)
328 mov a1, sp
329 addi a1, 8
330 jsri ffi_closure_SYSV_inner
331 ldw a0, (sp, 0x0)
332 /*
333 * if FFI_TYPE_SINT64, need a1.
334 * if FFI_TYPE_INT, ignore a1.
335 */
336 ldw a1, (sp, 0x4)
337
338 ldw lr, (sp, 0x14)
339 addi sp, sp, 24
340 addi sp, sp, 24
341 rts
342 .cfi_endproc
343
344 .size ffi_closure_SYSV, .-ffi_closure_SYSV
345
346 CSKY_FUNC_START ffi_csky_trampoline
347 subi sp, 24
348 stw a0, (sp, 0x0)
349 stw a1, (sp, 0x4)
350 stw a2, (sp, 0x8)
351 stw a3, (sp, 0xC)
352 stw a4, (sp, 0x10)
353 stw a5, (sp, 0x14)
354 lrw a0, [.Lctx]
355 lrw a1, [.Lfun]
356 jmp a1
357 .Lctx:
358 mov a0, a0
359 mov a0, a0
360 .Lfun:
361
362 .size ffi_csky_trampoline, .-ffi_csky_trampoline
363
364 CSKY_FUNC_START ffi_csky_cacheflush
365 lrw r1, 123
366 trap 0
367 rts
368
369 .size ffi_csky_cacheflush, .-ffi_csky_cacheflush
370
371 #endif /* __CSKYABIV2__ */