Debian Codegraph @

src/Network/HTTP/Media/Language/Internal.hs

raw
1 -- | Defines the 'Language' accept header with an 'Accept' instance for use in
2 -- language negotiation.
3 module Network.HTTP.Media.Language.Internal
4 ( Language (..),
5 )
6 where
7
8 import Control.Monad (guard)
9 import Data.ByteString (ByteString)
10 import qualified Data.ByteString.Char8 as BS
11 import Data.CaseInsensitive (CI, original)
12 import qualified Data.CaseInsensitive as CI
13 import Data.Char (isAlpha, isAlphaNum)
14 import Data.List (isPrefixOf)
15 import Data.Maybe (fromMaybe)
16 import Data.String (IsString (..))
17 import Network.HTTP.Media.Accept (Accept (..))
18 import Network.HTTP.Media.RenderHeader (RenderHeader (..))
19
20 -- | Suitable for HTTP language-ranges as defined in
21 -- <https://tools.ietf.org/html/rfc4647#section-2.1 RFC4647>.
22 --
23 -- Specifically:
24 --
25 -- > language-range = (1*8ALPHA *("-" 1*8alphanum)) / "*"
26 newtype Language = Language [CI ByteString]
27 deriving (Eq, Ord)
28
29 -- Note that internally, Language [] equates to *.
30
31 instance Show Language where
32 show = BS.unpack . renderHeader
33
34 instance IsString Language where
35 fromString "*" = Language []
36 fromString str =
37 flip fromMaybe (parseAccept $ BS.pack str) $
38 error $
39 "Invalid language literal " ++ str
40
41 instance Accept Language where
42 parseAccept "*" = Just $ Language []
43 parseAccept bs = do
44 let pieces = BS.split '-' bs
45 guard $ not (null pieces)
46 Language <$> mapM check pieces
47 where
48 check part = do
49 let len = BS.length part
50 guard $
51 len >= 1
52 && len <= 8
53 && isAlpha (BS.head part)
54 && BS.all isAlphaNum (BS.tail part)
55 return (CI.mk part)
56
57 -- Languages match if the right argument is a prefix of the left.
58 matches (Language a) (Language b) = b `isPrefixOf` a
59
60 -- The left language is more specific than the right if the right
61 -- arguments is a strict prefix of the left.
62 moreSpecificThan (Language a) (Language b) =
63 b `isPrefixOf` a && length a > length b
64
65 instance RenderHeader Language where
66 renderHeader (Language []) = "*"
67 renderHeader (Language l) = BS.intercalate "-" (map original l)