Debian Codegraph @

debug/traces.ha

raw
1 // SPDX-License-Identifier: MPL-2.0
2 // (c) Hare authors <https://harelang.org>
3
4 use hash;
5 use hash::fnv;
6
7 def TRACE_BUCKETS = 65535;
8
9 let traces: [TRACE_BUCKETS][]trace = [[]...];
10
11 export type trace = struct {
12 id: u64,
13 frames: *stackframe,
14 };
15
16 // Retrives a stack trace by its ID.
17 export fn trace_by_id(id: u64) (stackframe | void) = {
18 let bucket = &traces[id % TRACE_BUCKETS];
19 for (let trace &.. bucket) {
20 if (trace.id == id) {
21 return *trace.frames;
22 };
23 };
24 };
25
26 // Stores a stack trace and returns its ID. Stored stack traces are hashed and
27 // de-duplicated in a global stack list.
28 export fn trace_store(frame: stackframe) (u64 | nomem) = {
29 static let pc: []uintptr = [];
30 pc = pc[..0];
31
32 const prev_heap = begin_altheap();
33 defer end_altheap(prev_heap);
34
35 const hash = fnv::fnv64a();
36 for (true) {
37 hash::write(&hash, &frame_pc(frame): *[size(uintptr)]u8);
38 append(pc, frame_pc(frame))?;
39
40 match (next(frame)) {
41 case let next: stackframe =>
42 frame = next;
43 case done => break;
44 };
45 };
46
47 const id = fnv::sum64(&hash);
48 let bucket = &traces[id % TRACE_BUCKETS];
49 for (let trace &.. bucket) {
50 if (trace.id == id) {
51 return id;
52 };
53 };
54
55 let frames: []stackframe = alloc([stackframe { ... }...], len(pc) + 1)?;
56 for (let i = 0z; i < len(pc); i += 1) {
57 frames[i] = mkframe(&frames[i + 1], pc[i]);
58 };
59
60 append(bucket, trace {
61 id = id,
62 frames = &frames[0],
63 })?;
64
65 return id;
66 };