Debian Codegraph @

net/dns/query.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use endian;
5 use errors;
6 use io;
7 use net;
8 use net::ip;
9 use net::tcp;
10 use net::udp;
11 use time;
12 use types;
13 use unix::poll;
14 use unix::resolvconf;
15
16 // TODO: Let user customize this?
17 def timeout: time::duration = 3 * time::SECOND;
18
19 // Performs a DNS query using the provided list of DNS servers. The caller must
20 // free the return value with [[message_free]].
21 //
22 // If no DNS servers are provided, the system default servers (if any) are used.
23 export fn query(query: *message, servers: ip::addr...) (*message | error | nomem) = {
24 if (len(servers) == 0) {
25 servers = resolvconf::load().nameservers;
26 };
27 if (len(servers) == 0) {
28 // Fall back to localhost
29 servers = [ip::LOCAL_V6, ip::LOCAL_V4];
30 };
31
32 let socket4 = udp::listen(ip::ANY_V4, 0)?;
33 defer net::close(socket4)!;
34 let socket6 = udp::listen(ip::ANY_V6, 0)?;
35 defer net::close(socket6)!;
36 const pollfd: [_]poll::pollfd = [
37 poll::pollfd {
38 fd = socket4,
39 events = poll::event::POLLIN,
40 ...
41 },
42 poll::pollfd {
43 fd = socket6,
44 events = poll::event::POLLIN,
45 ...
46 },
47 ];
48
49 let buf: [512]u8 = [0...];
50 let z = encode(buf, query)?;
51
52 // We send requests in parallel to all configured servers and take the
53 // first one which sends us a reasonable answer.
54 for (let i = 0z; i < len(servers); i += 1) match (servers[i]) {
55 case ip::addr4 =>
56 udp::sendto(socket4, buf[..z], servers[i], 53)?;
57 case ip::addr6 =>
58 udp::sendto(socket6, buf[..z], servers[i], 53)?;
59 };
60
61 let header = header { ... };
62 let src: ip::addr = ip::ANY_V4;
63 for (true) {
64 let nevent = match (poll::poll(pollfd, timeout)) {
65 case let nevent: uint =>
66 yield nevent;
67 case let e: poll::error =>
68 return e: io::error;
69 };
70 if (nevent == 0) {
71 return errors::timeout;
72 };
73
74 if (pollfd[0].revents & poll::event::POLLIN != 0) {
75 z = udp::recvfrom(socket4, buf, &src, null)?;
76 };
77 if (pollfd[1].revents & poll::event::POLLIN != 0) {
78 z = udp::recvfrom(socket6, buf, &src, null)?;
79 };
80
81 for (let s .. servers) {
82 if (ip::equal(src, s)) {
83 break;
84 };
85 } else continue;
86
87 const dec = decoder_init(buf[..z]);
88 decode_header(&dec, &header)?;
89 if (header.id == query.header.id && header.op.qr == qr::RESPONSE) {
90 break;
91 };
92 };
93
94 if (!header.op.tc) {
95 check_rcode(header.op.rcode)?;
96 return match (decode(buf[..z])) {
97 case let m: *message =>
98 return m;
99 case format =>
100 return format;
101 case nomem =>
102 return nomem;
103 };
104 };
105
106 // Response was truncated, retry over TCP. In TCP mode, the
107 // query is preceded by two bytes indicating the query length
108 z = encode(buf, query)?;
109 if (z > types::U16_MAX) {
110 return errors::overflow;
111 };
112 let zbuf: [2]u8 = [0...];
113 endian::beputu16(zbuf, z: u16);
114 let socket = tcp::connect(src, 53)?;
115 defer net::close(socket)!;
116
117 io::writeall(socket, zbuf)?;
118 io::writeall(socket, buf[..z])?;
119
120 let rz: u16 = match (io::readall(socket, zbuf)?) {
121 case let s: size =>
122 if (s != 2) {
123 return format;
124 };
125 yield endian::begetu16(zbuf);
126 case =>
127 return format;
128 };
129 let tcpbuf: []u8 = alloc([0...], rz)?;
130 defer free(tcpbuf);
131
132 match (io::readall(socket, tcpbuf)?) {
133 case let s: size =>
134 if (s != rz) {
135 return format;
136 };
137 case =>
138 return format;
139 };
140
141 const dec = decoder_init(tcpbuf);
142 decode_header(&dec, &header)?;
143 if ((header.id != query.header.id) || header.op.tc) {
144 return format;
145 };
146 check_rcode(header.op.rcode)?;
147 return match (decode(tcpbuf)) {
148 case let m: *message =>
149 return m;
150 case format =>
151 return format;
152 case nomem =>
153 return nomem;
154 };
155 };