Debian Codegraph @

strings/dup.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use types;
5
6 // Duplicates a string. The result must be freed after use.
7 export fn dup(s: const str) (str | nomem) = {
8 const in = &s: *types::string;
9 const id = match (in.data) {
10 case null =>
11 return ""; // Empty string
12 case let b: *[*]u8 =>
13 yield b;
14 };
15 let buf: []u8 = alloc(id[..in.length], in.length)?;
16 let out = types::string {
17 data = buf: *[*]u8,
18 length = in.length,
19 capacity = in.length,
20 };
21 return *(&out: *str);
22 };
23
24 // Creates a copy of a []str slice with all the strings duplicated. The result
25 // must be freed using [[freeall]].
26 export fn dupall(strs: []str) ([]str | nomem) = {
27 let newsl: []str = alloc([], len(strs))?;
28 let ok = false;
29 defer if (!ok) freeall(newsl);
30 for (let s .. strs) {
31 static append(newsl, dup(s)?)!;
32 };
33 ok = true;
34 return newsl;
35 };
36
37 // Frees all the strings in a slice and the slice itself. Inverse of [[dupall]].
38 export fn freeall(s: []str) void = {
39 for (let i = 0z; i < len(s); i += 1) {
40 free(s[i]);
41 };
42 free(s);
43 };
44
45 @test fn dup() void = {
46 let s = dup("")!;
47 defer free(s);
48 assert(s == "");
49
50 let s = dup("hello")!;
51 defer free(s);
52 assert(s == "hello");
53 };
54
55 @test fn dupall() void = {
56 const payload: []str = [];
57
58 let s = dupall(payload)!;
59 defer freeall(s);
60 assert(len(s) == len(payload));
61 for (let i = 0z; i < len(s); i += 1) {
62 assert(s[i] == payload[i]);
63 };
64
65 const payload: []str = ["a", "aaa"];
66
67 let s = dupall(payload)!;
68 defer freeall(s);
69 assert(len(s) == len(payload));
70 for (let i = 0z; i < len(s); i += 1) {
71 assert(s[i] == payload[i]);
72 };
73 };