Debian Codegraph @

proxy/libproxy/meson.build

raw
1 service_conf = configuration_data()
2 service_conf.set('libexecdir', libexecdir)
3
4 service = 'org.gtk.GLib.PACRunner.service'
5
6 configure_file(
7 input: service + '.in',
8 output: service,
9 install: true,
10 install_dir: join_paths(datadir, 'dbus-1', 'services'),
11 configuration: service_conf
12 )
13
14 service = 'glib-pacrunner.service'
15
16 configure_file(
17 input: service + '.in',
18 output: service,
19 install: true,
20 install_dir: join_paths('lib', 'systemd', 'user'),
21 configuration: service_conf
22 )
23
24 sources = files(
25 'glibproxyresolver.c',
26 'libproxy-module.c'
27 )
28
29 deps = [
30 gio_dep,
31 glib_dep,
32 gmodule_dep,
33 gobject_dep,
34 libproxy_dep
35 ]
36
37 giomodules += 'giolibproxy'
38
39 module = shared_module(
40 'giolibproxy',
41 sources: sources,
42 include_directories: top_inc,
43 dependencies: deps,
44 c_args: '-DGLIBPROXY_MODULE',
45 link_args: module_ldflags,
46 link_depends: symbol_map,
47 name_suffix: module_suffix,
48 install: build_shared,
49 install_dir: gio_module_dir
50 )
51
52 if build_static
53 giolibproxy_lib = static_library('giolibproxy',
54 objects: module.extract_all_objects(recursive: true),
55 dependencies: deps,
56 install: true,
57 install_dir: gio_module_dir
58 )
59 pkg.generate(module)
60
61 giolibproxy_dep = declare_dependency(link_with: giolibproxy_lib)
62 meson.override_dependency('giolibproxy', giolibproxy_dep)
63 endif
64
65 sources = files(
66 'glibproxyresolver.c',
67 'glibpacrunner.c'
68 )
69
70 executable(
71 'glib-pacrunner',
72 sources,
73 include_directories: top_inc,
74 dependencies: deps,
75 install: true,
76 install_dir: libexecdir
77 )
78
79 proxy_test_programs += [['environment', 'libproxy', deps]]
80
81 if meson.version().version_compare('>=0.58')
82 env = environment()
83 env.prepend('GIO_EXTRA_MODULES', meson.current_build_dir())
84 meson.add_devenv(env)
85 endif