Debian Codegraph @

Modules/ThirdParty/VNL/src/vxl/v3p/netlib/lapack/double/dgecon.f

raw
1 SUBROUTINE DGECON( NORM, N, A, LDA, ANORM, RCOND, WORK, IWORK,
2 $ INFO )
3 *
4 * -- LAPACK routine (version 3.0) --
5 * Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
6 * Courant Institute, Argonne National Lab, and Rice University
7 * February 29, 1992
8 *
9 * .. Scalar Arguments ..
10 CHARACTER NORM
11 INTEGER INFO, LDA, N
12 DOUBLE PRECISION ANORM, RCOND
13 * ..
14 * .. Array Arguments ..
15 INTEGER IWORK( * )
16 DOUBLE PRECISION A( LDA, * ), WORK( * )
17 * ..
18 *
19 * Purpose
20 * =======
21 *
22 * DGECON estimates the reciprocal of the condition number of a general
23 * real matrix A, in either the 1-norm or the infinity-norm, using
24 * the LU factorization computed by DGETRF.
25 *
26 * An estimate is obtained for norm(inv(A)), and the reciprocal of the
27 * condition number is computed as
28 * RCOND = 1 / ( norm(A) * norm(inv(A)) ).
29 *
30 * Arguments
31 * =========
32 *
33 * NORM (input) CHARACTER*1
34 * Specifies whether the 1-norm condition number or the
35 * infinity-norm condition number is required:
36 * = '1' or 'O': 1-norm;
37 * = 'I': Infinity-norm.
38 *
39 * N (input) INTEGER
40 * The order of the matrix A. N >= 0.
41 *
42 * A (input) DOUBLE PRECISION array, dimension (LDA,N)
43 * The factors L and U from the factorization A = P*L*U
44 * as computed by DGETRF.
45 *
46 * LDA (input) INTEGER
47 * The leading dimension of the array A. LDA >= max(1,N).
48 *
49 * ANORM (input) DOUBLE PRECISION
50 * If NORM = '1' or 'O', the 1-norm of the original matrix A.
51 * If NORM = 'I', the infinity-norm of the original matrix A.
52 *
53 * RCOND (output) DOUBLE PRECISION
54 * The reciprocal of the condition number of the matrix A,
55 * computed as RCOND = 1/(norm(A) * norm(inv(A))).
56 *
57 * WORK (workspace) DOUBLE PRECISION array, dimension (4*N)
58 *
59 * IWORK (workspace) INTEGER array, dimension (N)
60 *
61 * INFO (output) INTEGER
62 * = 0: successful exit
63 * < 0: if INFO = -i, the i-th argument had an illegal value
64 *
65 * =====================================================================
66 *
67 * .. Parameters ..
68 DOUBLE PRECISION ONE, ZERO
69 PARAMETER ( ONE = 1.0D+0, ZERO = 0.0D+0 )
70 * ..
71 * .. Local Scalars ..
72 LOGICAL ONENRM
73 CHARACTER NORMIN
74 INTEGER IX, KASE, KASE1
75 DOUBLE PRECISION AINVNM, SCALE, SL, SMLNUM, SU
76 * ..
77 * .. External Functions ..
78 LOGICAL LSAME
79 INTEGER IDAMAX
80 DOUBLE PRECISION DLAMCH
81 EXTERNAL LSAME, IDAMAX, DLAMCH
82 * ..
83 * .. External Subroutines ..
84 EXTERNAL DLACON, DLATRS, DRSCL, XERBLA
85 * ..
86 * .. Intrinsic Functions ..
87 INTRINSIC ABS, MAX
88 * ..
89 * .. Executable Statements ..
90 *
91 * Test the input parameters.
92 *
93 INFO = 0
94 ONENRM = NORM.EQ.'1' .OR. LSAME( NORM, 'O' )
95 IF( .NOT.ONENRM .AND. .NOT.LSAME( NORM, 'I' ) ) THEN
96 INFO = -1
97 ELSE IF( N.LT.0 ) THEN
98 INFO = -2
99 ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
100 INFO = -4
101 ELSE IF( ANORM.LT.ZERO ) THEN
102 INFO = -5
103 END IF
104 IF( INFO.NE.0 ) THEN
105 CALL XERBLA( 'DGECON', -INFO )
106 RETURN
107 END IF
108 *
109 * Quick return if possible
110 *
111 RCOND = ZERO
112 IF( N.EQ.0 ) THEN
113 RCOND = ONE
114 RETURN
115 ELSE IF( ANORM.EQ.ZERO ) THEN
116 RETURN
117 END IF
118 *
119 SMLNUM = DLAMCH( 'Safe minimum' )
120 *
121 * Estimate the norm of inv(A).
122 *
123 AINVNM = ZERO
124 NORMIN = 'N'
125 IF( ONENRM ) THEN
126 KASE1 = 1
127 ELSE
128 KASE1 = 2
129 END IF
130 KASE = 0
131 10 CONTINUE
132 CALL DLACON( N, WORK( N+1 ), WORK, IWORK, AINVNM, KASE )
133 IF( KASE.NE.0 ) THEN
134 IF( KASE.EQ.KASE1 ) THEN
135 *
136 * Multiply by inv(L).
137 *
138 CALL DLATRS( 'Lower', 'No transpose', 'Unit', NORMIN, N, A,
139 $ LDA, WORK, SL, WORK( 2*N+1 ), INFO )
140 *
141 * Multiply by inv(U).
142 *
143 CALL DLATRS( 'Upper', 'No transpose', 'Non-unit', NORMIN, N,
144 $ A, LDA, WORK, SU, WORK( 3*N+1 ), INFO )
145 ELSE
146 *
147 * Multiply by inv(U').
148 *
149 CALL DLATRS( 'Upper', 'Transpose', 'Non-unit', NORMIN, N, A,
150 $ LDA, WORK, SU, WORK( 3*N+1 ), INFO )
151 *
152 * Multiply by inv(L').
153 *
154 CALL DLATRS( 'Lower', 'Transpose', 'Unit', NORMIN, N, A,
155 $ LDA, WORK, SL, WORK( 2*N+1 ), INFO )
156 END IF
157 *
158 * Divide X by 1/(SL*SU) if doing so will not cause overflow.
159 *
160 SCALE = SL*SU
161 NORMIN = 'Y'
162 IF( SCALE.NE.ONE ) THEN
163 IX = IDAMAX( N, WORK, 1 )
164 IF( SCALE.LT.ABS( WORK( IX ) )*SMLNUM .OR. SCALE.EQ.ZERO )
165 $ GO TO 20
166 CALL DRSCL( N, SCALE, WORK, 1 )
167 END IF
168 GO TO 10
169 END IF
170 *
171 * Compute the estimate of the reciprocal condition number.
172 *
173 IF( AINVNM.NE.ZERO )
174 $ RCOND = ( ONE / AINVNM ) / ANORM
175 *
176 20 CONTINUE
177 RETURN
178 *
179 * End of DGECON
180 *
181 END