Debian Codegraph @

libgcc/config/arm/cmse_nonsecure_call.S

raw
1 /* CMSE wrapper function used to save, clear and restore callee saved registers
2 for cmse_nonsecure_call's.
3
4 Copyright (C) 2016-2025 Free Software Foundation, Inc.
5 Contributed by ARM Ltd.
6
7 This file is free software; you can redistribute it and/or modify it
8 under the terms of the GNU General Public License as published by the
9 Free Software Foundation; either version 3, or (at your option) any
10 later version.
11
12 This file is distributed in the hope that it will be useful, but
13 WITHOUT ANY WARRANTY; without even the implied warranty of
14 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 General Public License for more details.
16
17 Under Section 7 of GPL version 3, you are granted additional
18 permissions described in the GCC Runtime Library Exception, version
19 3.1, as published by the Free Software Foundation.
20
21 You should have received a copy of the GNU General Public License and
22 a copy of the GCC Runtime Library Exception along with this program;
23 see the files COPYING3 and COPYING.RUNTIME respectively. If not, see
24 <http://www.gnu.org/licenses/>. */
25
26 .syntax unified
27 #ifdef __ARM_PCS_VFP
28 # if (__ARM_FP & 0x8) || (__ARM_FEATURE_MVE & 1)
29 .fpu fpv5-d16
30 # else
31 .fpu fpv4-sp-d16
32 # endif
33 #endif
34
35 .thumb
36 .type __gnu_cmse_nonsecure_call, %function
37 .global __gnu_cmse_nonsecure_call
38 __gnu_cmse_nonsecure_call:
39 #if defined(__ARM_ARCH_8M_MAIN__)
40 push {r5-r11,lr}
41 mov r7, r4
42 mov r8, r4
43 mov r9, r4
44 mov r10, r4
45 mov r11, r4
46 mov ip, r4
47
48 /* Save and clear callee-saved registers only if we are dealing with hard float
49 ABI. The unused caller-saved registers have already been cleared by GCC
50 generated code. */
51 #ifdef __ARM_PCS_VFP
52 vpush.f64 {d8-d15}
53 mov r5, #0
54 vmov d8, r5, r5
55 #if __ARM_FP & 0x04
56 vmov s18, s19, r5, r5
57 vmov s20, s21, r5, r5
58 vmov s22, s23, r5, r5
59 vmov s24, s25, r5, r5
60 vmov s26, s27, r5, r5
61 vmov s28, s29, r5, r5
62 vmov s30, s31, r5, r5
63 #elif (__ARM_FP & 0x8) || (__ARM_FEATURE_MVE & 1)
64 vmov.f64 d9, d8
65 vmov.f64 d10, d8
66 vmov.f64 d11, d8
67 vmov.f64 d12, d8
68 vmov.f64 d13, d8
69 vmov.f64 d14, d8
70 vmov.f64 d15, d8
71 #else
72 #error "Half precision implementation not supported."
73 #endif
74 /* Clear the cumulative exception-status bits (0-4,7) and the
75 condition code bits (28-31) of the FPSCR. */
76 vmrs r5, fpscr
77 movw r6, #65376
78 movt r6, #4095
79 ands r5, r6
80 vmsr fpscr, r5
81
82 /* We are not dealing with hard float ABI, so we can safely use the vlstm and
83 vlldm instructions without needing to preserve the registers used for
84 argument passing. */
85 #else
86 sub sp, sp, #0x88 /* Reserve stack space to save all floating point
87 registers, including FPSCR. */
88 vlstm sp /* Lazy store and clearance of d0-d16 and FPSCR. */
89 #endif /* __ARM_PCS_VFP */
90
91 /* Make sure to clear the 'GE' bits of the APSR register if 32-bit SIMD
92 instructions are available. */
93 #if defined(__ARM_FEATURE_SIMD32)
94 msr APSR_nzcvqg, r4
95 #else
96 msr APSR_nzcvq, r4
97 #endif
98
99 mov r5, r4
100 mov r6, r4
101 blxns r4
102
103 #ifdef __ARM_PCS_VFP
104 vpop.f64 {d8-d15}
105 #else
106 /* VLLDM erratum mitigation sequence. */
107 mrs r5, control
108 tst r5, #8 /* CONTROL_S.SFPA */
109 it ne
110 .inst.w 0xeeb00a40 /* vmovne s0, s0 */
111 vlldm sp /* Lazy restore of d0-d16 and FPSCR. */
112 add sp, sp, #0x88 /* Free space used to save floating point registers. */
113 #endif /* __ARM_PCS_VFP */
114
115 pop {r5-r11, pc}
116
117 #elif defined (__ARM_ARCH_8M_BASE__)
118 push {r5-r7, lr}
119 mov r5, r8
120 mov r6, r9
121 mov r7, r10
122 push {r5-r7}
123 mov r5, r11
124 push {r5}
125 mov r5, r4
126 mov r6, r4
127 mov r7, r4
128 mov r8, r4
129 mov r9, r4
130 mov r10, r4
131 mov r11, r4
132 mov ip, r4
133 msr APSR_nzcvq, r4
134 blxns r4
135 pop {r5}
136 mov r11, r5
137 pop {r5-r7}
138 mov r10, r7
139 mov r9, r6
140 mov r8, r5
141 pop {r5-r7, pc}
142
143 #else
144 #error "This should only be used for armv8-m base- and mainline."
145 #endif
146 .size __gnu_cmse_nonsecure_call, .-__gnu_cmse_nonsecure_call