Debian Codegraph @

data/CMakeLists.txt

raw
1 # create a directory for generated definitions
2 execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_CURRENT_BINARY_DIR}/generated/syntax)
3
4 macro(generate_syntax_definition generator targetFile srcFile)
5 add_custom_target(
6 ${targetFile} ALL
7 DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/generated/syntax/${targetFile}
8 )
9 add_custom_command(
10 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/generated/syntax/${targetFile}
11 COMMAND ${PERL_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/generators/${generator}
12 ${CMAKE_CURRENT_SOURCE_DIR}/syntax/${srcFile}
13 ${CMAKE_CURRENT_BINARY_DIR}/generated/syntax/${targetFile}
14 DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/generators/${generator}
15 ${CMAKE_CURRENT_SOURCE_DIR}/syntax/${srcFile}
16 ${ARGN}
17 VERBATIM
18 )
19 set(gen_defs ${gen_defs} ${CMAKE_CURRENT_BINARY_DIR}/generated/syntax/${targetFile})
20 endmacro()
21
22 # generate PHP definitions
23 macro(generate_php_syntax_definition targetFile srcFile)
24 generate_syntax_definition(generate-php.pl ${targetFile} ${srcFile} ${CMAKE_CURRENT_SOURCE_DIR}/syntax/php.xml)
25 endmacro()
26
27 generate_php_syntax_definition(javascript-php.xml javascript.xml)
28 generate_php_syntax_definition(css-php.xml css.xml)
29 generate_php_syntax_definition(html-php.xml html.xml)
30 generate_php_syntax_definition(javascript-react-php.xml javascript-react.xml)
31 generate_php_syntax_definition(typescript-php.xml typescript.xml)
32 generate_php_syntax_definition(mustache-php.xml mustache.xml)
33
34 # generate DoxygenLua definition
35 generate_syntax_definition(generate-doxygenlua.pl doxygenlua.xml doxygen.xml)
36
37 # find all definitions
38 file(GLOB src_defs "${CMAKE_CURRENT_SOURCE_DIR}/syntax/*.xml")
39 set(defs ${src_defs} ${gen_defs})
40
41 # object library to make cross-folder dependencies work
42 add_library(SyntaxHighlightingData OBJECT)
43
44 # theme data resource
45 target_sources(SyntaxHighlightingData PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/themes/theme-data.qrc)
46
47 # generate the resource file
48 set(qrc_file ${CMAKE_CURRENT_BINARY_DIR}/syntax-data.qrc)
49 set(qrc_body "")
50 foreach(def ${defs})
51 get_filename_component(def_name ${def} NAME)
52 string(APPEND qrc_body "<file alias=\"${def_name}\">${def}</file>\n")
53 endforeach()
54 set(SYNTAX_DATA_QRC_FILES_STRING ${qrc_body})
55 configure_file(syntax-data.qrc.in ${qrc_file} @ONLY)
56
57 # generate the index file
58 add_custom_target(katesyntax DEPENDS "${CMAKE_CURRENT_BINARY_DIR}/index.katesyntax")
59 add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/index.katesyntax"
60 COMMAND katehighlightingindexer "${CMAKE_CURRENT_BINARY_DIR}/index.katesyntax" "${CMAKE_CURRENT_SOURCE_DIR}/schema/language.xsd" "${CMAKE_CURRENT_BINARY_DIR}/syntax-data.qrc"
61 DEPENDS katehighlightingindexer ${defs} ${CMAKE_CURRENT_SOURCE_DIR}/schema/language.xsd ${CMAKE_CURRENT_BINARY_DIR}/syntax-data.qrc
62 )
63
64 # do we want syntax files bundled in the library?
65 if (QRC_SYNTAX)
66 # generate the qrc file manually, to make dependencies on generated files work...
67 add_custom_command(OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/qrc_syntax-data.cpp"
68 COMMAND Qt${QT_MAJOR_VERSION}::rcc --name syntax_data -o "${CMAKE_CURRENT_BINARY_DIR}/qrc_syntax-data.cpp" "${CMAKE_CURRENT_BINARY_DIR}/syntax-data.qrc"
69 DEPENDS ${defs} ${CMAKE_CURRENT_BINARY_DIR}/index.katesyntax
70 )
71 set_source_files_properties("${CMAKE_CURRENT_BINARY_DIR}/qrc_syntax-data.cpp" PROPERTIES SKIP_AUTOMOC ON)
72
73 target_sources(SyntaxHighlightingData PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/qrc_syntax-data.cpp)
74 else()
75 add_dependencies(SyntaxHighlightingData katesyntax)
76 # install the syntax files as normal files into the prefix
77 install (FILES "${CMAKE_CURRENT_BINARY_DIR}/index.katesyntax" ${defs} DESTINATION ${KDE_INSTALL_DATADIR}/org.kde.syntax-highlighting/syntax-bundled)
78 endif()
79
80 # set PIC to allow use in static and shared libs
81 # this needs some more recent CMake than generally required
82 set_property(TARGET SyntaxHighlightingData PROPERTY POSITION_INDEPENDENT_CODE 1)
83 if(NOT ${CMAKE_VERSION} VERSION_LESS "3.13.0")
84 target_link_libraries(SyntaxHighlightingData PRIVATE Qt${QT_MAJOR_VERSION}::Core)
85 endif()