Debian Codegraph @

Network/Wai/Logger/Apache.hs

raw
1 {-# LANGUAGE OverloadedStrings, CPP, TupleSections #-}
2
3 module Network.Wai.Logger.Apache (
4 IPAddrSource(..)
5 , apacheLogStr
6 , serverpushLogStr
7 ) where
8
9 #ifndef MIN_VERSION_base
10 #define MIN_VERSION_base(x,y,z) 1
11 #endif
12 #ifndef MIN_VERSION_wai
13 #define MIN_VERSION_wai(x,y,z) 1
14 #endif
15
16 import Data.ByteString.Char8 (ByteString)
17 import qualified Data.ByteString.Char8 as BS
18 import Data.List (find)
19 import Data.Maybe (fromMaybe)
20 #if MIN_VERSION_base(4,5,0)
21 import Data.Monoid ((<>), First (..))
22 #else
23 import Data.Monoid (mappend)
24 #endif
25 import Network.HTTP.Types (Status, statusCode)
26 import Network.HTTP.Types.Header (HeaderName)
27 import Network.Wai (Request(..))
28 import Network.Wai.Logger.IP
29 import System.Log.FastLogger
30
31 -- $setup
32 -- >>> :set -XOverloadedStrings
33 -- >>> import Network.Wai (defaultRequest)
34
35 -- | Source from which the IP source address of the client is obtained.
36 data IPAddrSource =
37 -- | From the peer address of the HTTP connection.
38 FromSocket
39 -- | From @X-Real-IP@ or @X-Forwarded-For@ in the HTTP header.
40 --
41 -- This picks either @X-Real-IP@ or @X-Forwarded-For@ depending on which of these
42 -- headers comes first in the ordered list of request headers.
43 --
44 -- If the @X-Forwarded-For@ header is picked, the value will be assumed to be a
45 -- comma-separated list of IP addresses. The value will be parsed, and the
46 -- left-most IP address will be used (which is mostly likely to be the actual
47 -- client IP address).
48 | FromHeader
49 -- | From a custom HTTP header, useful in proxied environment.
50 --
51 -- The header value will be assumed to be a comma-separated list of IP
52 -- addresses. The value will be parsed, and the left-most IP address will be
53 -- used (which is mostly likely to be the actual client IP address).
54 --
55 -- Note that this still works as expected for a single IP address.
56 | FromHeaderCustom [HeaderName]
57 -- | Just like 'FromHeader', but falls back on the peer address if header is not found.
58 | FromFallback
59 -- | This gives you the most flexibility to figure out the IP source address
60 -- from the 'Request'. The returned 'ByteString' is used as the IP source
61 -- address.
62 | FromRequest (Request -> ByteString)
63
64 -- | Apache style log format.
65 apacheLogStr :: ToLogStr user => IPAddrSource -> (Request -> Maybe user) -> FormattedTime -> Request -> Status -> Maybe Integer -> LogStr
66 apacheLogStr ipsrc userget tmstr req status msize =
67 toLogStr (getSourceIP ipsrc req)
68 <> " - "
69 <> maybe "-" toLogStr (userget req)
70 <> " ["
71 <> toLogStr tmstr
72 <> "] \""
73 <> toLogStr (requestMethod req)
74 <> " "
75 <> toLogStr path
76 <> " "
77 <> toLogStr (show (httpVersion req))
78 <> "\" "
79 <> toLogStr (show (statusCode status))
80 <> " "
81 <> toLogStr (maybe "-" show msize)
82 <> " \""
83 <> toLogStr (fromMaybe "" mr)
84 <> "\" \""
85 <> toLogStr (fromMaybe "" mua)
86 <> "\"\n"
87 where
88 path = rawPathInfo req <> rawQueryString req
89 #if !MIN_VERSION_base(4,5,0)
90 (<>) = mappend
91 #endif
92 #if MIN_VERSION_wai(3,2,0)
93 mr = requestHeaderReferer req
94 mua = requestHeaderUserAgent req
95 #else
96 mr = lookup "referer" $ requestHeaders req
97 mua = lookup "user-agent" $ requestHeaders req
98 #endif
99
100 -- | HTTP/2 Push log format in the Apache style.
101 serverpushLogStr :: ToLogStr user => IPAddrSource -> (Request -> Maybe user) -> FormattedTime -> Request -> ByteString -> Integer -> LogStr
102 serverpushLogStr ipsrc userget tmstr req path size =
103 toLogStr (getSourceIP ipsrc req)
104 <> " - "
105 <> maybe "-" toLogStr (userget req)
106 <> " ["
107 <> toLogStr tmstr
108 <> "] \"PUSH "
109 <> toLogStr path
110 <> " HTTP/2\" 200 "
111 <> toLogStr (show size)
112 <> " \""
113 <> toLogStr ref
114 <> "\" \""
115 <> toLogStr (fromMaybe "" mua)
116 <> "\"\n"
117 where
118 ref = rawPathInfo req
119 #if !MIN_VERSION_base(4,5,0)
120 (<>) = mappend
121 #endif
122 #if MIN_VERSION_wai(3,2,0)
123 mua = requestHeaderUserAgent req
124 #else
125 mua = lookup "user-agent" $ requestHeaders req
126 #endif
127
128 getSourceIP :: IPAddrSource -> Request -> ByteString
129 getSourceIP FromSocket = getSourceFromSocket
130 getSourceIP FromHeader = getSourceFromHeader
131 getSourceIP FromFallback = getSourceFromFallback
132 getSourceIP (FromHeaderCustom hs) = fromMaybe "-" . getSourceFromHeaderCustom hs
133 getSourceIP (FromRequest fromReq) = fromReq
134
135 -- |
136 -- >>> getSourceFromSocket defaultRequest
137 -- "0.0.0.0"
138 getSourceFromSocket :: Request -> ByteString
139 getSourceFromSocket = BS.pack . showSockAddr . remoteHost
140
141 -- |
142 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("X-Real-IP", "127.0.0.1") ] }
143 -- "127.0.0.1"
144 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("X-Forwarded-For", "127.0.0.1") ] }
145 -- "127.0.0.1"
146 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("Something", "127.0.0.1") ] }
147 -- "-"
148 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [] }
149 -- "-"
150 --
151 -- 'getSourceFromHeader' uses the first instance of either @"X-Real-IP"@ or
152 -- @"X-Forwarded-For"@ that it finds in the ordered header list:
153 --
154 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("X-Real-IP", "1.2.3.4"), ("X-Forwarded-For", "5.6.7.8") ] }
155 -- "1.2.3.4"
156 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8"), ("X-Real-IP", "1.2.3.4") ] }
157 -- "5.6.7.8"
158 --
159 -- 'getSourceFromHeader' handles pulling out the first IP in the
160 -- comma-separated IP list in X-Forwarded-For:
161 --
162 -- >>> getSourceFromHeader defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8, 10.11.12.13, 1.2.3.4") ] }
163 -- "5.6.7.8"
164 getSourceFromHeader :: Request -> ByteString
165 getSourceFromHeader = fromMaybe "-" . getSource
166
167 -- |
168 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("X-Real-IP", "127.0.0.1") ] }
169 -- "127.0.0.1"
170 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("X-Forwarded-For", "127.0.0.1") ] }
171 -- "127.0.0.1"
172 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("Something", "127.0.0.1") ] }
173 -- "0.0.0.0"
174 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [] }
175 -- "0.0.0.0"
176 --
177 -- 'getSourceFromFallback' uses the first instance of either @"X-Real-IP"@ or
178 -- @"X-Forwarded-For"@ that it finds in the ordered header list:
179 --
180 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("X-Real-IP", "1.2.3.4"), ("X-Forwarded-For", "5.6.7.8") ] }
181 -- "1.2.3.4"
182 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8"), ("X-Real-IP", "1.2.3.4") ] }
183 -- "5.6.7.8"
184 --
185 -- 'getSourceFromFallback' handles pulling out the first IP in the
186 -- comma-separated IP list in X-Forwarded-For:
187 --
188 -- >>> getSourceFromFallback defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8, 10.11.12.13, 1.2.3.4") ] }
189 -- "5.6.7.8"
190 getSourceFromFallback :: Request -> ByteString
191 getSourceFromFallback req = fromMaybe (getSourceFromSocket req) $ getSource req
192
193 -- |
194 -- >>> getSource defaultRequest { requestHeaders = [ ("X-Real-IP", "127.0.0.1") ] }
195 -- Just "127.0.0.1"
196 -- >>> getSource defaultRequest { requestHeaders = [ ("X-Forwarded-For", "127.0.0.1") ] }
197 -- Just "127.0.0.1"
198 -- >>> getSource defaultRequest { requestHeaders = [ ("Something", "127.0.0.1") ] }
199 -- Nothing
200 -- >>> getSource defaultRequest
201 -- Nothing
202 --
203 -- 'getSource' uses the first instance of either @"X-Real-IP"@ or
204 -- @"X-Forwarded-For"@ that it finds in the ordered header list:
205 --
206 -- >>> getSource defaultRequest { requestHeaders = [ ("X-Real-IP", "1.2.3.4"), ("X-Forwarded-For", "5.6.7.8") ] }
207 -- Just "1.2.3.4"
208 -- >>> getSource defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8"), ("X-Real-IP", "1.2.3.4") ] }
209 -- Just "5.6.7.8"
210 --
211 -- 'getSource' handles pulling out the first IP in the comma-separated IP list
212 -- in X-Forwarded-For:
213 --
214 -- >>> getSource defaultRequest { requestHeaders = [ ("X-Forwarded-For", "5.6.7.8, 10.11.12.13, 1.2.3.4") ] }
215 -- Just "5.6.7.8"
216 getSource :: Request -> Maybe ByteString
217 getSource = getSourceFromHeaders [("x-real-ip", id), ("x-forwarded-for", firstIpInXFF)]
218
219 -- | Pull out the first IP in a comma-separated list of X-Forwarded-For IPs.
220 --
221 -- >>> firstIpInXFF "1.2.3.4, 5.6.7.8, 10.11.12.13"
222 -- "1.2.3.4"
223 --
224 -- If there are no commas, just return the whole input ByteString:
225 --
226 -- >>> firstIpInXFF "5.6.7.8"
227 -- "5.6.7.8"
228 --
229 -- Note that this function doesn't make sure the input is actually an IP address:
230 --
231 -- >>> firstIpInXFF "hello, world"
232 -- "hello"
233 firstIpInXFF :: ByteString -> ByteString
234 firstIpInXFF = BS.takeWhile (/= ',')
235
236 getSourceFromHeaders :: [(HeaderName, ByteString -> ByteString)] -> Request -> Maybe ByteString
237 getSourceFromHeaders headerNamesAndPostProc req = getFirst $ foldMap f $ requestHeaders req
238 where
239 -- Take a header name and value from the request, and try match it against
240 -- the list of headers and post-processing functions. If it matches,
241 -- return the ByteString resulting from applying the post-processing function
242 -- to the header value.
243 f :: (HeaderName, ByteString) -> First ByteString
244 f (headerNameFromReq, headerValFromReq) =
245 let maybePostProc = find (\(headerNameFromPostProc, _) -> headerNameFromReq == headerNameFromPostProc) headerNamesAndPostProc
246 in First $ fmap (\(_, postProc) -> postProc headerValFromReq) maybePostProc
247
248 -- |
249 -- >>> getSourceFromHeaderCustom ["x-foobar"] defaultRequest { requestHeaders = [ ("X-catdog", "1.2.3.4"), ("X-Foobar", "5.6.7.8"), ("Other", "1.1.1.1") ] }
250 -- Just "5.6.7.8"
251 --
252 -- If none of the headers in the passed-in list are in the 'Request', then return 'Nothing':
253 --
254 -- >>> getSourceFromHeaderCustom ["x-foobar", "baz"] defaultRequest { requestHeaders = [ ("abb", "1.2.3.4"), ("xyz", "5.6.7.8") ] }
255 -- Nothing
256 --
257 -- 'getSourceFromHeaderCustom' uses the first instance of any header in the
258 -- passed in list that it finds in the ordered header list from the request:
259 --
260 -- >>> getSourceFromHeaderCustom ["x-foobar", "baz"] defaultRequest { requestHeaders = [ ("baz", "1.2.3.4"), ("x-foobar", "5.6.7.8") ] }
261 -- Just "1.2.3.4"
262 --
263 -- 'getSourceFromHeaderCustom' splits the value of the header it finds by @,@
264 -- and uses the first item. This makes it easy to use with headers like
265 -- @X-Forwarded-For@, which are expected to have a comma-separated list of IP
266 -- addresses:
267 --
268 -- >>> getSourceFromHeaderCustom ["x-foobar"] defaultRequest { requestHeaders = [ ("X-Foobar", "5.6.7.8, 10.11.12.13, 1.2.3.4") ] }
269 -- Just "5.6.7.8"
270 getSourceFromHeaderCustom :: [HeaderName] -> Request -> Maybe ByteString
271 getSourceFromHeaderCustom hs = getSourceFromHeaders (fmap (,firstIpInXFF) hs)