Debian Codegraph @

helper/xsl_to_v74/convert72to73.xsl

raw
1 <?xml version="1.0" encoding="utf-8"?>
2 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
3 <xsl:output method="xml"
4 indent="yes" omit-xml-declaration="no" encoding="utf-8"/>
5
6 <!-- default rule -->
7 <xsl:template match="*" mode="conv72to73">
8 <xsl:copy>
9 <xsl:copy-of select="@*"/>
10 <xsl:apply-templates mode="conv72to73"/>
11 </xsl:copy>
12 </xsl:template>
13
14 <!-- version update -->
15 <para xmlns="http://docbook.org/ns/docbook">
16 Changed attribute <tag class="attribute">schemaversion</tag>
17 to <tag class="attribute">schemaversion</tag> from
18 <literal>7.2</literal> to <literal>7.3</literal>.
19 </para>
20 <xsl:template match="image" mode="conv72to73">
21 <xsl:choose>
22 <!-- nothing to do if already at 7.3 -->
23 <xsl:when test="@schemaversion > 7.2">
24 <xsl:copy-of select="."/>
25 </xsl:when>
26 <!-- otherwise apply templates -->
27 <xsl:otherwise>
28 <image schemaversion="7.3">
29 <xsl:copy-of select="@*[local-name() != 'schemaversion']"/>
30 <xsl:apply-templates mode="conv72to73"/>
31 </image>
32 </xsl:otherwise>
33 </xsl:choose>
34 </xsl:template>
35
36 <!-- toplevel processing instructions and comments -->
37 <xsl:template match="processing-instruction()|comment()" mode="conv72to73">
38 <xsl:copy>
39 <xsl:copy-of select="@*"/>
40 <xsl:apply-templates mode="conv72to73"/>
41 </xsl:copy>
42 </xsl:template>
43
44 <!-- change vmx type to oem type with oem-resize set to false-->
45 <xsl:template match="type[@image='vmx']" mode="conv72to73">
46 <type image="oem">
47 <xsl:copy-of select="@*[local-name() != 'image']"/>
48 <oemconfig>
49 <xsl:apply-templates select="oemconfig/*[not(self::oem-resize)]" mode="conv72to73"/>
50 <oem-resize>false</oem-resize>
51 </oemconfig>
52 <xsl:apply-templates select="*[not(self::oemconfig)]" mode="conv72to73"/>
53 </type>
54 </xsl:template>
55
56 </xsl:stylesheet>