Debian Codegraph @

libs/gst/controller/meson.build

raw
1 gst_controller_sources = files(
2 'gstargbcontrolbinding.c',
3 'gstdirectcontrolbinding.c',
4 'gsttimedvaluecontrolsource.c',
5 'gstinterpolationcontrolsource.c',
6 'gstproxycontrolbinding.c',
7 'gsttriggercontrolsource.c',
8 'gstlfocontrolsource.c',
9 )
10
11 controller_mkenum_headers = files(
12 'gstinterpolationcontrolsource.h',
13 'gstlfocontrolsource.h',
14 )
15
16 gst_controller_headers = controller_mkenum_headers + files(
17 'gstargbcontrolbinding.h',
18 'gstdirectcontrolbinding.h',
19 'gsttimedvaluecontrolsource.h',
20 'gstinterpolationcontrolsource.h',
21 'gstproxycontrolbinding.h',
22 'gsttriggercontrolsource.h',
23 'gstlfocontrolsource.h',
24 'controller-prelude.h',
25 'controller.h',
26 )
27 install_headers(gst_controller_headers, subdir : 'gstreamer-1.0/gst/controller/')
28
29 doc_sources = []
30 foreach s: gst_controller_sources + gst_controller_headers
31 doc_sources += s.full_path()
32 endforeach
33
34 libs_sources += {
35 'controller': pathsep.join(doc_sources)
36 }
37
38
39 controller_enums = gnome.mkenums_simple('controller-enumtypes',
40 sources : controller_mkenum_headers,
41 header_prefix : '#include <gst/controller/controller-prelude.h>',
42 body_prefix : '#include "config.h"',
43 decorator : 'GST_CONTROLLER_API',
44 install_header : true,
45 install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/controller'))
46 gstcontroller_c = controller_enums[0]
47 gstcontroller_h = controller_enums[1]
48
49 gst_controller_gen_sources = [gstcontroller_h]
50 gst_controller = library('gstcontroller-@0@'.format(api_version),
51 gst_controller_sources, gstcontroller_h, gstcontroller_c,
52 c_args : gst_c_args + ['-DBUILDING_GST_CONTROLLER', '-DG_LOG_DOMAIN="GStreamer-Controller"'],
53 install : true,
54 version : libversion,
55 soversion : soversion,
56 darwin_versions : osxversion,
57 include_directories : [configinc, libsinc],
58 dependencies : [mathlib, gst_dep],
59 )
60
61 library_def = {'lib': gst_controller}
62 pkg_name = 'gstreamer-controller-1.0'
63 pkgconfig.generate(gst_controller,
64 libraries : [libgst],
65 variables : pkgconfig_variables,
66 subdirs : pkgconfig_subdirs,
67 name : pkg_name,
68 description : 'Dynamic parameter control for GStreamer elements',
69 )
70
71 if build_gir
72 gst_gir_extra_args = gir_init_section + [ '--c-include=gst/controller/controller.h' ]
73 gir = {
74 'sources' : gst_controller_sources + gst_controller_headers + [gstcontroller_h] + [gstcontroller_c],
75 'namespace': 'GstController',
76 'nsversion': api_version,
77 'identifier_prefix' : 'Gst',
78 'symbol_prefix' : 'gst',
79 'export_packages' : pkg_name,
80 'dependencies' : [gst_dep],
81 'include_directories' : [configinc, libsinc, privinc],
82 'includes' : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gst-1.0'],
83 'install' : true,
84 'extra_args' : gst_gir_extra_args,
85 }
86 library_def += {'gir': [gir]}
87 if not static_build
88 gst_controller_gir = gnome.generate_gir(gst_controller, kwargs: gir)
89 library_def += {'gir_targets': library_def.get('gir_targets', []) + [gst_controller_gir]}
90 gst_controller_gen_sources += [gst_controller_gir]
91 endif
92 endif
93 gst_libraries += [[pkg_name, library_def]]
94
95 gst_controller_dep = declare_dependency(link_with : gst_controller,
96 include_directories : [libsinc],
97 sources: gst_controller_gen_sources,
98 dependencies : [gst_dep])
99
100 meson.override_dependency(pkg_name, gst_controller_dep)