Debian Codegraph @

src/python/config/ModuleDefine.cmake

raw
1 # SPDX-License-Identifier: BSD-3-Clause
2 # Copyright Contributors to the OpenEXR Project.
3
4 function(PYIMATH_ADD_LIBRARY_PRIV libname)
5 set(options)
6 set(oneValueArgs PRIV_EXPORT CURDIR CURBINDIR OUTROOT)
7 set(multiValueArgs SOURCE HEADERS DEPENDENCIES PRIVATE_DEPS)
8 cmake_parse_arguments(PYIMATH_CURLIB "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
9
10
11 # Currently, the python bindings REQUIRE a shared library for
12 # the Iex stuff to be initialized correctly. As such, force that
13 # here
14 # TODO Change this back when these bindings are refactored
15 add_library(${libname} SHARED ${PYIMATH_CURLIB_SOURCE})
16 #if(BUILD_SHARED_LIBS)
17 set_target_properties(${libname} PROPERTIES
18 SOVERSION ${IMATH_LIB_SOVERSION}
19 VERSION ${IMATH_LIB_VERSION}
20 )
21 #endif()
22 set_target_properties(${libname} PROPERTIES
23 OUTPUT_NAME "${PYIMATH_CURLIB_OUTROOT}${libname}${PYIMATH_LIB_SUFFIX}"
24 )
25 target_compile_features(${libname} PUBLIC cxx_std_${IMATH_CXX_STANDARD})
26 # we are always building shared, so don't check for that
27 if(PYIMATH_CURLIB_PRIV_EXPORT)
28 target_compile_definitions(${libname} PRIVATE ${PYIMATH_CURLIB_PRIV_EXPORT})
29 endif()
30 if(WIN32)
31 target_compile_definitions(${libname} PUBLIC IMATH_DLL)
32 endif()
33 if(PYIMATH_CURLIB_CURDIR)
34 target_include_directories(${libname} PUBLIC $<BUILD_INTERFACE:${PYIMATH_CURLIB_CURDIR}>)
35 endif()
36 if(PYIMATH_CURLIB_CURBINDIR)
37 target_include_directories(${libname} PRIVATE $<BUILD_INTERFACE:${PYIMATH_CURLIB_CURBINDIR}>)
38 endif()
39 if(Boost_INCLUDE_DIR)
40 target_include_directories(${libname} PUBLIC ${Boost_INCLUDE_DIR})
41 endif()
42 target_link_libraries(${libname} PUBLIC ${PYIMATH_CURLIB_DEPENDENCIES})
43 if(PYIMATH_CURLIB_PRIVATE_DEPS)
44 target_link_libraries(${libname} PRIVATE ${PYIMATH_CURLIB_PRIVATE_DEPS})
45 endif()
46 set_target_properties(${libname} PROPERTIES
47 CXX_STANDARD_REQUIRED ON
48 CXX_EXTENSIONS OFF
49 POSITION_INDEPENDENT_CODE ON
50 )
51
52 add_library(${PROJECT_NAME}::${libname} ALIAS ${libname})
53
54 install(TARGETS ${libname}
55 RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
56 LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
57 ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
58 )
59 endfunction()
60
61 # NB: This function has a number if specific names / variables
62 # not to mention behavior, so be careful copying...
63 function(PYIMATH_DEFINE_MODULE modname)
64 set(options NEEDED_BY_OTHER_MODULES)
65 set(oneValueArgs PRIV_EXPORT CURDIR CURBINDIR LIBNAME)
66 set(multiValueArgs LIBSOURCE MODSOURCE HEADERS DEPENDENCIES PRIVATE_DEPS MODULE_DEPS)
67 cmake_parse_arguments(PYIMATH_CURMOD "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
68
69 if(PYIMATH_CURMOD_HEADERS)
70 install(
71 FILES
72 ${PYIMATH_CURMOD_HEADERS}
73 DESTINATION
74 ${CMAKE_INSTALL_INCLUDEDIR}/${IMATH_OUTPUT_SUBDIR}
75 )
76 endif()
77
78 if(NOT PYIMATH_CURMOD_LIBNAME)
79 message(FATAL_ERROR "NYI usage of pyimath_define_module")
80 return()
81 endif()
82
83 set(libarglist SOURCE ${PYIMATH_CURMOD_LIBSOURCE})
84 if(PYIMATH_CURMOD_PRIV_EXPORT)
85 list(APPEND libarglist PRIV_EXPORT ${PYIMATH_CURMOD_PRIV_EXPORT})
86 endif()
87 if(PYIMATH_CURMOD_HEADERS)
88 list(APPEND libarglist HEADERS ${PYIMATH_CURMOD_HEADERS})
89 endif()
90 if(PYIMATH_CURMOD_CURDIR)
91 list(APPEND libarglist CURDIR ${PYIMATH_CURMOD_CURDIR})
92 endif()
93 if(PYIMATH_CURMOD_CURBINDIR)
94 list(APPEND libarglist CURBINDIR ${PYIMATH_CURMOD_CURBINDIR})
95 endif()
96 if(PYIMATH_CURMOD_DEPENDENCIES)
97 list(APPEND libarglist DEPENDENCIES ${PYIMATH_CURMOD_DEPENDENCIES})
98 endif()
99 # NB: make this one last so we can cheat and add the python and boost
100 # libs as private deps at the end regardless of whether it was provided
101 list(APPEND libarglist PRIVATE_DEPS ${PYIMATH_CURMOD_PRIVATE_DEPS})
102 if(USE_PYTHON2)
103 if(TARGET Python2::Python AND TARGET Boost::${PYIMATH_BOOST_PY_COMPONENT})
104 set(libname "${PYIMATH_CURMOD_LIBNAME}${PYIMATH_LIB_PYTHONVER_ROOT}${Python2_VERSION_MAJOR}_${Python2_VERSION_MINOR}")
105 set(extraDeps ${PYIMATH_CURMOD_MODULE_DEPS})
106 list(TRANSFORM extraDeps APPEND ${PYIMATH_LIB_PYTHONVER_ROOT}${Python2_VERSION_MAJOR}_${Python2_VERSION_MINOR})
107
108 pyimath_add_library_priv(${libname}
109 ${libarglist}
110 ${extraDeps}
111 Python2::Python
112 Boost::${PYIMATH_BOOST_PY_COMPONENT}
113 )
114
115 Python2_add_library(${modname}_python2 MODULE ${PYIMATH_CURMOD_MODSOURCE})
116 target_link_libraries(${modname}_python2
117 PRIVATE
118 ${libname}
119 ${extraDeps}
120 ${PYIMATH_CURMOD_DEPENDENCIES}
121 ${PYIMATH_CURMOD_PRIVATE_DEPS}
122 Boost::${PYIMATH_BOOST_PY_COMPONENT}
123 )
124 set_target_properties(${modname}_python2 PROPERTIES
125 LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/python${Python2_VERSION_MAJOR}_${Python2_VERSION_MINOR}/"
126 LIBRARY_OUTPUT_NAME "${modname}"
127 DEBUG_POSTFIX ""
128 )
129 install(TARGETS ${modname}_python2 DESTINATION ${PyImath_Python2_SITEARCH_REL})
130 endif()
131 else()
132 if(TARGET Python3::Python AND TARGET Boost::${PYIMATH_BOOST_PY_COMPONENT})
133 set(libname "${PYIMATH_CURMOD_LIBNAME}${PYIMATH_LIB_PYTHONVER_ROOT}${Python3_VERSION_MAJOR}_${Python3_VERSION_MINOR}")
134 set(extraDeps ${PYIMATH_CURMOD_MODULE_DEPS})
135 list(TRANSFORM extraDeps APPEND ${PYIMATH_LIB_PYTHONVER_ROOT}${Python3_VERSION_MAJOR}_${Python3_VERSION_MINOR})
136
137 pyimath_add_library_priv(${libname}
138 ${libarglist}
139 ${extraDeps}
140 Python3::Python
141 Boost::${PYIMATH_BOOST_PY_COMPONENT}
142 )
143 Python3_add_library(${modname}_python3 MODULE ${PYIMATH_CURMOD_MODSOURCE})
144 target_link_libraries(${modname}_python3
145 PRIVATE
146 ${libname} ${extraDeps}
147 ${PYIMATH_CURMOD_DEPENDENCIES}
148 ${PYIMATH_CURMOD_PRIVATE_DEPS}
149 Boost::${PYIMATH_BOOST_PY_COMPONENT}
150 )
151 set_target_properties(${modname}_python3 PROPERTIES
152 LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/python${Python3_VERSION_MAJOR}_${Python3_VERSION_MINOR}/"
153 LIBRARY_OUTPUT_NAME "${modname}"
154 DEBUG_POSTFIX ""
155 )
156 install(TARGETS ${modname}_python3 DESTINATION ${PyImath_Python3_SITEARCH_REL})
157 endif()
158 endif()
159 endfunction()