Debian Codegraph @

.cargo/vendor/rav1e/src/x86/me.asm

raw
1 ; Copyright (c) 2018, The rav1e contributors. All rights reserved
2 ;
3 ; This source code is subject to the terms of the BSD 2 Clause License and
4 ; the Alliance for Open Media Patent License 1.0. If the BSD 2 Clause License
5 ; was not distributed with this source code in the LICENSE file, you can
6 ; obtain it at www.aomedia.org/license/software. If the Alliance for Open
7 ; Media Patent License 1.0 was not distributed with this source code in the
8 ; PATENTS file, you can obtain it at www.aomedia.org/license/patent.
9
10 %include "config.asm"
11 %include "ext/x86/x86inc.asm"
12
13 SECTION .text
14
15 %macro W_ABS_DIFF 8
16 psubw %1, %5
17 psubw %2, %6
18 psubw %3, %7
19 psubw %4, %8
20 pabsw %1, %1
21 pabsw %2, %2
22 pabsw %3, %3
23 pabsw %4, %4
24 %endmacro
25
26 INIT_XMM ssse3
27 cglobal sad_4x4_hbd, 4, 6, 8, src, src_stride, dst, dst_stride, \
28 src_stride3, dst_stride3
29 lea src_stride3q, [src_strideq*3]
30 lea dst_stride3q, [dst_strideq*3]
31 movq m0, [srcq]
32 movq m1, [srcq+src_strideq*1]
33 movq m2, [srcq+src_strideq*2]
34 movq m3, [srcq+src_stride3q]
35 movq m4, [dstq]
36 movq m5, [dstq+dst_strideq*1]
37 movq m6, [dstq+dst_strideq*2]
38 movq m7, [dstq+dst_stride3q]
39 W_ABS_DIFF m0, m1, m2, m3, m4, m5, m6, m7
40 ; Don't convert to 32 bit integers: 4*4 abs diffs of 12-bits fits in 16 bits.
41 ; Accumulate onto m0
42 %define sum m0
43 paddw sum, m1
44 paddw m2, m3
45 paddw sum, m2
46 ; Horizontal reduction
47 pshuflw m1, sum, q2323
48 paddw sum, m1
49 pshuflw m1, sum, q1111
50 paddw sum, m1
51 movd eax, sum
52 ; Convert to 16-bits since the upper half of eax is dirty
53 movzx eax, ax
54 RET
55
56 %if ARCH_X86_64
57
58 INIT_XMM ssse3
59 cglobal sad_16x16_hbd, 4, 5, 10, src, src_stride, dst, dst_stride, \
60 cnt
61 mov cntd, 8
62 %define sum m0
63 pxor sum, sum
64 pxor m9, m9
65 .loop:
66 movu m1, [srcq]
67 movu m2, [srcq+16]
68 movu m3, [srcq+src_strideq]
69 movu m4, [srcq+src_strideq+16]
70 lea srcq, [srcq+src_strideq*2]
71 movu m5, [dstq]
72 movu m6, [dstq+16]
73 movu m7, [dstq+dst_strideq]
74 movu m8, [dstq+dst_strideq+16]
75 lea dstq, [dstq+dst_strideq*2]
76 W_ABS_DIFF m1, m2, m3, m4, m5, m6, m7, m8
77 paddw m1, m2
78 paddw m3, m4
79 ; Convert to 32-bits
80 punpcklwd m2, m1, m9
81 punpcklwd m4, m3, m9
82 punpckhwd m1, m9
83 punpckhwd m3, m9
84 paddd m1, m2
85 paddd m3, m4
86 paddd sum, m1
87 paddd sum, m3
88 dec cntd
89 jg .loop
90 ; Horizontal reduction
91 movhlps m1, sum
92 paddd sum, m1
93 pshufd m1, sum, q1111
94 paddd sum, m1
95 movd eax, sum
96 RET
97
98 %endif