Debian Codegraph @

Formal_ineqs/trig/atn.hl

raw
1 (* ========================================================================== *)
2 (* Formal verification of nonlinear inequalities in HOL Light *)
3 (* *)
4 (* Copyright (c) 2011 Thomas C. Hales *)
5 (* Copyright (c) 2014 Alexey Solovyev *)
6 (* *)
7 (* This file is distributed under the terms of the MIT licence *)
8 (* ========================================================================== *)
9
10 (* -------------------------------------------------------------------------- *)
11 (* Formal interval evaluation of functions: atn (theory) *)
12 (* -------------------------------------------------------------------------- *)
13
14 needs "Formal_ineqs/trig/series.hl";;
15
16 module Atn = struct
17
18 open Series;;
19
20 prioritize_real();;
21
22 let halfatn = new_definition `halfatn x = x / (sqrt (&1 + x pow 2) + &1)`;;
23
24 let halfatn4 = new_definition `halfatn4 = halfatn o halfatn o halfatn o halfatn`;;
25
26 let abs_lemma = prove(`&0 < a ==> abs a = a`, REAL_ARITH_TAC);;
27
28 let pos_lemma = prove
29 (`!x. &0 < &1 + x pow 2`,
30 GEN_TAC THEN MATCH_MP_TAC (REAL_ARITH `&0 <= a ==> &0 < &1 + a`) THEN
31 REWRITE_TAC[REAL_LE_POW_2]);;
32
33 let pos_lemma2 = prove
34 (`!x. &0 < sqrt (&1 + x pow 2) + &1`,
35 GEN_TAC THEN MATCH_MP_TAC (REAL_ARITH `&0 <= a ==> &0 < a + &1`) THEN
36 SIMP_TAC[SQRT_LE_0; REAL_LT_IMP_LE; pos_lemma]);;
37
38 let eq_lemma = prove
39 (`!x. &1 - halfatn x pow 2 = &2 / (sqrt (&1 + x pow 2) + &1)`,
40 GEN_TAC THEN REWRITE_TAC[halfatn; REAL_POW_DIV] THEN
41 SUBGOAL_THEN `sqrt (&1 + x pow 2) pow 2 = &1 + x pow 2` MP_TAC THENL [
42 SIMP_TAC[REAL_SQRT_POW_2; abs_lemma; pos_lemma2; pos_lemma];
43 ALL_TAC
44 ] THEN
45 MP_TAC (SPEC `x:real` pos_lemma2) THEN
46 CONV_TAC REAL_FIELD);;
47
48 let halfatn_bounds_abs = prove
49 (`!x. abs (halfatn x) < &1`,
50 GEN_TAC THEN REWRITE_TAC[halfatn; REAL_ABS_DIV] THEN
51 SIMP_TAC[abs_lemma; pos_lemma2; REAL_LT_LDIV_EQ] THEN
52 MATCH_MP_TAC (REAL_ARITH `x < y ==> x < &1 * (y + &1)`) THEN
53 MATCH_MP_TAC REAL_LT_RSQRT THEN
54 REWRITE_TAC[REAL_POW2_ABS] THEN REAL_ARITH_TAC);;
55
56 let halfatn_half = prove
57 (`!x t. abs x < t ==> abs (halfatn x) < t / &2`,
58 REWRITE_TAC[halfatn; REAL_ABS_DIV] THEN REPEAT STRIP_TAC THEN
59 SIMP_TAC[abs_lemma; pos_lemma2; REAL_LT_LDIV_EQ] THEN
60 MATCH_MP_TAC REAL_LTE_TRANS THEN EXISTS_TAC `t:real` THEN
61 ASM_REWRITE_TAC[REAL_ARITH `t / &2 * a = t * (a / &2)`] THEN
62 MATCH_MP_TAC (REAL_ARITH `t * (&1 + &1) <= t * a ==> t <= t * (a / &2)`) THEN
63 MATCH_MP_TAC REAL_LE_LMUL THEN
64 CONJ_TAC THENL [ POP_ASSUM MP_TAC THEN REAL_ARITH_TAC; ALL_TAC ] THEN
65 REWRITE_TAC[REAL_LE_RADD] THEN
66 MATCH_MP_TAC REAL_LE_RSQRT THEN
67 MP_TAC (SPEC `x:real` REAL_LE_POW_2) THEN REAL_ARITH_TAC);;
68
69 let atn_half = prove
70 (`!x. atn x = &2 * atn (halfatn x)`,
71 GEN_TAC THEN REWRITE_TAC[REAL_MUL_2] THEN
72 SUBGOAL_THEN `abs (halfatn x * halfatn x) < &1` ASSUME_TAC THENL [
73 REWRITE_TAC[GSYM REAL_POW_2; REAL_ABS_POW; REAL_POW2_ABS] THEN
74 REWRITE_TAC[ABS_SQUARE_LT_1; halfatn_bounds_abs];
75 ALL_TAC
76 ] THEN
77 ASM_SIMP_TAC[ATN_ADD_SMALL; GSYM REAL_MUL_2; GSYM REAL_POW_2] THEN
78 AP_TERM_TAC THEN REWRITE_TAC[eq_lemma; halfatn] THEN
79 MP_TAC (SPEC `x:real` pos_lemma2) THEN
80 CONV_TAC REAL_FIELD);;
81
82 let rat_lemma4_lt = prove
83 (`!x1 y1 x2 y2. &0 < y1 /\ &0 < y2 ==> (x1 / y1 < x2 / y2 <=> x1 * y2 < x2 * y1)`,
84 REPEAT STRIP_TAC THEN
85 ASM_SIMP_TAC[REAL_LT_LDIV_EQ] THEN
86 ASM_SIMP_TAC[GSYM (SPECL[`x1:real`; `x2 / y2 * y1`; `y2:real`] REAL_LT_RMUL_EQ)] THEN
87 REWRITE_TAC[REAL_ARITH `(x2 / y2 * y1) * y2 = x2 * y1 * (y2 / y2)`] THEN
88 ASM_SIMP_TAC[REAL_DIV_REFL; REAL_ARITH `&0 < y2 ==> ~(y2 = &0)`; REAL_MUL_RID]);;
89
90 let halfatn_odd = prove
91 (`!x. halfatn (--x) = --halfatn x`,
92 REWRITE_TAC[halfatn; REAL_POW_NEG; TWO; EVEN; ONE; REAL_ARITH `--(a / b) = --a / b`]);;
93
94 let real_sgn_imp = prove
95 (`(!x. &0 < x ==> real_sgn x = &1) /\
96 (!x. x < &0 ==> real_sgn x = -- &1) /\
97 (!x. x = &0 ==> real_sgn x = &0)`,
98 REWRITE_TAC[REAL_SGN_EQ; real_gt]);;
99
100 let real_sgn_eq_pos = prove
101 (`!a b. (real_sgn a = real_sgn b) ==> (&0 <= a <=> &0 <= b)`,
102 REPEAT STRIP_TAC THEN ONCE_REWRITE_TAC[GSYM REAL_SGN_INEQS] THEN ASM_REWRITE_TAC[]);;
103
104 let real_sgn_eq_pos_lt = prove
105 (`!a b. (real_sgn a = real_sgn b) ==> (&0 < a <=> &0 < b)`,
106 REPEAT STRIP_TAC THEN ONCE_REWRITE_TAC[GSYM REAL_SGN_INEQS] THEN ASM_REWRITE_TAC[]);;
107
108 let halfatn_sgn = prove
109 (`!x. real_sgn (halfatn x) = real_sgn x`,
110 GEN_TAC THEN REWRITE_TAC[halfatn; REAL_SGN_DIV] THEN
111 SIMP_TAC[pos_lemma2; real_sgn_imp; REAL_DIV_1]);;
112
113 let halfatn_pos_eq = prove
114 (`!x. &0 <= halfatn x <=> &0 <= x`,
115 GEN_TAC THEN MATCH_MP_TAC real_sgn_eq_pos THEN REWRITE_TAC[halfatn_sgn]);;
116
117 let halfatn_pos_lt_eq = prove
118 (`!x. &0 < halfatn x <=> &0 < x`,
119 GEN_TAC THEN MATCH_MP_TAC real_sgn_eq_pos_lt THEN REWRITE_TAC[halfatn_sgn]);;
120
121 let halfatn_pos = prove
122 (`!x. &0 <= x ==> &0 <= halfatn x`,
123 GEN_TAC THEN REWRITE_TAC[halfatn] THEN DISCH_TAC THEN
124 MATCH_MP_TAC REAL_LE_DIV THEN ASM_SIMP_TAC[REAL_LT_IMP_LE; pos_lemma2]);;
125
126 let halfatn_neg = prove
127 (`!x. x < &0 ==> halfatn x < &0`,
128 GEN_TAC THEN ONCE_REWRITE_TAC[REAL_ARITH `a < &0 <=> &0 < --a`] THEN DISCH_TAC THEN
129 REWRITE_TAC[halfatn; REAL_ARITH `--(a / b) = --a / b`] THEN
130 MATCH_MP_TAC REAL_LT_DIV THEN ASM_SIMP_TAC[pos_lemma2]);;
131
132 let halfatn4_pos = prove
133 (`!x. &0 <= x ==> &0 <= halfatn4 x`,
134 REPEAT STRIP_TAC THEN REWRITE_TAC[halfatn4; o_THM] THEN
135 REPEAT (MATCH_MP_TAC halfatn_pos) THEN ASM_REWRITE_TAC[]);;
136
137 let halfatn4_pos_eq = prove
138 (`!x. &0 <= halfatn4 x <=> &0 <= x`,
139 REWRITE_TAC[halfatn4; o_THM; halfatn_pos_eq]);;
140
141 let halfatn4_pos_lt_eq = prove
142 (`!x. &0 < halfatn4 x <=> &0 < x`,
143 REWRITE_TAC[halfatn4; o_THM; halfatn_pos_lt_eq]);;
144
145 let halfatn_mono_lt = prove
146 (`!x y. x < y ==> halfatn x < halfatn y`,
147 SUBGOAL_THEN `!x y. &0 <= x /\ x < y ==> halfatn x < halfatn y` ASSUME_TAC THENL [
148 REWRITE_TAC[halfatn] THEN REPEAT STRIP_TAC THEN
149 SIMP_TAC[rat_lemma4_lt; pos_lemma2] THEN
150 REWRITE_TAC[REAL_ADD_LDISTRIB; REAL_MUL_RID] THEN
151 MATCH_MP_TAC REAL_LET_ADD2 THEN ASM_REWRITE_TAC[] THEN
152 SUBGOAL_THEN `!a. sqrt (&1 + a pow 2) = abs (sqrt (&1 + a pow 2))` (fun th -> ONCE_REWRITE_TAC[th]) THENL [
153 SIMP_TAC[abs_lemma; pos_lemma; SQRT_POS_LT];
154 ALL_TAC
155 ] THEN
156 SUBGOAL_THEN `abs y = y /\ abs x = x` ASSUME_TAC THENL [
157 ASM_ARITH_TAC;
158 ALL_TAC
159 ] THEN
160 FIRST_ASSUM (fun th -> ONCE_REWRITE_TAC[GSYM th]) THEN
161 REWRITE_TAC[GSYM REAL_ABS_MUL; REAL_LE_SQUARE_ABS; REAL_POW_MUL] THEN
162 ASM_SIMP_TAC[SQRT_POW_2; REAL_LT_IMP_LE; pos_lemma; REAL_ADD_LDISTRIB] THEN
163 REWRITE_TAC[REAL_MUL_LID; REAL_MUL_SYM; REAL_LE_RADD; GSYM REAL_LE_SQUARE_ABS] THEN
164 ASM_ARITH_TAC;
165 ALL_TAC
166 ] THEN
167 REPEAT STRIP_TAC THEN
168 ASM_CASES_TAC `y < &0` THENL [
169 ONCE_REWRITE_TAC[REAL_ARITH `a < b <=> --b < --a`] THEN REWRITE_TAC[GSYM halfatn_odd] THEN
170 FIRST_X_ASSUM MATCH_MP_TAC THEN ASM_ARITH_TAC;
171 ALL_TAC
172 ] THEN
173 ASM_CASES_TAC `x < &0` THENL [
174 MATCH_MP_TAC REAL_LTE_TRANS THEN EXISTS_TAC `&0` THEN
175 ASM_SIMP_TAC[halfatn_pos; halfatn_neg; REAL_ARITH `~(y < &0) ==> &0 <= y`];
176 ALL_TAC
177 ] THEN
178 FIRST_X_ASSUM MATCH_MP_TAC THEN ASM_ARITH_TAC);;
179
180 let halfatn_mono = prove
181 (`!x y. x <= y ==> halfatn x <= halfatn y`,
182 REWRITE_TAC[REAL_LE_LT] THEN REPEAT STRIP_TAC THEN ASM_SIMP_TAC[halfatn_mono_lt]);;
183
184 let atn_halfatn4 = prove
185 (`!x. atn x = &16 * atn(halfatn4 x)`,
186 ONCE_REWRITE_TAC[REAL_ARITH `&16 * x = &2 * &2 * &2 * &2 * x`] THEN
187 REWRITE_TAC[halfatn4; o_THM; GSYM atn_half]);;
188
189 let halfatn4_bound = prove
190 (`!x. abs (halfatn4 x) < inv (&8)`,
191 GEN_TAC THEN REWRITE_TAC[halfatn4; o_THM; REAL_ARITH `inv (&8) = &1 / &2 / &2 / &2`] THEN
192 REPEAT (MATCH_MP_TAC halfatn_half) THEN REWRITE_TAC[halfatn_bounds_abs]);;
193
194 let atn_series_alt_sign = prove
195 (`!x. abs x < &1 ==>
196 let f = (\i. (-- &1) pow i / &(2 * i + 1) * x pow (2 * i + 1)) in
197 (!n. abs (f (n + 1)) <= abs (f n) /\ f (n + 1) * f n <= &0) /\
198 ((f ---> &0) sequentially)`,
199 REPEAT STRIP_TAC THEN CONV_TAC let_CONV THEN
200 REWRITE_TAC[REAL_ABS_MUL; REAL_ABS_DIV] THEN
201 REWRITE_TAC[abs_neg_one_pow; ARITH_RULE `2 * (n + 1) + 1 = 2 * n + 3`] THEN
202 REWRITE_TAC[REAL_ABS_POW; REAL_ARITH `&1 / a * b = b / a`; REAL_ABS_NUM] THEN
203 SUBGOAL_THEN `!n. &0 < &(2 * n + 3) /\ &0 < &(2 * n + 1)` ASSUME_TAC THENL [
204 REWRITE_TAC[REAL_OF_NUM_LT] THEN ARITH_TAC;
205 ALL_TAC
206 ] THEN
207 REPEAT STRIP_TAC THENL [
208 ASM_SIMP_TAC[RAT_LEMMA4] THEN
209 MATCH_MP_TAC REAL_LE_MUL2 THEN REWRITE_TAC[REAL_POS] THEN
210 CONJ_TAC THENL [ MATCH_MP_TAC REAL_POW_LE THEN REWRITE_TAC[REAL_ABS_POS]; ALL_TAC ] THEN
211 REWRITE_TAC[REAL_OF_NUM_LE] THEN CONJ_TAC THENL [ ALL_TAC; ARITH_TAC ] THEN
212 MATCH_MP_TAC REAL_POW_MONO_INV THEN
213 ASM_SIMP_TAC[REAL_LT_IMP_LE; REAL_ABS_POS] THEN ARITH_TAC;
214 REWRITE_TAC[REAL_ARITH `((a / b) * c) * (d / e) * f = (a * d) * (c * f) / b / e`] THEN
215 REWRITE_TAC[GSYM REAL_POW_ADD; ARITH_RULE `(n + 1) + n = 2 * n + 1`] THEN
216 REWRITE_TAC[ARITH_RULE `(2 * n + 3) + 2 * n + 1 = (2 * n + 2) * 2`] THEN
217 REWRITE_TAC[REAL_POW_ADD; REAL_POW_1] THEN REWRITE_TAC[GSYM REAL_POW_POW] THEN
218 REWRITE_TAC[REAL_ARITH `-- &1 pow 2 = &1`; REAL_POW_ONE; REAL_MUL_LID] THEN
219 REWRITE_TAC[REAL_ARITH `-- &1 * x <= &0 <=> &0 <= x`] THEN
220 REPEAT (MATCH_MP_TAC REAL_LE_DIV THEN ASM_SIMP_TAC[REAL_LT_IMP_LE]) THEN
221 REWRITE_TAC[REAL_LE_POW_2];
222 MATCH_MP_TAC REAL_SERIES_TERMS_TOZERO THEN
223 MAP_EVERY EXISTS_TAC [`atn x`; `0`] THEN
224 ASM_SIMP_TAC[FROM_0; atn_series]
225 ]);;
226
227 let atn_poly_bound = prove
228 (`!n x. abs x < &1
229 ==> abs (atn x - sum (0..n) (\i. (-- &1 pow i / &(2 * i + 1)) * x pow (2 * i + 1)))
230 <= abs x pow (2 * n + 3) / &(2 * n + 3)`,
231 REPEAT STRIP_TAC THEN
232 MP_TAC (SPECL[`\i. (-- &1) pow i / &(2 * i + 1) * x pow (2 * i + 1)`; `0`; `n + 1`] alt_sign_abs_bound) THEN
233 ANTS_TAC THENL [
234 ASM_SIMP_TAC[CONV_RULE (DEPTH_CONV let_CONV) atn_series_alt_sign] THEN ARITH_TAC;
235 ALL_TAC
236 ] THEN
237 ASM_SIMP_TAC[atn_infsum; ARITH_RULE `(n + 1) - 1 = n`] THEN
238 REWRITE_TAC[REAL_ABS_MUL; REAL_ABS_DIV] THEN
239 REWRITE_TAC[abs_neg_one_pow; ARITH_RULE `2 * (n + 1) + 1 = 2 * n + 3`] THEN
240 REWRITE_TAC[REAL_ABS_POW; REAL_ARITH `&1 / a * b = b / a`; REAL_ABS_NUM]);;
241
242 let atn_poly_pos_upper_bound = prove
243 (`!x n. EVEN n /\ &0 <= x /\ x < &1
244 ==> atn x <= sum (0..n) (\i. ((-- &1) pow i / &(2 * i + 1)) * x pow (2 * i + 1))`,
245 REPEAT STRIP_TAC THEN
246 SUBGOAL_THEN `abs x < &1` ASSUME_TAC THENL [ ASM_ARITH_TAC; ALL_TAC ] THEN
247 ASM_CASES_TAC `n = 0` THENL [
248 MP_TAC (SPECL[`\i. (-- &1) pow i / &(2 * i + 1) * x pow (2 * i + 1)`; `0`] alt_sign_bound) THEN
249 ASM_SIMP_TAC[CONV_RULE (DEPTH_CONV let_CONV) atn_series_alt_sign] THEN
250 ASM_SIMP_TAC[atn_infsum; NUMSEG_SING; SUM_SING] THEN
251 REWRITE_TAC[real_pow; ARITH_RULE `2 * 0 + 1 = 1`; REAL_POW_1; REAL_ARITH `&1 / &1 * x = x`] THEN
252 ASM_SIMP_TAC[REAL_ARITH `&0 <= x ==> abs x = x`; ATN_POS_LE];
253 ALL_TAC
254 ] THEN
255 MP_TAC (SPECL[`n - 1`; `x:real`] atn_poly_bound) THEN ASM_REWRITE_TAC[] THEN
256 ASM_SIMP_TAC[SUM_CLAUSES_RIGHT; ARITH_RULE `~(n = 0) ==> 0 < n`; ARITH_RULE `0 <= n`] THEN
257 SUBGOAL_THEN `-- &1 pow n / &(2 * n + 1) * x pow (2 * n + 1) = abs x pow (2 * (n - 1) + 3) / &(2 * (n - 1) + 3)` ASSUME_TAC THENL [
258 ASM_REWRITE_TAC[REAL_POW_NEG; REAL_POW_ONE] THEN
259 ASM_SIMP_TAC[REAL_ARITH `&0 <= x ==> abs x = x`] THEN
260 ASM_SIMP_TAC[ARITH_RULE `~(n = 0) ==> 2 * (n - 1) + 3 = 2 * n + 1`] THEN
261 REAL_ARITH_TAC;
262 ALL_TAC
263 ] THEN
264 ASM_REWRITE_TAC[] THEN REAL_ARITH_TAC);;
265
266 let atn_poly_pos_lower_bound = prove
267 (`!x n. ODD n /\ &0 <= x /\ x < &1
268 ==> sum (0..n) (\i. ((-- &1) pow i / &(2 * i + 1)) * x pow (2 * i + 1)) <= atn x`,
269 REPEAT STRIP_TAC THEN
270 SUBGOAL_THEN `abs x < &1` ASSUME_TAC THENL [ ASM_ARITH_TAC; ALL_TAC ] THEN
271 ASM_CASES_TAC `n = 0` THENL [
272 UNDISCH_TAC `ODD n` THEN ASM_REWRITE_TAC[ODD];
273 ALL_TAC
274 ] THEN
275 MP_TAC (SPECL[`n - 1`; `x:real`] atn_poly_bound) THEN ASM_REWRITE_TAC[] THEN
276 ASM_SIMP_TAC[SUM_CLAUSES_RIGHT; ARITH_RULE `~(n = 0) ==> 0 < n`; ARITH_RULE `0 <= n`] THEN
277 SUBGOAL_THEN `-- &1 pow n / &(2 * n + 1) * x pow (2 * n + 1) = --(abs x pow (2 * (n - 1) + 3) / &(2 * (n - 1) + 3))` ASSUME_TAC THENL [
278 ASM_REWRITE_TAC[REAL_POW_NEG; GSYM NOT_ODD; REAL_POW_ONE] THEN
279 ASM_SIMP_TAC[REAL_ARITH `&0 <= x ==> abs x = x`] THEN
280 ASM_SIMP_TAC[ARITH_RULE `~(n = 0) ==> 2 * (n - 1) + 3 = 2 * n + 1`] THEN
281 REAL_ARITH_TAC;
282 ALL_TAC
283 ] THEN
284 ASM_REWRITE_TAC[] THEN REAL_ARITH_TAC);;
285
286 let atn_halfatn4_pos_upper_bound = prove
287 (`!x n. EVEN n /\ &0 <= x
288 ==> atn (halfatn4 x)
289 <= sum (0..n) (\i. ((-- &1) pow i / &(2 * i + 1)) * (halfatn4 x) pow (2 * i + 1))`,
290 REPEAT STRIP_TAC THEN MATCH_MP_TAC atn_poly_pos_upper_bound THEN
291 ASM_SIMP_TAC[halfatn4_pos; halfatn4_bound; REAL_ARITH `abs x < inv (&8) ==> x < &1`]);;
292
293 let atn_halfatn4_pos_lower_bound = prove
294 (`!x n. ODD n /\ &0 <= x
295 ==> sum (0..n) (\i. ((-- &1) pow i / &(2 * i + 1)) * (halfatn4 x) pow (2 * i + 1))
296 <= atn (halfatn4 x)`,
297 REPEAT STRIP_TAC THEN MATCH_MP_TAC atn_poly_pos_lower_bound THEN
298 ASM_SIMP_TAC[halfatn4_pos; halfatn4_bound; REAL_ARITH `abs x < inv (&8) ==> x < &1`]);;
299
300 let real_taylor_atn_halfatn4 = prove
301 (`!n x. abs (atn(halfatn4 x) -
302 sum (0..n) (\j. (-- &1 pow j) * halfatn4 x pow (2 * j + 1) / &(2 * j+ 1)))
303 <= inv (&8 pow (2 * n + 3) * &(2 * n + 3))`,
304 REPEAT GEN_TAC THEN ABBREV_TAC `y = halfatn4 x` THEN
305 SUBGOAL_THEN `abs y < inv (&8)` ASSUME_TAC THENL [
306 EXPAND_TAC "y" THEN REWRITE_TAC[halfatn4_bound];
307 ALL_TAC
308 ] THEN
309 MATCH_MP_TAC REAL_LE_TRANS THEN EXISTS_TAC `abs y pow (2 * n + 3) / &(2 * n + 3)` THEN
310 CONJ_TAC THENL [
311 SUBGOAL_THEN `abs y < &1` ASSUME_TAC THENL [ ASM_ARITH_TAC; ALL_TAC ] THEN
312 MP_TAC (SPECL[`n:num`; `y:real`] atn_poly_bound) THEN ASM_REWRITE_TAC[] THEN
313 REWRITE_TAC[REAL_ARITH `a * b / c = a / c * b`];
314 REWRITE_TAC[REAL_INV_MUL; real_div] THEN
315 MATCH_MP_TAC REAL_LE_RMUL THEN CONJ_TAC THENL [
316 REWRITE_TAC[REAL_INV_POW] THEN
317 MATCH_MP_TAC REAL_POW_LE2 THEN ASM_SIMP_TAC[REAL_ABS_POS; REAL_LT_IMP_LE];
318 MATCH_MP_TAC REAL_LE_INV THEN REWRITE_TAC[REAL_OF_NUM_LE] THEN ARITH_TAC
319 ]
320 ]);;
321
322 end;;