Debian Codegraph @

demos/gtk-demo/neon.glsl

raw
1 // Originally from: https://www.shadertoy.com/view/WlByzy
2 // License CC0: Neonwave style road, sun and city
3 // The result of a bit of experimenting with neonwave style colors.
4
5 #define PI 3.141592654
6 #define TAU (2.0*PI)
7
8 #define TIME iTime
9 #define RESOLUTION iResolution
10
11 vec3 hsv2rgb(vec3 c) {
12 const vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
13 vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
14 return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
15 }
16
17 float hash(in float co) {
18 return fract(sin(co*12.9898) * 13758.5453);
19 }
20
21 float hash(in vec2 co) {
22 return fract(sin(dot(co.xy ,vec2(12.9898,58.233))) * 13758.5453);
23 }
24
25 float psin(float a) {
26 return 0.5 + 0.5*sin(a);
27 }
28
29 float mod1(inout float p, float size) {
30 float halfsize = size*0.5;
31 float c = floor((p + halfsize)/size);
32 p = mod(p + halfsize, size) - halfsize;
33 return c;
34 }
35
36 float circle(vec2 p, float r) {
37 return length(p) - r;
38 }
39
40 float box(vec2 p, vec2 b) {
41 vec2 d = abs(p)-b;
42 return length(max(d,0.0)) + min(max(d.x,d.y),0.0);
43 }
44
45 float planex(vec2 p, float w) {
46 return abs(p.y) - w;
47 }
48
49 float planey(vec2 p, float w) {
50 return abs(p.x) - w;
51 }
52
53 float pmin(float a, float b, float k) {
54 float h = clamp( 0.5+0.5*(b-a)/k, 0.0, 1.0 );
55 return mix( b, a, h ) - k*h*(1.0-h);
56 }
57
58 float pmax(float a, float b, float k) {
59 return -pmin(-a, -b, k);
60 }
61
62 float sun(vec2 p) {
63 const float ch = 0.0125;
64 vec2 sp = p;
65 vec2 cp = p;
66 mod1(cp.y, ch*6.0);
67
68 float d0 = circle(sp, 0.5);
69 float d1 = planex(cp, ch);
70 float d2 = p.y+ch*3.0;
71
72 float d = d0;
73 d = pmax(d, -max(d1, d2), ch*2.0);
74
75 return d;
76 }
77
78 float city(vec2 p) {
79 float sd = circle(p, 0.5);
80 float cd = 1E6;
81
82 const float count = 5.0;
83 const float width = 0.1;
84
85 for (float i = 0.0; i < count; ++i) {
86 vec2 pp = p;
87 pp.x += i*width/count;
88 float nn = mod1(pp.x, width);
89 float rr = hash(nn+sqrt(3.0)*i);
90 float dd = box(pp-vec2(0.0, -0.5), vec2(0.02, 0.35*(1.0-smoothstep(0.0, 5.0, abs(nn)))*rr+0.1));
91 cd = min(cd, dd);
92 }
93
94 return max(sd,cd);
95 }
96 vec3 sunEffect(vec2 p) {
97 float aa = 4.0 / RESOLUTION.y;
98
99 vec3 col = vec3(0.1);
100 vec3 skyCol1 = hsv2rgb(vec3(283.0/360.0, 0.83, 0.16));
101 vec3 skyCol2 = hsv2rgb(vec3(297.0/360.0, 0.79, 0.43));
102 col = mix(skyCol1, skyCol2, pow(clamp(0.5*(1.0+p.y+0.1*sin(4.0*p.x+TIME*0.5)), 0.0, 1.0), 4.0));
103
104 p.y -= 0.375;
105 float ds = sun(p);
106 float dc = city(p);
107
108 float dd = circle(p, 0.5);
109
110 vec3 sunCol = mix(vec3(1.0, 1.0, 0.0), vec3(1.0, 0.0, 1.0), clamp(0.5 - 1.0*p.y, 0.0, 1.0));
111 vec3 glareCol = sqrt(sunCol);
112 vec3 cityCol = sunCol*sunCol;
113
114 col += glareCol*(exp(-30.0*ds))*step(0.0, ds);
115
116
117 float t1 = smoothstep(0.0, 0.075, -dd);
118 float t2 = smoothstep(0.0, 0.3, -dd);
119 col = mix(col, sunCol, smoothstep(-aa, 0.0, -ds));
120 col = mix(col, glareCol, smoothstep(-aa, 0.0, -dc)*t1);
121 col += vec3(0.0, 0.25, 0.0)*(exp(-90.0*dc))*step(0.0, dc)*t2;
122
123 // col += 0.3*psin(d*400);
124
125 return col;
126 }
127
128 float ground(vec2 p) {
129 p.y += TIME*80.0;
130 p *= 0.075;
131 vec2 gp = p;
132 gp = fract(gp) - vec2(0.5);
133 float d0 = abs(gp.x);
134 float d1 = abs(gp.y);
135 float d2 = circle(gp, 0.05);
136
137 const float rw = 2.5;
138 const float sw = 0.0125;
139
140 vec2 rp = p;
141 mod1(rp.y, 12.0);
142 float d3 = abs(rp.x) - rw;
143 float d4 = abs(d3) - sw*2.0;
144 float d5 = box(rp, vec2(sw*2.0, 2.0));
145 vec2 sp = p;
146 mod1(sp.y, 4.0);
147 sp.x = abs(sp.x);
148 sp -= vec2(rw - 0.125, 0.0);
149 float d6 = box(sp, vec2(sw, 1.0));
150
151 float d = d0;
152 d = pmin(d, d1, 0.1);
153 d = max(d, -d3);
154 d = min(d, d4);
155 d = min(d, d5);
156 d = min(d, d6);
157
158 return d;
159 }
160
161 vec3 groundEffect(vec2 p) {
162 vec3 ro = vec3(0.0, 20.0, 0.0);
163 vec3 ww = normalize(vec3(0.0, -0.025, 1.0));
164 vec3 uu = normalize(cross(vec3(0.0,1.0,0.0), ww));
165 vec3 vv = normalize(cross(ww,uu));
166 vec3 rd = normalize(p.x*uu + p.y*vv + 2.5*ww);
167
168 float distg = (-9.0 - ro.y)/rd.y;
169
170 const vec3 shineCol = 0.75*vec3(0.5, 0.75, 1.0);
171 const vec3 gridCol = vec3(1.0);
172
173 vec3 col = vec3(0.0);
174 if (distg > 0.0) {
175 vec3 pg = ro + rd*distg;
176 float aa = length(dFdx(pg))*0.0002*RESOLUTION.x;
177
178 float dg = ground(pg.xz);
179
180 col = mix(col, gridCol, smoothstep(-aa, 0.0, -(dg+0.0175)));
181 col += shineCol*(exp(-10.0*clamp(dg, 0.0, 1.0)));
182 col = clamp(col, 0.0, 1.0);
183
184 // col += 0.3*psin(dg*100);
185 col *= pow(1.0-smoothstep(ro.y*3.0, 220.0+ro.y*2.0, distg), 2.0);
186 }
187
188 return col;
189 }
190
191 vec3 postProcess(vec3 col, vec2 q) {
192 col = clamp(col,0.0,1.0);
193 // col=pow(col,vec3(0.75));
194 col=col*0.6+0.4*col*col*(3.0-2.0*col);
195 col=mix(col, vec3(dot(col, vec3(0.33))), -0.4);
196 col*=0.5+0.5*pow(19.0*q.x*q.y*(1.0-q.x)*(1.0-q.y),0.7);
197 return col;
198 }
199
200 vec3 effect(vec2 p, vec2 q) {
201 vec3 col = vec3(0.0);
202
203 vec2 off = vec2(0.0, 0.0);
204
205 col += sunEffect(p+off);
206 col += groundEffect(p+off);
207
208 col = postProcess(col, q);
209 return col;
210 }
211
212 void mainImage(out vec4 fragColor, vec2 fragCoord) {
213 vec2 q = fragCoord/iResolution.xy;
214 vec2 p = -1. + 2. * q;
215 p.x *= RESOLUTION.x / RESOLUTION.y;
216
217 vec3 col = effect(p, q);
218
219 fragColor = vec4(col, 1.0);
220 }