Debian Codegraph @

example/jobrunner

raw
1 #!/usr/bin/perl
2
3 use strict;
4 use warnings;
5 use JSON qw( to_json );
6 use AnyEvent::Open3::Simple;
7 use AnyEvent::WebSocket::Client 0.12;
8
9 unless(@ARGV > 0)
10 {
11 print "usage: $0 command [arg1 [ arg2 [ ... ] ]\n";
12 exit 1;
13 }
14
15 my $client = AnyEvent::WebSocket::Client->new;
16 my $connection = $client->connect("ws://localhost:3000/run")->recv;
17
18 # error stdout stderr signal exit
19
20 my $done = AnyEvent->condvar;
21
22 my $ipc = AnyEvent::Open3::Simple->new(
23 on_stdout => sub {
24 my($proc, $line) = @_;
25 print $line, "\n";
26 $connection->send(to_json({ type => 'out', data => $line }));
27 },
28 on_stderr => sub {
29 my($proc, $line) = @_;
30 print STDERR $line, "\n";
31 $connection->send(to_json({ type => 'err', data => $line }));
32 },
33 on_exit => sub {
34 my($proc, $exit, $signal) = @_;
35 $connection->send(to_json({ type => 'exit', exit => $exit, signal => $signal }));
36 $done->send([$exit,$signal]);
37 },
38 on_error => sub {
39 my($error) = @_;
40 $connection->send(to_json({ type => 'error', data => $error }));
41 $done->croak($error);
42 },
43 );
44
45 $connection->send(to_json(\@ARGV));
46 $ipc->run(@ARGV);
47
48 my($exit,$signal) = @{ $done->recv };
49 if($signal)
50 {
51 print STDERR "died with signal $signal\n";
52 exit 1;
53 }
54 else
55 {
56 exit $exit;
57 }