Debian Codegraph @

glib/gio/tests/gdbus-object-manager-example/meson.build

raw
1 gdbus_example_objectmanager_visibility_h = configure_file(
2 output: 'gdbus-example-objectmanager-visibility.h',
3 command: [gen_visibility_macros, '2.0', 'visibility-macros',
4 'GDBUS_OBJECT_MANAGER_EXAMPLE', '@OUTPUT@'],
5 )
6
7 gdbus_example_objectmanager_xml = files('gdbus-example-objectmanager.xml')
8 gdbus_example_objectmanager_generated = custom_target('objectmanager-gen',
9 input : gdbus_example_objectmanager_xml,
10 output : ['objectmanager-gen.h',
11 'objectmanager-gen.c',
12 'objectmanager-gen-org.gtk.GDBus.Example.ObjectManager.Animal.xml',
13 'objectmanager-gen-org.gtk.GDBus.Example.ObjectManager.Cat.xml'],
14 command : [python, gdbus_codegen,
15 '--interface-prefix', 'org.gtk.GDBus.Example.ObjectManager.',
16 '--c-namespace', 'Example',
17 '--c-generate-object-manager',
18 '--output-directory', '@OUTDIR@',
19 '--generate-c-code', 'objectmanager-gen',
20 '--generate-docbook', 'objectmanager-gen',
21 '--symbol-decorator', 'GDBUS_OBJECT_MANAGER_EXAMPLE_AVAILABLE_IN_ALL',
22 '--symbol-decorator-header', 'gdbus-example-objectmanager-visibility.h',
23 '@INPUT@'],
24 depend_files : gdbus_codegen_built_files,
25 depends : gdbus_codegen_built_targets,
26 )
27
28 gdbus_example_objectmanager_rst_gen = custom_target('objectmanager-rst-gen',
29 input: gdbus_example_objectmanager_xml,
30 output: [
31 'objectmanager-rst-gen-org.gtk.GDBus.Example.ObjectManager.Animal.rst',
32 'objectmanager-rst-gen-org.gtk.GDBus.Example.ObjectManager.Cat.rst',
33 ],
34 command: [
35 python,
36 gdbus_codegen,
37 '--interface-prefix', 'org.gtk.GDBus.Example.ObjectManager.',
38 '--generate-rst', 'objectmanager-rst-gen',
39 '--output-directory', '@OUTDIR@',
40 '@INPUT@',
41 ],
42 depend_files: gdbus_codegen_built_files,
43 depends: gdbus_codegen_built_targets,
44 )
45
46 extra_c_args = []
47 if glib_build_static_only
48 extra_c_args = '-DGDBUS_OBJECT_MANAGER_EXAMPLE_STATIC_COMPILATION'
49 endif
50
51 libgdbus_example_objectmanager = library('gdbus-example-objectmanager',
52 gdbus_example_objectmanager_generated, gdbus_example_objectmanager_visibility_h,
53 c_args : [test_c_args, extra_c_args,
54 '-DGDBUS_OBJECT_MANAGER_EXAMPLE_COMPILATION'],
55 dependencies : [libglib_dep, libgmodule_dep, libgobject_dep, libgio_dep],
56 install : installed_tests_enabled,
57 install_dir : installed_tests_execdir)
58
59 libgdbus_example_objectmanager_dep = declare_dependency(
60 sources : [
61 gdbus_example_objectmanager_generated[0],
62 gdbus_example_objectmanager_rst_gen[0],
63 ],
64 link_with : libgdbus_example_objectmanager,
65 dependencies : [libgio_dep],
66 compile_args : extra_c_args,
67 )