| 1 |
/* Support routine for SME. |
| 2 |
Copyright (C) 2023-2025 Free Software Foundation, Inc. |
| 3 |
|
| 4 |
This file is part of GCC. |
| 5 |
|
| 6 |
GCC is free software; you can redistribute it and/or modify it |
| 7 |
under the terms of the GNU General Public License as published |
| 8 |
by the Free Software Foundation; either version 3, or (at your |
| 9 |
option) any later version. |
| 10 |
|
| 11 |
GCC is distributed in the hope that it will be useful, but WITHOUT |
| 12 |
ANY WARRANTY; without even the implied warranty of MERCHANTABILITY |
| 13 |
or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public |
| 14 |
License for more details. |
| 15 |
|
| 16 |
Under Section 7 of GPL version 3, you are granted additional |
| 17 |
permissions described in the GCC Runtime Library Exception, version |
| 18 |
3.1, as published by the Free Software Foundation. |
| 19 |
|
| 20 |
You should have received a copy of the GNU General Public License and |
| 21 |
a copy of the GCC Runtime Library Exception along with this program; |
| 22 |
see the files COPYING3 and COPYING.RUNTIME respectively. If not, see |
| 23 |
<http://www.gnu.org/licenses/>. */ |
| 24 |
|
| 25 |
#include "aarch64-asm.h" |
| 26 |
|
| 27 |
/* Used for lazy ZA restore. Call ABI: |
| 28 |
- Shared ZA, streaming-compatible. |
| 29 |
- x0 is a pointer to a TPIDR2 block. |
| 30 |
- x0-x13, x19-x29, sp and fp regs are call preserved. |
| 31 |
- Does not return a value. |
| 32 |
- Can abort on failure (then registers are not preserved). */ |
| 33 |
|
| 34 |
variant_pcs (__arm_tpidr2_restore) |
| 35 |
|
| 36 |
ENTRY (__arm_tpidr2_restore) |
| 37 |
.inst 0xd53bd0ae /* mrs x14, tpidr2_el0 */ |
| 38 |
cbnz x14, L(fail) |
| 39 |
|
| 40 |
/* check reserved bytes. */ |
| 41 |
ldrh w15, [x0, 10] |
| 42 |
ldr w16, [x0, 12] |
| 43 |
orr w15, w15, w16 |
| 44 |
cbnz w15, L(fail) |
| 45 |
|
| 46 |
ldr x16, [x0] |
| 47 |
cbz x16, L(end) |
| 48 |
ldrh w17, [x0, 8] |
| 49 |
cbz w17, L(end) |
| 50 |
|
| 51 |
/* x0: blk, x14: 0, x15: 0, |
| 52 |
x16: za_save_buffer, x17: num_za_save_slices. */ |
| 53 |
|
| 54 |
L(restore_loop): |
| 55 |
.inst 0xe1006200 /* ldr za[w15, 0], [x16] */ |
| 56 |
.inst 0xe1006201 /* ldr za[w15, 1], [x16, 1, mul vl] */ |
| 57 |
.inst 0xe1006202 /* ldr za[w15, 2], [x16, 2, mul vl] */ |
| 58 |
.inst 0xe1006203 /* ldr za[w15, 3], [x16, 3, mul vl] */ |
| 59 |
.inst 0xe1006204 /* ldr za[w15, 4], [x16, 4, mul vl] */ |
| 60 |
.inst 0xe1006205 /* ldr za[w15, 5], [x16, 5, mul vl] */ |
| 61 |
.inst 0xe1006206 /* ldr za[w15, 6], [x16, 6, mul vl] */ |
| 62 |
.inst 0xe1006207 /* ldr za[w15, 7], [x16, 7, mul vl] */ |
| 63 |
.inst 0xe1006208 /* ldr za[w15, 8], [x16, 8, mul vl] */ |
| 64 |
.inst 0xe1006209 /* ldr za[w15, 9], [x16, 9, mul vl] */ |
| 65 |
.inst 0xe100620a /* ldr za[w15, 10], [x16, 10, mul vl] */ |
| 66 |
.inst 0xe100620b /* ldr za[w15, 11], [x16, 11, mul vl] */ |
| 67 |
.inst 0xe100620c /* ldr za[w15, 12], [x16, 12, mul vl] */ |
| 68 |
.inst 0xe100620d /* ldr za[w15, 13], [x16, 13, mul vl] */ |
| 69 |
.inst 0xe100620e /* ldr za[w15, 14], [x16, 14, mul vl] */ |
| 70 |
.inst 0xe100620f /* ldr za[w15, 15], [x16, 15, mul vl] */ |
| 71 |
add w15, w15, 16 |
| 72 |
.inst 0x04305a10 /* addsvl x16, x16, 16 */ |
| 73 |
cmp w17, w15 |
| 74 |
bhi L(restore_loop) |
| 75 |
L(end): |
| 76 |
ret |
| 77 |
L(fail): |
| 78 |
PACIASP |
| 79 |
stp x29, x30, [sp, -32]! |
| 80 |
.cfi_adjust_cfa_offset 32 |
| 81 |
.cfi_rel_offset x29, 0 |
| 82 |
.cfi_rel_offset x30, 8 |
| 83 |
mov x29, sp |
| 84 |
.inst 0x04e0e3f0 /* cntd x16 */ |
| 85 |
str x16, [sp, 16] |
| 86 |
.cfi_rel_offset 46, 16 |
| 87 |
.inst 0xd503467f /* smstop */ |
| 88 |
bl abort |
| 89 |
END (__arm_tpidr2_restore) |