Debian Codegraph @

Utilities/KWSys/kwsysPlatformTests.cmake

raw
1 # Distributed under the OSI-approved BSD 3-Clause License. See accompanying
2 # file Copyright.txt or https://cmake.org/licensing#kwsys for details.
3
4 set(KWSYS_PLATFORM_TEST_FILE_C kwsysPlatformTestsC.c)
5 set(KWSYS_PLATFORM_TEST_FILE_CXX kwsysPlatformTestsCXX.cxx)
6
7 macro(KWSYS_PLATFORM_TEST lang var description invert)
8 if(NOT DEFINED ${var}_COMPILED)
9 message(STATUS "${description}")
10 set(maybe_cxx_standard "")
11 try_compile(${var}_COMPILED
12 ${CMAKE_CURRENT_BINARY_DIR}
13 ${CMAKE_CURRENT_SOURCE_DIR}/${KWSYS_PLATFORM_TEST_FILE_${lang}}
14 COMPILE_DEFINITIONS -DTEST_${var} ${KWSYS_PLATFORM_TEST_DEFINES} ${KWSYS_PLATFORM_TEST_EXTRA_FLAGS}
15 CMAKE_FLAGS "-DLINK_LIBRARIES:STRING=${KWSYS_PLATFORM_TEST_LINK_LIBRARIES}"
16 ${maybe_cxx_standard}
17 OUTPUT_VARIABLE OUTPUT)
18 if(CMAKE_VERSION VERSION_LESS 3.26)
19 if(${var}_COMPILED)
20 file(APPEND
21 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
22 "${description} compiled with the following output:\n${OUTPUT}\n\n")
23 else()
24 file(APPEND
25 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
26 "${description} failed to compile with the following output:\n${OUTPUT}\n\n")
27 endif()
28 endif()
29 if(${invert} MATCHES INVERT)
30 if(${var}_COMPILED)
31 message(STATUS "${description} - no")
32 else()
33 message(STATUS "${description} - yes")
34 endif()
35 else()
36 if(${var}_COMPILED)
37 message(STATUS "${description} - yes")
38 else()
39 message(STATUS "${description} - no")
40 endif()
41 endif()
42 endif()
43 if(${invert} MATCHES INVERT)
44 if(${var}_COMPILED)
45 set(${var} 0)
46 else()
47 set(${var} 1)
48 endif()
49 else()
50 if(${var}_COMPILED)
51 set(${var} 1)
52 else()
53 set(${var} 0)
54 endif()
55 endif()
56 endmacro()
57
58 macro(KWSYS_PLATFORM_TEST_RUN lang var description invert)
59 if(NOT DEFINED ${var})
60 message(STATUS "${description}")
61 try_run(${var} ${var}_COMPILED
62 ${CMAKE_CURRENT_BINARY_DIR}
63 ${CMAKE_CURRENT_SOURCE_DIR}/${KWSYS_PLATFORM_TEST_FILE_${lang}}
64 COMPILE_DEFINITIONS -DTEST_${var} ${KWSYS_PLATFORM_TEST_DEFINES} ${KWSYS_PLATFORM_TEST_EXTRA_FLAGS}
65 OUTPUT_VARIABLE OUTPUT)
66
67 # Note that ${var} will be a 0 return value on success.
68 if(${var}_COMPILED)
69 if(CMAKE_VERSION VERSION_LESS 3.26)
70 if(${var})
71 file(APPEND
72 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
73 "${description} compiled but failed to run with the following output:\n${OUTPUT}\n\n")
74 else()
75 file(APPEND
76 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
77 "${description} compiled and ran with the following output:\n${OUTPUT}\n\n")
78 endif()
79 endif()
80 else()
81 if(CMAKE_VERSION VERSION_LESS 3.26)
82 file(APPEND
83 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
84 "${description} failed to compile with the following output:\n${OUTPUT}\n\n")
85 endif()
86 set(${var} -1 CACHE INTERNAL "${description} failed to compile.")
87 endif()
88
89 if(${invert} MATCHES INVERT)
90 if(${var}_COMPILED)
91 if(${var})
92 message(STATUS "${description} - yes")
93 else()
94 message(STATUS "${description} - no")
95 endif()
96 else()
97 message(STATUS "${description} - failed to compile")
98 endif()
99 else()
100 if(${var}_COMPILED)
101 if(${var})
102 message(STATUS "${description} - no")
103 else()
104 message(STATUS "${description} - yes")
105 endif()
106 else()
107 message(STATUS "${description} - failed to compile")
108 endif()
109 endif()
110 endif()
111
112 if(${invert} MATCHES INVERT)
113 if(${var}_COMPILED)
114 if(${var})
115 set(${var} 1)
116 else()
117 set(${var} 0)
118 endif()
119 else()
120 set(${var} 1)
121 endif()
122 else()
123 if(${var}_COMPILED)
124 if(${var})
125 set(${var} 0)
126 else()
127 set(${var} 1)
128 endif()
129 else()
130 set(${var} 0)
131 endif()
132 endif()
133 endmacro()
134
135 macro(KWSYS_PLATFORM_C_TEST var description invert)
136 set(KWSYS_PLATFORM_TEST_DEFINES ${KWSYS_PLATFORM_C_TEST_DEFINES})
137 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS ${KWSYS_PLATFORM_C_TEST_EXTRA_FLAGS})
138 KWSYS_PLATFORM_TEST(C "${var}" "${description}" "${invert}")
139 set(KWSYS_PLATFORM_TEST_DEFINES)
140 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS)
141 endmacro()
142
143 macro(KWSYS_PLATFORM_C_TEST_RUN var description invert)
144 set(KWSYS_PLATFORM_TEST_DEFINES ${KWSYS_PLATFORM_C_TEST_DEFINES})
145 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS ${KWSYS_PLATFORM_C_TEST_EXTRA_FLAGS})
146 KWSYS_PLATFORM_TEST_RUN(C "${var}" "${description}" "${invert}")
147 set(KWSYS_PLATFORM_TEST_DEFINES)
148 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS)
149 endmacro()
150
151 macro(KWSYS_PLATFORM_CXX_TEST var description invert)
152 set(KWSYS_PLATFORM_TEST_DEFINES ${KWSYS_PLATFORM_CXX_TEST_DEFINES})
153 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS ${KWSYS_PLATFORM_CXX_TEST_EXTRA_FLAGS})
154 set(KWSYS_PLATFORM_TEST_LINK_LIBRARIES ${KWSYS_PLATFORM_CXX_TEST_LINK_LIBRARIES})
155 KWSYS_PLATFORM_TEST(CXX "${var}" "${description}" "${invert}")
156 set(KWSYS_PLATFORM_TEST_DEFINES)
157 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS)
158 set(KWSYS_PLATFORM_TEST_LINK_LIBRARIES)
159 endmacro()
160
161 macro(KWSYS_PLATFORM_CXX_TEST_RUN var description invert)
162 set(KWSYS_PLATFORM_TEST_DEFINES ${KWSYS_PLATFORM_CXX_TEST_DEFINES})
163 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS ${KWSYS_PLATFORM_CXX_TEST_EXTRA_FLAGS})
164 KWSYS_PLATFORM_TEST_RUN(CXX "${var}" "${description}" "${invert}")
165 set(KWSYS_PLATFORM_TEST_DEFINES)
166 set(KWSYS_PLATFORM_TEST_EXTRA_FLAGS)
167 endmacro()
168
169 #-----------------------------------------------------------------------------
170 # KWSYS_PLATFORM_INFO_TEST(lang var description)
171 #
172 # Compile test named by ${var} and store INFO strings extracted from binary.
173 macro(KWSYS_PLATFORM_INFO_TEST lang var description)
174 # We can implement this macro on CMake 2.6 and above.
175 if("${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION}" LESS 2.6)
176 set(${var} "")
177 else()
178 # Choose a location for the result binary.
179 set(KWSYS_PLATFORM_INFO_FILE
180 ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_FILES_DIRECTORY}/${var}.bin)
181
182 # Compile the test binary.
183 if(NOT EXISTS ${KWSYS_PLATFORM_INFO_FILE})
184 message(STATUS "${description}")
185 try_compile(${var}_COMPILED
186 ${CMAKE_CURRENT_BINARY_DIR}
187 ${CMAKE_CURRENT_SOURCE_DIR}/${KWSYS_PLATFORM_TEST_FILE_${lang}}
188 COMPILE_DEFINITIONS -DTEST_${var}
189 ${KWSYS_PLATFORM_${lang}_TEST_DEFINES}
190 ${KWSYS_PLATFORM_${lang}_TEST_EXTRA_FLAGS}
191 OUTPUT_VARIABLE OUTPUT
192 COPY_FILE ${KWSYS_PLATFORM_INFO_FILE}
193 )
194 if(CMAKE_VERSION VERSION_LESS 3.26)
195 if(${var}_COMPILED)
196 file(APPEND
197 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log
198 "${description} compiled with the following output:\n${OUTPUT}\n\n")
199 else()
200 file(APPEND
201 ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log
202 "${description} failed to compile with the following output:\n${OUTPUT}\n\n")
203 endif()
204 endif()
205 if(${var}_COMPILED)
206 message(STATUS "${description} - compiled")
207 else()
208 message(STATUS "${description} - failed")
209 endif()
210 endif()
211
212 # Parse info strings out of the compiled binary.
213 if(${var}_COMPILED)
214 file(STRINGS ${KWSYS_PLATFORM_INFO_FILE} ${var} REGEX "INFO:[A-Za-z0-9]+\\[[^]]*\\]")
215 else()
216 set(${var} "")
217 endif()
218
219 set(KWSYS_PLATFORM_INFO_FILE)
220 endif()
221 endmacro()