Debian Codegraph @

.gdbinit

raw
1 # From http://cpansearch.perl.org/src/GOZER/mod_perl-1.31/.gdbinit
2
3 #some handy debugging macros, hopefully you'll never need them
4 #some don't quite work, like dump_hv and hv_fetch,
5 #where's the bloody manpage for .gdbinit syntax?
6
7 define thttpd
8 run -X -f `pwd`/t/conf/httpd.conf -d `pwd`/t
9 # set $sv = perl_eval_pv("$Apache::ErrLog = '/tmp/mod_perl_error_log'",1)
10 end
11
12 define httpd
13 run -X -d `pwd`
14 set $sv = perl_eval_pv("$Apache::ErrLog = Apache->server_root_relative('logs/error_log')", 1)
15 #printf "error_log = %s\n", ((XPV*) ($sv)->sv_any )->xpv_pv
16 end
17
18 define STpvx
19 print ((XPV*) (PL_stack_base [ax + ($arg0)] )->sv_any )->xpv_pv
20 end
21
22 define TOPs
23 print ((XPV*) (**sp)->sv_any )->xpv_pv
24 end
25
26 define curstash
27 print ((XPVHV*) (PL_curstash)->sv_any)->xhv_name
28 end
29
30 define defstash
31 print ((XPVHV*) (PL_defstash)->sv_any)->xhv_name
32 end
33
34 define curinfo
35 printf "%d:%s\n", PL_curcop->cop_line, \
36 ((XPV*)(*(XPVGV*)PL_curcop->cop_filegv->sv_any)\
37 ->xgv_gp->gp_sv->sv_any)->xpv_pv
38 end
39
40 define SvPVX
41 print ((XPV*) ($arg0)->sv_any )->xpv_pv
42 end
43
44 define SvCUR
45 print ((XPV*) ($arg0)->sv_any )->xpv_cur
46 end
47
48 define SvLEN
49 print ((XPV*) ($arg0)->sv_any )->xpv_len
50 end
51
52 define SvEND
53 print (((XPV*) ($arg0)->sv_any )->xpv_pv + ((XPV*)($arg0)->sv_any )->xpv_cur) - 1
54 end
55
56 define SvSTASH
57 print ((XPVHV*)((XPVMG*)($arg0)->sv_any )->xmg_stash)->sv_any->xhv_name
58 end
59
60 define SvTAINTED
61 print ((($arg0)->sv_flags & (0x00002000 |0x00004000 |0x00008000 )) && Perl_sv_tainted ($arg0))
62 end
63
64 define SvTRUE
65 print ( !$arg0 ? 0 : (($arg0)->sv_flags & 0x00040000 ) ? ((PL_Xpv = (XPV*)($arg0)->sv_any ) && (*PL_Xpv ->xpv_pv > '0' || PL_Xpv ->xpv_cur > 1 || (PL_Xpv ->xpv_cur && *PL_Xpv ->xpv_pv != '0')) ? 1 : 0) : (($arg0)->sv_flags & 0x00010000 ) ? ((XPVIV*) ($arg0)->sv_any )->xiv_iv != 0 : (($arg0)->sv_flags & 0x00020000 ) ? ((XPVNV*)($arg0)->sv_any )->xnv_nv != 0.0 : Perl_sv_2bool ($arg0) )
66 end
67
68 define GvHV
69 set $hv = (((((XPVGV*)($arg0)->sv_any ) ->xgv_gp) )->gp_hv)
70 end
71
72 define GvSV
73 print ((XPV*) ((((XPVGV*)($arg0)->sv_any ) ->xgv_gp) ->gp_sv )->sv_any )->xpv_pv
74 end
75
76 define GvNAME
77 print (((XPVGV*)($arg0)->sv_any ) ->xgv_name)
78 end
79
80 define GvFILEGV
81 print ((XPV*) ((((XPVGV*)$arg0->filegv)->xgv_gp)->gp_sv)->sv_any)->xpv_pv
82 end
83
84 define CvNAME
85 print ((XPVGV*)(((XPVCV*)($arg0)->sv_any)->xcv_gv)->sv_any)->xgv_name
86 end
87
88 define CvSTASH
89 print ((XPVHV*)(((XPVGV*)(((XPVCV*)($arg0)->sv_any)->xcv_gv)->sv_any)->xgv_stash)->sv_any)->xhv_name
90 end
91
92 define CvDEPTH
93 print ((XPVCV*)($arg0)->sv_any )->xcv_depth
94 end
95
96 define CvFILEGV
97 print ((XPV*) ((((XPVGV*)((XPVCV*)($arg0)->sv_any )->xcv_filegv)->xgv_gp)->gp_sv)->sv_any)->xpv_pv
98 end
99
100 define SVOPpvx
101 print ((XPV*) ( ((SVOP*)$arg0)->op_sv)->sv_any )->xpv_pv
102 end
103
104 define HvNAME
105 print ((XPVHV*)$arg0->sv_any)->xhv_name
106 end
107
108 define HvKEYS
109 print ((XPVHV*) ($arg0)->sv_any)->xhv_keys
110 end
111
112 define AvFILL
113 print ((XPVAV*) ($arg0)->sv_any)->xav_fill
114 end
115
116 define dumpav
117 set $n = ((XPVAV*) ($arg0)->sv_any)->xav_fill
118 set $i = 0
119 while $i <= $n
120 set $sv = *Perl_av_fetch($arg0, $i, 0)
121 printf "[%u] -> `%s'\n", $i, ((XPV*) ($sv)->sv_any )->xpv_pv
122 set $i = $i + 1
123 end
124 end
125
126 define dumphv
127 set $n = ((XPVHV*) ($arg0)->sv_any)->xhv_keys
128 set $i = 0
129 set $key = 0
130 set $klen = 0
131 Perl_hv_iterinit($arg0)
132 while $i <= $n
133 set $sv = Perl_hv_iternextsv($arg0, &$key, &$klen)
134 printf "%s = `%s'\n", $key, ((XPV*) ($sv)->sv_any )->xpv_pv
135 set $i = $i + 1
136 end
137 end
138
139 define hvfetch
140 set $klen = strlen($arg1)
141 set $sv = *Perl_hv_fetch($arg0, $arg1, $klen, 0)
142 printf "%s = `%s'\n", $arg1, ((XPV*) ($sv)->sv_any )->xpv_pv
143 end
144
145 define hvINCval
146 set $hv = (((((XPVGV*)(PL_incgv)->sv_any)->xgv_gp))->gp_hv)
147 set $klen = strlen($arg0)
148 set $sv = *Perl_hv_fetch($hv, $arg0, $klen, 0)
149 printf "%s = `%s'\n", $arg0, ((XPV*) ($sv)->sv_any )->xpv_pv
150 end
151
152 define dumpany
153 set $sv = Perl_newSVpv("use Data::Dumper; Dumper \\",0)
154 set $void = Perl_sv_catpv($sv, $arg0)
155 set $dump = perl_eval_pv(((XPV*) ($sv)->sv_any )->xpv_pv, 1)
156 printf "%s = `%s'\n", $arg0, ((XPV*) ($dump)->sv_any )->xpv_pv
157 end
158
159 define dumpanyrv
160 set $rv = Perl_newRV((SV*)$arg0)
161 set $rvpv = perl_get_sv("main::DumpAnyRv", 1)
162 set $void = Perl_sv_setsv($rvpv, $rv)
163 set $sv = perl_eval_pv("use Data::Dumper; Dumper $::DumpAnyRv",1)
164 printf "`%s'\n", ((XPV*) ($sv)->sv_any )->xpv_pv
165 end
166
167 define svpeek
168 set $pv = Perl_sv_peek((SV*)$arg0)
169 printf "%s\n", $pv
170 end
171
172 define caller
173 set $sv = perl_eval_pv("scalar caller", 1)
174 printf "caller = %s\n", ((XPV*) ($sv)->sv_any )->xpv_pv
175 end
176
177 define cluck
178 set $sv = perl_eval_pv("Carp::cluck(); `tail '$Apache::ErrLog'`", 1)
179 printf "%s\n", ((XPV*) ($sv)->sv_any )->xpv_pv
180 end
181
182 define longmess
183 set $sv = perl_eval_pv("Carp::longmess()", 1)
184 printf "%s\n", ((XPV*) ($sv)->sv_any )->xpv_pv
185 end
186
187 define shortmess
188 set $sv = perl_eval_pv("Carp::shortmess()", 1)
189 printf "%s\n", ((XPV*) ($sv)->sv_any )->xpv_pv
190 end
191
192 define perl_get_sv
193 set $sv = perl_get_sv($arg0, 0)
194 printf "%s\n", $sv ? ((XPV*) ((SV*)$sv)->sv_any)->xpv_pv : "undef"
195 end