Debian Codegraph @

crypto_nPbatch/montgomery25519/amd64-avx2-4x1-10l-maax/fe25519_mul.S

raw
1 #include "crypto_asm_property.h"
2 #include "crypto_asm_hidden.h"
3 // linker define fe25519_mul
4 // linker use mask63
5
6 /* Assembly for field multiplication. */
7
8 #define mask63 CRYPTO_SHARED_NAMESPACE(mask63)
9
10 .p2align 5
11 ASM_HIDDEN _CRYPTO_SHARED_NAMESPACE(fe25519_mul)
12 .globl _CRYPTO_SHARED_NAMESPACE(fe25519_mul)
13 ASM_HIDDEN CRYPTO_SHARED_NAMESPACE(fe25519_mul)
14 .globl CRYPTO_SHARED_NAMESPACE(fe25519_mul)
15 _CRYPTO_SHARED_NAMESPACE(fe25519_mul):
16 CRYPTO_SHARED_NAMESPACE(fe25519_mul):
17
18 movq %rsp,%r11
19 andq $-32,%rsp
20 subq $56,%rsp
21
22 movq %r11,0(%rsp)
23 movq %r12,8(%rsp)
24 movq %r13,16(%rsp)
25 movq %r14,24(%rsp)
26 movq %r15,32(%rsp)
27 movq %rbx,40(%rsp)
28 movq %rbp,48(%rsp)
29
30 movq %rdx,%rbx
31
32 xorq %r13,%r13
33 movq 0(%rbx),%rdx
34
35 mulx 0(%rsi),%r8,%r9
36 mulx 8(%rsi),%rcx,%r10
37 adcx %rcx,%r9
38
39 mulx 16(%rsi),%rcx,%r11
40 adcx %rcx,%r10
41
42 mulx 24(%rsi),%rcx,%r12
43 adcx %rcx,%r11
44 adcx %r13,%r12
45
46 xorq %r14,%r14
47 movq 8(%rbx),%rdx
48
49 mulx 0(%rsi),%rcx,%rbp
50 adcx %rcx,%r9
51 adox %rbp,%r10
52
53 mulx 8(%rsi),%rcx,%rbp
54 adcx %rcx,%r10
55 adox %rbp,%r11
56
57 mulx 16(%rsi),%rcx,%rbp
58 adcx %rcx,%r11
59 adox %rbp,%r12
60
61 mulx 24(%rsi),%rcx,%rbp
62 adcx %rcx,%r12
63 adox %rbp,%r13
64 adcx %r14,%r13
65
66 xorq %r15,%r15
67
68 movq 16(%rbx),%rdx
69
70 mulx 0(%rsi),%rcx,%rbp
71 adcx %rcx,%r10
72 adox %rbp,%r11
73
74 mulx 8(%rsi),%rcx,%rbp
75 adcx %rcx,%r11
76 adox %rbp,%r12
77
78 mulx 16(%rsi),%rcx,%rbp
79 adcx %rcx,%r12
80 adox %rbp,%r13
81
82 mulx 24(%rsi),%rcx,%rbp
83 adcx %rcx,%r13
84 adox %rbp,%r14
85 adcx %r15,%r14
86
87 xorq %rax,%rax
88
89 movq 24(%rbx),%rdx
90
91 mulx 0(%rsi),%rcx,%rbp
92 adcx %rcx,%r11
93 adox %rbp,%r12
94
95 mulx 8(%rsi),%rcx,%rbp
96 adcx %rcx,%r12
97 adox %rbp,%r13
98
99 mulx 16(%rsi),%rcx,%rbp
100 adcx %rcx,%r13
101 adox %rbp,%r14
102
103 mulx 24(%rsi),%rcx,%rbp
104 adcx %rcx,%r14
105 adox %rbp,%r15
106 adcx %rax,%r15
107
108 xorq %rbp,%rbp
109 movq $38,%rdx
110
111 mulx %r12,%rax,%r12
112 adcx %rax,%r8
113 adox %r12,%r9
114
115 mulx %r13,%rcx,%r13
116 adcx %rcx,%r9
117 adox %r13,%r10
118
119 mulx %r14,%rcx,%r14
120 adcx %rcx,%r10
121 adox %r14,%r11
122
123 mulx %r15,%rcx,%r15
124 adcx %rcx,%r11
125 adox %rbp,%r15
126 adcx %rbp,%r15
127
128 shld $1,%r11,%r15
129 andq mask63(%rip),%r11
130
131 imul $19,%r15,%r15
132 addq %r15,%r8
133 adcq $0,%r9
134 adcq $0,%r10
135 adcq $0,%r11
136
137 movq %r8,0(%rdi)
138 movq %r9,8(%rdi)
139 movq %r10,16(%rdi)
140 movq %r11,24(%rdi)
141
142 movq 0(%rsp),%r11
143 movq 8(%rsp),%r12
144 movq 16(%rsp),%r13
145 movq 24(%rsp),%r14
146 movq 32(%rsp),%r15
147 movq 40(%rsp),%rbx
148 movq 48(%rsp),%rbp
149
150 movq %r11,%rsp
151
152 ret
153 .section .note.GNU-stack,"",@progbits