Debian Codegraph @

os/exec/+netbsd/platform_cmd.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use errors;
5 use path;
6 use io;
7 use os;
8 use rt;
9 use strings;
10 use types::c;
11
12 export type platform_cmd = io::file;
13
14 fn platform_finish(cmd: *command) void = void;
15
16 export type strlist = []nullable *const c::char;
17
18 fn free_strlist(l: strlist) void = {
19 for (let i = 0z; i < len(l) - 1; i += 1) {
20 free(l[i]: *const c::char);
21 };
22 free(l);
23 };
24
25 export type platform_argv = strlist;
26
27 fn platform_newargv(name: str, args: str...) (platform_argv | nomem) = {
28 let ok = false;
29 let argv: platform_argv = alloc([null...], len(args) + 2z)?;
30 defer if (!ok) platform_free_argv(argv);
31
32 argv[0] = c::fromstr(name)?;
33
34 let i = 1z;
35 for (let arg .. args) {
36 argv[i] = c::fromstr(arg)?;
37 i += 1;
38 };
39
40 ok = true;
41 return argv;
42 };
43
44 fn platform_free_argv(argv: platform_argv) void = free_strlist(argv);
45
46 fn platform_setname(cmd: *command, name: str) (void | nomem) = {
47 cmd.argv[0] = c::fromstr(name)?;
48 };
49
50 export type platform_env = strlist;
51
52 fn platfrom_newenv() platform_env = [];
53
54 fn platform_dup_env(env: []str) (platform_env | nomem) = {
55 let ok = false;
56 let dup: platform_env = [];
57 defer if (!ok) platform_free_env(dup);
58
59 for (let e .. env) {
60 let centry = c::fromstr(e)?;
61 if (append(dup, centry) is nomem) {
62 free(centry);
63 return nomem;
64 };
65 };
66 append(dup, null)?;
67
68 ok = true;
69 return dup;
70 };
71
72 fn platform_free_env(env: platform_env) void = free_strlist(env);
73
74 fn platform_setenv(
75 cmd: *command,
76 key: str,
77 value: str
78 ) (void | errors::invalid | nomem) = {
79 if (len(cmd.env) == 0) {
80 append(cmd.env, null)?;
81 };
82
83 let entry = strings::join("=", key, value)?;
84 defer free(entry);
85 let centry = c::fromstr(entry)?;
86
87 if (insert(cmd.env[len(cmd.env)-1], centry) is nomem) {
88 free(centry);
89 return nomem;
90 };
91 };
92
93 fn platform_unsetenv(cmd: *command, key: str) (void | errors::invalid) = {
94 // XXX: This can be a binary search
95 for (let i = 0z; i < len(cmd.env) && cmd.env[i] != null; i += 1) {
96 let e = c::tostr(cmd.env[i]: *const c::char)!;
97 if (strings::cut(e, "=").0 == key) {
98 free(cmd.env[i]);
99 delete(cmd.env[i]);
100 break;
101 };
102 };
103 };
104
105 // Same as [[cmd]] except that executable file is determined by [[io::file]].
106 // This function is not portable.
107 export fn cmdfile(file: io::file, name: str, args: str...) (command | nomem) = {
108 let argv = platform_newargv(name, args...)?;
109
110 let env = match (platform_dup_env(os::getenvs())) {
111 case let env: platform_env =>
112 yield env;
113 case nomem =>
114 platform_free_argv(argv);
115 return nomem;
116 };
117
118 return command {
119 platform = file,
120 argv = argv,
121 env = env,
122 files = [],
123 dir = "",
124 };
125 };