Debian Codegraph @

src/main/groovy/com/zeroc/gradle/icebuilder/slice/SlicePlugin.groovy

raw
1 // **********************************************************************
2 //
3 // Copyright (c) 2014-2017 ZeroC, Inc. All rights reserved.
4 //
5 // **********************************************************************
6
7 package com.zeroc.gradle.icebuilder.slice;
8
9 import org.gradle.api.logging.Logging
10 import org.gradle.api.NamedDomainObjectContainer
11 import org.gradle.api.Plugin
12 import org.gradle.api.Project
13 import org.gradle.api.UnknownTaskException
14
15 class SlicePlugin implements Plugin<Project> {
16 private static final def LOGGER = Logging.getLogger(SliceTask)
17
18 void apply(Project project) {
19 project.task('compileSlice', type: SliceTask) {
20 group = "Slice"
21 }
22
23 // Create and install the extension object.
24 project.extensions.create("slice", SliceExtension, project.container(Java))
25 project.extensions.slice.extensions.create("freezej",
26 Freezej,
27 project.container(Dict),
28 project.container(Index))
29
30 project.slice.output = project.file("${project.buildDir}/generated-src")
31
32 // Android projects do not define a 'compileJava' task. We wait until the project is evaluated
33 // and add our dependency to the variant's javaCompiler task.
34 if(isAndroidProject(project)) {
35 LOGGER.debug("Detected Android project: ${project}. Delaying applying task until project is evaluated")
36 project.afterEvaluate {
37 getAndroidVariants(project).all { variant ->
38 variant.registerJavaGeneratingTask(project.tasks.getByName('compileSlice'), project.slice.output)
39 }
40 }
41 } else {
42 project.tasks.getByName("compileJava").dependsOn('compileSlice');
43 project.sourceSets.main.java.srcDir project.slice.output
44 }
45 }
46
47 def isAndroidProject(Project project) {
48 return project.hasProperty('android') && project.android.sourceSets
49 }
50
51 def getAndroidVariants(Project project) {
52 // https://sites.google.com/a/android.com/tools/tech-docs/new-build-system/user-guide
53 return project.android.hasProperty('libraryVariants') ?
54 project.android.libraryVariants : project.android.applicationVariants
55 }
56 }