Debian Codegraph @

lib/hx509/sel-gram.y

raw
1 /*
2 * Copyright (c) 2017 Kungliga Tekniska Högskolan
3 * (Royal Institute of Technology, Stockholm, Sweden).
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 *
10 * 1. Redistributions of source code must retain the above copyright
11 * notice, this list of conditions and the following disclaimer.
12 *
13 * 2. Redistributions in binary form must reproduce the above copyright
14 * notice, this list of conditions and the following disclaimer in the
15 * documentation and/or other materials provided with the distribution.
16 *
17 * 3. Neither the name of the Institute nor the names of its contributors
18 * may be used to endorse or promote products derived from this software
19 * without specific prior written permission.
20 *
21 * THIS SOFTWARE IS PROVIDED BY THE INSTITUTE AND CONTRIBUTORS ``AS IS'' AND
22 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
23 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
24 * ARE DISCLAIMED. IN NO EVENT SHALL THE INSTITUTE OR CONTRIBUTORS BE LIABLE
25 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
26 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
27 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
28 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
29 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
30 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
31 * SUCH DAMAGE.
32 */
33
34 %{
35 #ifdef HAVE_CONFIG_H
36 #include <config.h>
37 #endif
38 #include <stdio.h>
39 #include <stdlib.h>
40 #include <hx_locl.h>
41
42 #if !defined(yylex)
43 #define yylex _hx509_sel_yylex
44 #define yywrap _hx509_sel_yywrap
45 #endif
46 #if !defined(yyparse)
47 #define yyparse _hx509_sel_yyparse
48 #define yyerror _hx509_sel_yyerror
49 #define yylval _hx509_sel_yylval
50 #define yychar _hx509_sel_yychar
51 #define yydebug _hx509_sel_yydebug
52 #define yynerrs _hx509_sel_yynerrs
53 #endif
54
55 %}
56
57 %union {
58 char *string;
59 struct hx_expr *expr;
60 }
61
62 %token kw_TRUE
63 %token kw_FALSE
64 %token kw_AND
65 %token kw_OR
66 %token kw_IN
67 %token kw_TAILMATCH
68
69 %type <expr> expr
70 %type <expr> comp
71 %type <expr> word words
72 %type <expr> number
73 %type <expr> string
74 %type <expr> function
75 %type <expr> variable variables
76
77 %token <string> NUMBER
78 %token <string> STRING
79 %token <string> IDENTIFIER
80
81 %start start
82
83 %%
84
85 start: expr { _hx509_expr_input.expr = $1; }
86
87 expr : kw_TRUE { $$ = _hx509_make_expr(op_TRUE, NULL, NULL); }
88 | kw_FALSE { $$ = _hx509_make_expr(op_FALSE, NULL, NULL); }
89 | '!' expr { $$ = _hx509_make_expr(op_NOT, $2, NULL); }
90 | expr kw_AND expr { $$ = _hx509_make_expr(op_AND, $1, $3); }
91 | expr kw_OR expr { $$ = _hx509_make_expr(op_OR, $1, $3); }
92 | '(' expr ')' { $$ = $2; }
93 | comp { $$ = _hx509_make_expr(op_COMP, $1, NULL); }
94 ;
95
96 words : word { $$ = _hx509_make_expr(expr_WORDS, $1, NULL); }
97 | word ',' words { $$ = _hx509_make_expr(expr_WORDS, $1, $3); }
98 ;
99
100 comp : word '=' '=' word { $$ = _hx509_make_expr(comp_EQ, $1, $4); }
101 | word '!' '=' word { $$ = _hx509_make_expr(comp_NE, $1, $4); }
102 | word kw_TAILMATCH word { $$ = _hx509_make_expr(comp_TAILEQ, $1, $3); }
103 | word kw_IN '(' words ')' { $$ = _hx509_make_expr(comp_IN, $1, $4); }
104 | word kw_IN variable { $$ = _hx509_make_expr(comp_IN, $1, $3); }
105 ;
106
107 word : number { $$ = $1; }
108 | string { $$ = $1; }
109 | function { $$ = $1; }
110 | variable { $$ = $1; }
111 ;
112
113 number : NUMBER { $$ = _hx509_make_expr(expr_NUMBER, $1, NULL); };
114 string : STRING { $$ = _hx509_make_expr(expr_STRING, $1, NULL); };
115
116 function: IDENTIFIER '(' words ')' {
117 $$ = _hx509_make_expr(expr_FUNCTION, $1, $3); }
118 ;
119 variable: '%' '{' variables '}' { $$ = $3; }
120 ;
121
122 variables: IDENTIFIER '.' variables {
123 $$ = _hx509_make_expr(expr_VAR, $1, $3); }
124 | IDENTIFIER {
125 $$ = _hx509_make_expr(expr_VAR, $1, NULL); }
126 ;