Debian Codegraph @

jackrabbit-spi-commons/src/main/javacc/sql/JCRSQL.jjt

raw
1 options {
2 LOOKAHEAD = 1;
3 CHOICE_AMBIGUITY_CHECK = 5;
4 OTHER_AMBIGUITY_CHECK = 2;
5 STATIC = false;
6 //DEBUG_PARSER = true;
7 //DEBUG_LOOKAHEAD = false;
8 //DEBUG_TOKEN_MANAGER = true;
9 ERROR_REPORTING = true;
10 JAVA_UNICODE_ESCAPE = false;
11 UNICODE_INPUT = true;
12 IGNORE_CASE = false;
13 USER_TOKEN_MANAGER = false;
14 USER_CHAR_STREAM = false;
15 BUILD_PARSER = true;
16 BUILD_TOKEN_MANAGER = true;
17 SANITY_CHECK = true;
18 FORCE_LA_CHECK = true;
19
20 MULTI = true;
21 NODE_PACKAGE = "org.apache.jackrabbit.spi.commons.query.sql";
22 VISITOR = true;
23 }
24
25 PARSER_BEGIN(JCRSQLParser)
26 /*
27 * Licensed to the Apache Software Foundation (ASF) under one or more
28 * contributor license agreements. See the NOTICE file distributed with
29 * this work for additional information regarding copyright ownership.
30 * The ASF licenses this file to You under the Apache License, Version 2.0
31 * (the "License"); you may not use this file except in compliance with
32 * the License. You may obtain a copy of the License at
33 *
34 * http://www.apache.org/licenses/LICENSE-2.0
35 *
36 * Unless required by applicable law or agreed to in writing, software
37 * distributed under the License is distributed on an "AS IS" BASIS,
38 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
39 * See the License for the specific language governing permissions and
40 * limitations under the License.
41 */
42 package org.apache.jackrabbit.spi.commons.query.sql;
43
44 import org.apache.jackrabbit.spi.commons.conversion.NameException;
45 import org.apache.jackrabbit.spi.commons.conversion.NameResolver;
46 import org.apache.jackrabbit.spi.commons.query.QueryConstants;
47 import org.apache.jackrabbit.spi.commons.name.NameFactoryImpl;
48 import org.apache.jackrabbit.spi.Name;
49
50 import javax.jcr.NamespaceException;
51
52 public class JCRSQLParser {
53
54 private String statement;
55
56 private NameResolver resolver;
57
58 public static void main(String args[]) throws ParseException {
59 JCRSQLParser parser = new JCRSQLParser(System.in);
60 parser.Query().dump("");
61 }
62
63 public static ASTQuery parse(String statement, NameResolver resolver) throws ParseException {
64 java.io.StringReader sReader = new java.io.StringReader(statement);
65 JCRSQLParser parser = new JCRSQLParser(sReader);
66 parser.setNameResolver(resolver);
67 return parser.Query();
68 }
69
70 void setNameResolver(NameResolver resolver) {
71 this.resolver = resolver;
72 }
73
74 }
75
76 PARSER_END(JCRSQLParser)
77
78 SKIP :
79 {
80 " "
81 | "\r"
82 | "\n"
83 | "\t"
84 | < COMMENT: <COMMENT_INTRO> (<COMMENT_CHAR>)* "\n" >
85 | < #COMMENT_CHAR: <NON_QUOTE_CHAR> | <QUOTE> >
86 | < #NON_QUOTE_CHAR: ~["'"] > // syntax rules
87 | < #COMMENT_INTRO: <MINUS_SIGN> <MINUS_SIGN> (<MINUS_SIGN>)* >
88 }
89
90 // KEY WORDS
91 TOKEN [ IGNORE_CASE ] :
92 {
93 < BY: "BY" >
94 | < IN: "IN" >
95 | < OR: "OR" >
96 | < IS: "IS" >
97 | < AND: "AND" >
98 | < ASC: "ASC" >
99 | < NOT: "NOT" >
100 | < DESC: "DESC" >
101 | < LIKE: "LIKE" >
102 | < NULL: "NULL" >
103 | < FROM: "FROM" >
104 | < LOWER: "LOWER" >
105 | < ORDER: "ORDER" >
106 | < UPPER: "UPPER" >
107 | < WHERE: "WHERE" >
108 | < ESCAPE: "ESCAPE" >
109 | < SELECT: "SELECT" >
110 | < BETWEEN: "BETWEEN" >
111 | < EXCERPT: "EXCERPT" >
112 | < SIMILAR: "SIMILAR" >
113 | < CONTAINS: "CONTAINS" >
114 | < SPELLCHECK: "SPELLCHECK" >
115 }
116
117
118
119 TOKEN:
120 {
121 < #SIMPLE_LATIN_LETTER: <SIMPLE_LATIN_UPPER_CASE_LETTER> | <SIMPLE_LATIN_LOWER_CASE_LETTER> >
122 | < #SIMPLE_LATIN_UPPER_CASE_LETTER: (["A"-"Z"]) >
123 | < #SIMPLE_LATIN_LOWER_CASE_LETTER: (["a"-"z"]) >
124
125 | < #LETTER: <BASE_CHAR> | <IDEOGRAPHIC> >
126
127 | < #BASE_CHAR:
128 ["\u0041"-"\u005A"] | ["\u0061"-"\u007A"] | ["\u00C0"-"\u00D6"] | ["\u00D8"-"\u00F6"]
129 | ["\u00F8"-"\u00FF"] | ["\u0100"-"\u0131"] | ["\u0134"-"\u013E"] | ["\u0141"-"\u0148"]
130 | ["\u014A"-"\u017E"] | ["\u0180"-"\u01C3"] | ["\u01CD"-"\u01F0"] | ["\u01F4"-"\u01F5"]
131 | ["\u01FA"-"\u0217"] | ["\u0250"-"\u02A8"] | ["\u02BB"-"\u02C1"] | "\u0386" | ["\u0388"-"\u038A"]
132 | "\u038C" | ["\u038E"-"\u03A1"] | ["\u03A3"-"\u03CE"] | ["\u03D0"-"\u03D6"] | "\u03DA"
133 | "\u03DC" | "\u03DE" | "\u03E0" | ["\u03E2"-"\u03F3"] | ["\u0401"-"\u040C"] | ["\u040E"-"\u044F"]
134 | ["\u0451"-"\u045C"] | ["\u045E"-"\u0481"] | ["\u0490"-"\u04C4"] | ["\u04C7"-"\u04C8"]
135 | ["\u04CB"-"\u04CC"] | ["\u04D0"-"\u04EB"] | ["\u04EE"-"\u04F5"] | ["\u04F8"-"\u04F9"]
136 | ["\u0531"-"\u0556"] | "\u0559" | ["\u0561"-"\u0586"] | ["\u05D0"-"\u05EA"] | ["\u05F0"-"\u05F2"]
137 | ["\u0621"-"\u063A"] | ["\u0641"-"\u064A"] | ["\u0671"-"\u06B7"] | ["\u06BA"-"\u06BE"]
138 | ["\u06C0"-"\u06CE"] | ["\u06D0"-"\u06D3"] | "\u06D5" | ["\u06E5"-"\u06E6"] | ["\u0905"-"\u0939"]
139 | "\u093D" | ["\u0958"-"\u0961"] | ["\u0985"-"\u098C"] | ["\u098F"-"\u0990"] | ["\u0993"-"\u09A8"]
140 | ["\u09AA"-"\u09B0"] | "\u09B2" | ["\u09B6"-"\u09B9"] | ["\u09DC"-"\u09DD"] | ["\u09DF"-"\u09E1"]
141 | ["\u09F0"-"\u09F1"] | ["\u0A05"-"\u0A0A"] | ["\u0A0F"-"\u0A10"] | ["\u0A13"-"\u0A28"]
142 | ["\u0A2A"-"\u0A30"] | ["\u0A32"-"\u0A33"] | ["\u0A35"-"\u0A36"] | ["\u0A38"-"\u0A39"]
143 | ["\u0A59"-"\u0A5C"] | "\u0A5E" | ["\u0A72"-"\u0A74"] | ["\u0A85"-"\u0A8B"] | "\u0A8D"
144 | ["\u0A8F"-"\u0A91"] | ["\u0A93"-"\u0AA8"] | ["\u0AAA"-"\u0AB0"] | ["\u0AB2"-"\u0AB3"]
145 | ["\u0AB5"-"\u0AB9"] | "\u0ABD" | "\u0AE0" | ["\u0B05"-"\u0B0C"] | ["\u0B0F"-"\u0B10"]
146 | ["\u0B13"-"\u0B28"] | ["\u0B2A"-"\u0B30"] | ["\u0B32"-"\u0B33"] | ["\u0B36"-"\u0B39"]
147 | "\u0B3D" | ["\u0B5C"-"\u0B5D"] | ["\u0B5F"-"\u0B61"] | ["\u0B85"-"\u0B8A"]
148 | ["\u0B8E"-"\u0B90"] | ["\u0B92"-"\u0B95"] | ["\u0B99"-"\u0B9A"] | "\u0B9C" | ["\u0B9E"-"\u0B9F"]
149 | ["\u0BA3"-"\u0BA4"] | ["\u0BA8"-"\u0BAA"] | ["\u0BAE"-"\u0BB5"] | ["\u0BB7"-"\u0BB9"]
150 | ["\u0C05"-"\u0C0C"] | ["\u0C0E"-"\u0C10"] | ["\u0C12"-"\u0C28"] | ["\u0C2A"-"\u0C33"]
151 | ["\u0C35"-"\u0C39"] | ["\u0C60"-"\u0C61"] | ["\u0C85"-"\u0C8C"] | ["\u0C8E"-"\u0C90"]
152 | ["\u0C92"-"\u0CA8"] | ["\u0CAA"-"\u0CB3"] | ["\u0CB5"-"\u0CB9"] | "\u0CDE" | ["\u0CE0"-"\u0CE1"]
153 | ["\u0D05"-"\u0D0C"] | ["\u0D0E"-"\u0D10"] | ["\u0D12"-"\u0D28"] | ["\u0D2A"-"\u0D39"]
154 | ["\u0D60"-"\u0D61"] | ["\u0E01"-"\u0E2E"] | "\u0E30" | ["\u0E32"-"\u0E33"] | ["\u0E40"-"\u0E45"]
155 | ["\u0E81"-"\u0E82"] | "\u0E84" | ["\u0E87"-"\u0E88"] | "\u0E8A" | "\u0E8D" | ["\u0E94"-"\u0E97"]
156 | ["\u0E99"-"\u0E9F"] | ["\u0EA1"-"\u0EA3"] | "\u0EA5" | "\u0EA7" | ["\u0EAA"-"\u0EAB"]
157 | ["\u0EAD"-"\u0EAE"] | "\u0EB0" | ["\u0EB2"-"\u0EB3"] | "\u0EBD" | ["\u0EC0"-"\u0EC4"]
158 | ["\u0F40"-"\u0F47"] | ["\u0F49"-"\u0F69"] | ["\u10A0"-"\u10C5"] | ["\u10D0"-"\u10F6"] | "\u1100"
159 | ["\u1102"-"\u1103"] | ["\u1105"-"\u1107"] | "\u1109" | ["\u110B"-"\u110C"] | ["\u110E"-"\u1112"]
160 | "\u113C" | "\u113E" | "\u1140" | "\u114C" | "\u114E" | "\u1150" | ["\u1154"-"\u1155"] | "\u1159"
161 | ["\u115F"-"\u1161"] | "\u1163" | "\u1165" | "\u1167" | "\u1169" | ["\u116D"-"\u116E"]
162 | ["\u1172"-"\u1173"] | "\u1175" | "\u119E" | "\u11A8" | "\u11AB" | ["\u11AE"-"\u11AF"]
163 | ["\u11B7"-"\u11B8"] | "\u11BA" | ["\u11BC"-"\u11C2"] | "\u11EB" | "\u11F0" | "\u11F9"
164 | ["\u1E00"-"\u1E9B"] | ["\u1EA0"-"\u1EF9"] | ["\u1F00"-"\u1F15"] | ["\u1F18"-"\u1F1D"]
165 | ["\u1F20"-"\u1F45"] | ["\u1F48"-"\u1F4D"] | ["\u1F50"-"\u1F57"] | "\u1F59" | "\u1F5B" | "\u1F5D"
166 | ["\u1F5F"-"\u1F7D"] | ["\u1F80"-"\u1FB4"] | ["\u1FB6"-"\u1FBC"] | "\u1FBE" | ["\u1FC2"-"\u1FC4"]
167 | ["\u1FC6"-"\u1FCC"] | ["\u1FD0"-"\u1FD3"] | ["\u1FD6"-"\u1FDB"] | ["\u1FE0"-"\u1FEC"]
168 | ["\u1FF2"-"\u1FF4"] | ["\u1FF6"-"\u1FFC"] | "\u2126" | ["\u212A"-"\u212B"] | "\u212E"
169 | ["\u2180"-"\u2182"] | ["\u3041"-"\u3094"] | ["\u30A1"-"\u30FA"] | ["\u3105"-"\u312C"]
170 | ["\uAC00"-"\uD7A3"] >
171 | < #IDEOGRAPHIC :
172 ["\u4E00"-"\u9FA5"] | "\u3007" | ["\u3021"-"\u3029"] >
173
174 | < #DIGIT: (["0"-"9"]) >
175
176
177 | < DOUBLE_QUOTE: "\"" >
178 | < PERCENT: "%" >
179 | < AMPERSAND: "&" >
180 | < QUOTE: "'" >
181 | < LEFT_PAREN: "(" >
182 | < RIGHT_PAREN: ")" >
183 | < ASTERISK: "*" >
184 | < PLUS_SIGN: "+" >
185 | < COMMA: "," >
186 | < MINUS_SIGN: "-" >
187 | < PERIOD: "." >
188 | < SOLIDUS: "/" >
189 | < COLON: ":" >
190 | < SEMICOLON: ";" >
191 | < LT_OPERATOR: "<" >
192 | < EQ_OPERATOR: "=" >
193 | < GT_OPERATOR: ">" >
194 | < QUESTION_MARK: "?" >
195 | < UNDERSCORE: "_" >
196 | < VERTICAL_BAR: "|" >
197
198 | < LEFT_BRACKET: "[" > // also special char?
199 | < RIGHT_BRACKET: "]" > // also special char?
200
201
202 | < REGULAR_IDENTIFIER: <IDENTIFIER_BODY> >
203 | < #IDENTIFIER_BODY: <IDENTIFIER_START> (<UNDERSCORE> | <COLON> | <IDENTIFIER_PART>)* >
204 | < #IDENTIFIER_START: <LETTER> > // syntax rules 5.2
205 | < #IDENTIFIER_PART: <IDENTIFIER_START> | <DIGIT> >
206
207 | < DELIMITED_IDENTIFIER: <DOUBLE_QUOTE> <DELIMITED_IDENTIFIER_BODY> <DOUBLE_QUOTE> >
208 | < #DELIMITED_IDENTIFIER_BODY: (<DELIMITED_IDENTIFIER_PART>)+ >
209 | < #DELIMITED_IDENTIFIER_PART: <NON_DOUBLE_QUOTE_CHAR> | <DOUBLE_QUOTE_SYMBOL> >
210 | < #NON_DOUBLE_QUOTE_CHAR: ~["\""] > // syntax rules 5.2
211 | < #DOUBLE_QUOTE_SYMBOL: <DOUBLE_QUOTE><DOUBLE_QUOTE> >
212
213 | < NE_OPERATOR: "<>" >
214 | < GE_OPERATOR: ">=" >
215 | < LE_OPERATOR: "<=" >
216 | < CONCAT_OPERATOR: "||" >
217 | < DOUBLE_PERIOD: ".." >
218
219 /*
220 | < COMMENT: <COMMENT_INTRO> (<COMMENT_CHAR>)* "\n" >
221 | < #COMMENT_CHAR: <NON_QUOTE_CHAR> | <QUOTE> >
222 | < #NON_QUOTE_CHAR: ~["'"] > // syntax rules
223 | < #COMMENT_INTRO: <MINUS_SIGN> <MINUS_SIGN> (<MINUS_SIGN>)* >
224 */
225
226 /* Literals */
227
228 | < EXACT_NUMERIC_LITERAL: (<SIGN>)? (<UNSIGNED_INTEGER> (<PERIOD> (<UNSIGNED_INTEGER>)?)?) | (<PERIOD> <UNSIGNED_INTEGER>) >
229 | < #SIGN: <PLUS_SIGN> | <MINUS_SIGN> >
230 | < APPROXIMATE_NUMERIC_LITERAL: <MANTISSA> ("E" | "e") <EXPONENT> >
231 | < #MANTISSA: <EXACT_NUMERIC_LITERAL> >
232 | < #EXPONENT: <SIGNED_INTEGER> >
233 | < #SIGNED_INTEGER: (<SIGN>)? <UNSIGNED_INTEGER> >
234 | < #UNSIGNED_INTEGER: (<DIGIT>)+ >
235 | < DATETIME_LITERAL: <DATE_LITERAL> | /* <TIME_LITERAL> | */ <TIMESTAMP_LITERAL> >
236 | < DATE_LITERAL: "DATE" (" ")+ <DATE_STRING> >
237 //| < TIME_LITERAL: "TIME" (" ")+ <TIME_STRING> > // not supported in jcr
238 | < TIMESTAMP_LITERAL: "TIMESTAMP" (" ")+ <TIMESTAMP_STRING> >
239 | < #DATE_STRING: <QUOTE> <DATE_VALUE> <QUOTE> >
240 // | < #TIME_STRING: <QUOTE> <TIME_VALUE> (<TIME_ZONE_INTERVAL>)? <QUOTE> > // not supported in jcr
241 | < #TIMESTAMP_STRING: <QUOTE> <DATE_VALUE> (" "|"T") <TIME_VALUE> (<TIME_ZONE_INTERVAL>)? <QUOTE> >
242 | < #TIME_ZONE_INTERVAL: "Z" | (<SIGN> <HOURS_VALUE> <COLON> <MINUTES_VALUE>) >
243 | < #DATE_VALUE: <YEARS_VALUE> <MINUS_SIGN> <MONTHS_VALUE> <MINUS_SIGN> <DAYS_VALUE> >
244 | < #TIME_VALUE: <HOURS_VALUE> <COLON> <MINUTES_VALUE> <COLON> <SECONDS_VALUE> >
245 | < #YEARS_VALUE: <DATETIME_VALUE> >
246 | < #MONTHS_VALUE: <DATETIME_VALUE> >
247 | < #DAYS_VALUE: <DATETIME_VALUE> >
248 | < #HOURS_VALUE: <DATETIME_VALUE> >
249 | < #MINUTES_VALUE: <DATETIME_VALUE> >
250 | < #SECONDS_VALUE: <SECONDS_INTEGER_VALUE> (<PERIOD> (<SECONDS_FRACTION>)?)? >
251 | < #SECONDS_INTEGER_VALUE: <UNSIGNED_INTEGER> >
252 | < #SECONDS_FRACTION: <UNSIGNED_INTEGER> >
253 | < #DATETIME_VALUE: <UNSIGNED_INTEGER> >
254
255 | < CHAR_STRING_LITERAL: <QUOTE> (<CHAR_REPRESENTATION>)* <QUOTE> >
256 | < #CHAR_REPRESENTATION: <NON_QUOTE_CHAR> | (<QUOTE_SYMBOL>) >
257 | < #QUOTE_SYMBOL: <QUOTE><QUOTE> >
258 }
259
260
261
262
263 // QUERY EXPRESSIONS, 7
264
265 ASTQuery Query() :
266 {}
267 {
268 <SELECT>
269 SelectList()
270 TableExpression()
271 [ OrderByClause() ]
272 <EOF>
273 { return jjtThis; }
274 }
275
276 void SelectList() :
277 {}
278 {
279 (<ASTERISK>)
280 | ( SelectItem() ( <COMMA> SelectItem() )* )
281 }
282
283 void SelectItem() #void :
284 {}
285 {
286 (ExcerptFunction() | Identifier() (<PERIOD> Identifier() { Node n = jjtree.popNode(); jjtree.popNode(); jjtree.pushNode(n); } )?)
287 }
288
289 void TableExpression() #void :
290 {}
291 {
292 FromClause()
293 [ WhereClause() ]
294 }
295
296 void FromClause() :
297 {}
298 {
299 <FROM> Identifier() (<COMMA> Identifier())*
300 }
301
302 void WhereClause() :
303 {}
304 {
305 <WHERE> SearchCondition()
306 }
307
308 // PREDICATES 8.1
309 void Predicate() :
310 {
311 int operationType;
312 Name identifier;
313 String value;
314 String escapeString;
315 }
316 {
317 (
318 (
319 (
320 (
321 identifier = Identifier() { jjtThis.setIdentifier(identifier); } ( <PERIOD> identifier = Identifier() { Node n = jjtree.popNode(); jjtree.popNode(); jjtree.pushNode(n); jjtThis.setIdentifier(identifier); } )?
322 )
323 |
324 (
325 identifier = PropertyFunction() { jjtThis.setIdentifier(identifier); }
326 )
327 )
328 (
329 (
330 operationType = ComparisonOperation() { jjtThis.setOperationType(operationType); }
331 (Literal() | (identifier = Identifier() { jjtThis.setIdentifier(identifier); } ( <PERIOD> identifier = Identifier() { Node n = jjtree.popNode(); jjtree.popNode(); jjtree.pushNode(n); jjtThis.setIdentifier(identifier); } )? ) )
332 )
333 |
334 ((<NOT> { jjtThis.setNegate(true); })?
335 (
336 (<BETWEEN> { jjtThis.setOperationType(QueryConstants.OPERATION_BETWEEN); } Literal() <AND> Literal())
337 |
338 (
339 <LIKE> { jjtThis.setOperationType(QueryConstants.OPERATION_LIKE); } value = CharStringLiteral()
340 {
341 ASTLiteral s = new ASTLiteral(JJTLITERAL);
342 s.setType(QueryConstants.TYPE_STRING);
343 s.setValue(value);
344 jjtree.pushNode(s);
345 }
346 (<ESCAPE> escapeString = CharStringLiteral() { jjtThis.setEscapeString(escapeString); })?
347 )
348 )
349 )
350 |
351 (<IS> (<NOT> { jjtThis.setNegate(true); })? <NULL>
352 {
353 jjtThis.setOperationType(jjtThis.isNegate() ? QueryConstants.OPERATION_NOT_NULL : QueryConstants.OPERATION_NULL);
354 }
355 )
356 )
357 )
358 |
359 (
360 Literal() (<NOT> { jjtThis.setNegate(true); })? <IN>
361 (
362 (
363 identifier = Identifier()
364 | identifier = PropertyFunction()
365 )
366 {
367 jjtThis.setIdentifier(identifier);
368 jjtThis.setOperationType(jjtThis.isNegate() ? QueryConstants.OPERATION_NE_GENERAL : QueryConstants.OPERATION_EQ_GENERAL);
369 }
370 )
371 )
372 |
373 (
374 <SIMILAR> "(" { jjtThis.setOperationType(QueryConstants.OPERATION_SIMILAR); }
375 ("." | identifier = Identifier() { jjtThis.setIdentifier(identifier); })
376 ","
377 value = CharStringLiteral()
378 {
379 ASTLiteral s = new ASTLiteral(JJTLITERAL);
380 s.setType(QueryConstants.TYPE_STRING);
381 s.setValue(value);
382 jjtree.pushNode(s);
383 } ")"
384 )
385 |
386 (
387 <SPELLCHECK> "(" { jjtThis.setOperationType(QueryConstants.OPERATION_SPELLCHECK); }
388 value = CharStringLiteral()
389 {
390 ASTLiteral stmt = new ASTLiteral(JJTLITERAL);
391 stmt.setType(QueryConstants.TYPE_STRING);
392 stmt.setValue(value);
393 jjtree.pushNode(stmt);
394 } ")"
395 )
396 )
397 }
398
399 Name PropertyFunction() #void :
400 {
401 Name identifier;
402 }
403 {
404 (
405 identifier = LowerFunction()
406 | identifier = UpperFunction()
407 )
408 {
409 return identifier;
410 }
411 }
412
413 Name LowerFunction() :
414 {
415 Name identifier;
416 }
417 {
418 (
419 <LOWER> "(" identifier = Identifier() ")"
420 )
421 {
422 return identifier;
423 }
424 }
425
426 Name UpperFunction() :
427 {
428 Name identifier;
429 }
430 {
431 (
432 <UPPER> "(" identifier = Identifier() ")"
433 )
434 {
435 return identifier;
436 }
437 }
438
439 int ComparisonOperation() #void :
440 {
441 int operationType;
442 }
443 {
444 (
445 <EQ_OPERATOR> { operationType = QueryConstants.OPERATION_EQ_GENERAL; }
446 | <NE_OPERATOR> { operationType = QueryConstants.OPERATION_NE_GENERAL; }
447 | <LT_OPERATOR> { operationType = QueryConstants.OPERATION_LT_GENERAL; }
448 | <GT_OPERATOR> { operationType = QueryConstants.OPERATION_GT_GENERAL; }
449 | <LE_OPERATOR> { operationType = QueryConstants.OPERATION_LE_GENERAL; }
450 | <GE_OPERATOR> { operationType = QueryConstants.OPERATION_GE_GENERAL; }
451 )
452 {
453 return operationType;
454 }
455 }
456
457
458 // SEARCH CONDITION 8.12
459 void SearchCondition() #void :
460 {}
461 {
462 OrExpression()
463 }
464
465 void OrExpression() #void :
466 {}
467 {
468 (
469 AndExpression() (<OR> AndExpression())*
470 ) #OrExpression(>1)
471 }
472
473 void AndExpression() #void :
474 {}
475 {
476 (
477 UnaryExpression() (<AND> UnaryExpression())*
478 ) #AndExpression(>1)
479 }
480
481 void UnaryExpression() #void :
482 {}
483 {
484 (
485 <NOT> UnaryExpression()
486 ) #NotExpression()
487 |
488 (
489 PrimaryExpression()
490 )
491 }
492
493 void PrimaryExpression() #void :
494 {}
495 {
496 (
497 Predicate()
498 )
499 |
500 (
501 BracketExpression()
502 )
503 |
504 (
505 ContainsExpression()
506 )
507 }
508
509 void BracketExpression() :
510 {}
511 {
512 <LEFT_PAREN> SearchCondition() <RIGHT_PAREN>
513 }
514
515 void ContainsExpression() :
516 {
517 Token t = null;
518 Name name = null;
519 }
520 {
521 <CONTAINS>
522 <LEFT_PAREN>
523 ( <ASTERISK> | <PERIOD> | (name = Identifier() { jjtThis.setPropertyName(name); }) ) ","
524 t = <CHAR_STRING_LITERAL> { jjtThis.setQuery(t.image.substring(1, t.image.length() - 1).replaceAll("''", "'")); }
525 <RIGHT_PAREN>
526 }
527
528 void Literal() :
529 {
530 Token t = null;
531 String value;
532 }
533 {
534 (
535 t = <APPROXIMATE_NUMERIC_LITERAL> { jjtThis.setType(QueryConstants.TYPE_DOUBLE); jjtThis.setValue(t.image); }
536 |
537 // can contain a dot -> use double
538 t = <EXACT_NUMERIC_LITERAL>
539 {
540 if (t.image.indexOf('.') > -1) {
541 jjtThis.setType(QueryConstants.TYPE_DOUBLE);
542 } else {
543 jjtThis.setType(QueryConstants.TYPE_LONG);
544 }
545 jjtThis.setValue(t.image);
546 }
547 |
548 value = CharStringLiteral() { jjtThis.setType(QueryConstants.TYPE_STRING); jjtThis.setValue(value); }
549 |
550 t = <DATETIME_LITERAL>
551 {
552 if (t.image.startsWith("TIMESTAMP")) {
553 jjtThis.setValue(t.image.substring(t.image.indexOf('\'') + 1, t.image.length() - 1));
554 if (jjtThis.getValue().indexOf(" ") == 10) {
555 // replace SQL 92 timesamp string with ISO8601
556 StringBuffer tmp = new StringBuffer();
557 tmp.append(jjtThis.getValue().substring(0, 10));
558 tmp.append("T").append(jjtThis.getValue().substring(11));
559 jjtThis.setValue(tmp.toString());
560 }
561 jjtThis.setType(QueryConstants.TYPE_TIMESTAMP);
562 /*
563 } else if (t.image.startsWith("TIME")) {
564 jjtThis.setValue(t.image.substring(t.image.indexOf('\'') + 1, t.image.length() - 1));
565 jjtThis.setType(QueryConstants.TYPE_TIME);
566 */
567 } else {
568 jjtThis.setValue(t.image.substring(t.image.indexOf('\'') + 1, t.image.length() - 1));
569 jjtThis.setType(QueryConstants.TYPE_DATE);
570 }
571 }
572 )
573 }
574
575 String CharStringLiteral() #void :
576 {
577 Token t;
578 String value = "";
579 }
580 {
581 (
582 t = <CHAR_STRING_LITERAL> { value += t.image.substring(1, t.image.length() - 1); } ( t = <CHAR_STRING_LITERAL> { value += t.image.substring(1, t.image.length() - 1); } )*
583 )
584 {
585 // strip any quote escapes
586 return value.replaceAll("''", "'");
587 }
588 }
589
590 Name Identifier() :
591 {
592 Token t = null;
593 Name name = null;
594 boolean pseudoProperty = false;
595 }
596 {
597 (
598 t = <REGULAR_IDENTIFIER> ( <LEFT_PAREN> <RIGHT_PAREN> { pseudoProperty = true; } ) ?
599 {
600 try {
601 String jcrName = t.image;
602 if (pseudoProperty) {
603 jcrName += "()";
604 }
605 jjtThis.setName(resolver.getQName(jcrName));
606 } catch (NameException e) {
607 throw new ParseException(e.getMessage());
608 } catch (NamespaceException e) {
609 throw new ParseException(e.getMessage());
610 }
611 }
612 |
613 t = <DELIMITED_IDENTIFIER>
614 {
615 try {
616 jjtThis.setName(resolver.getQName(t.image.substring(1, t.image.length()-1)));
617 } catch (NameException e) {
618 throw new ParseException(e.getMessage());
619 } catch (NamespaceException e) {
620 throw new ParseException(e.getMessage());
621 }
622 }
623 |
624 (
625 (
626 // or any keyword
627 t = <BY>
628 | t = <IN>
629 | t = <OR>
630 | t = <IS>
631 | t = <AND>
632 /*| <NOT>*/
633 | t = <LIKE>
634 | t = <NULL>
635 | t = <FROM>
636 | t = <ORDER>
637 | t = <WHERE>
638 | t = <SELECT>
639 | t = <BETWEEN>
640 )
641 {
642 try {
643 jjtThis.setName(resolver.getQName(t.image));
644 } catch (NameException e) {
645 throw new ParseException(e.getMessage());
646 } catch (NamespaceException e) {
647 throw new ParseException(e.getMessage());
648 }
649 }
650 )
651 )
652 {
653 return jjtThis.getName();
654 }
655 }
656
657 Name ExcerptFunction() :
658 {}
659 {
660 <EXCERPT> "(" <PERIOD> ")"
661 {
662 return NameFactoryImpl.getInstance().create(Name.NS_REP_URI, "excerpt(.)");
663 }
664 }
665
666 void OrderByClause() :
667 {}
668 {
669 <ORDER> <BY> OrderSpec() (<COMMA> OrderSpec())*
670 }
671
672 void OrderSpec() :
673 {}
674 {
675 Identifier() (AscendingOrderSpec() | DescendingOrderSpec())?
676 }
677
678 void AscendingOrderSpec() :
679 {}
680 {
681 <ASC>
682 }
683
684 void DescendingOrderSpec() :
685 {}
686 {
687 <DESC>
688 }