Debian Codegraph @

demos/widget-factory/meson.build

raw
1 # demos/widget-factory
2
3 widgetfactory_resources = gnome.compile_resources('widgetfactory_resources',
4 'widget-factory.gresource.xml',
5 source_dir: meson.current_source_dir(),
6 )
7
8 executable('gtk4-widget-factory',
9 sources: ['widget-factory.c', widgetfactory_resources],
10 c_args: common_cflags,
11 dependencies: [ libgtk_dep, gmodule_headers_dep, profile_conf_h ],
12 include_directories: confinc,
13 win_subsystem: 'windows',
14 link_args: extra_demo_ldflags,
15 install: true,
16 )
17
18 # desktop file
19 install_data('org.gtk.WidgetFactory4.desktop', install_dir: gtk_applicationsdir)
20
21 # icons
22 icontheme_dir = join_paths(gtk_datadir, 'icons/hicolor')
23
24 foreach size: ['scalable', 'symbolic']
25 install_subdir('data/' + size, install_dir: icontheme_dir)
26 endforeach
27
28 # appdata
29 configure_file(
30 input: 'org.gtk.WidgetFactory4.appdata.xml.in',
31 output: 'org.gtk.WidgetFactory4.appdata.xml',
32 configuration: appdata_config,
33 install_dir: gtk_appdatadir
34 )
35
36 if bash.found()
37 install_data([ 'completion' ],
38 rename: [ 'gtk4-widget-factory' ],
39 install_dir: bash_comp_inst_dir,
40 install_tag: 'bin',
41 )
42 endif