Debian Codegraph @

src/libparam.scm

raw
1 ;;;
2 ;;; libparam.scm - Parameters
3 ;;;
4 ;;; Copyright (c) 2020-2024 Shiro Kawai <[email protected]>
5 ;;;
6 ;;; Redistribution and use in source and binary forms, with or without
7 ;;; modification, are permitted provided that the following conditions
8 ;;; are met:
9 ;;;
10 ;;; 1. Redistributions of source code must retain the above copyright
11 ;;; notice, this list of conditions and the following disclaimer.
12 ;;;
13 ;;; 2. Redistributions in binary form must reproduce the above copyright
14 ;;; notice, this list of conditions and the following disclaimer in the
15 ;;; documentation and/or other materials provided with the distribution.
16 ;;;
17 ;;; 3. Neither the name of the authors nor the names of its contributors
18 ;;; may be used to endorse or promote products derived from this
19 ;;; software without specific prior written permission.
20 ;;;
21 ;;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22 ;;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23 ;;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
24 ;;; A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
25 ;;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
26 ;;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
27 ;;; TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
28 ;;; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
29 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
30 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
31 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
32 ;;;
33
34 ;; NB: This must be initialized _after_ the object and marco system fully
35 ;; booted.
36
37 (select-module gauche)
38 (use util.match)
39
40 (inline-stub
41 (.include "gauche/priv/configP.h"
42 "gauche/priv/parameterP.h"
43 "gauche/priv/vmP.h"))
44
45 (declare (keep-private-macro parameterize parameterize/dynwind temporarily))
46
47 ;;;
48 ;;; Primitive parameters
49 ;;;
50
51 ;; Parameter internal API
52 (select-module gauche.internal)
53
54 (define-cproc %primitive-parameter-ref (p::<primitive-parameter>)
55 (return (Scm_PrimitiveParameterRef (Scm_VM) p)))
56 (define-cproc %primitive-parameter-set! (p::<primitive-parameter> val)
57 (return (Scm_PrimitiveParameterSet (Scm_VM) p val)))
58 (define-cproc %make-parameter-subr (p::<primitive-parameter>)
59 Scm_MakePrimitiveParameterSubr)
60 (define-cproc %with-parameterization (params vals thunk)
61 (Scm_PushParameterization params vals)
62 (return (Scm_VMApply0 thunk)))
63
64 ;;;
65 ;;; Generic parameters
66 ;;;
67
68 (select-module gauche)
69
70 ;; Must not be instantiated directly. Always use make-parameter.
71 (define-class <parameter> (<primitive-parameter>)
72 (;; all slots should be private.
73 (filter :init-keyword :filter :init-value #f)
74 (setter)
75 (restorer) ;used to restore previous value
76 ;; These are for the backward compatibility. gauche.parameter module
77 ;; provides the feature that uses them. New code shouldn't use these.
78 (pre-observers)
79 (post-observers)
80 ))
81
82 (define (%make-parameter value :optional (filter #f) (type 'legacy))
83 (call-with-current-expression-name
84 (^[name]
85 (let* ([v (if filter (filter value) value)]
86 [p (make <parameter>
87 :filter filter
88 :initial-value v
89 :type type
90 :name name)])
91 (getter-with-setter
92 ((with-module gauche.internal %make-parameter-subr) p)
93 (^[val] ((slot-ref p 'setter) val)))))))
94
95 (define (make-thread-parameter value :optional (filter #f))
96 (%make-parameter value filter 'thread))
97
98 ;; this is SRFI-226 make-parameter
99 (define (make-shared-parameter value :optional (filter #f))
100 (%make-parameter value filter 'shared))
101
102 (define (make-legacy-parameter value :optional (filter #f))
103 (%make-parameter value filter 'legacy))
104
105 ;; In 0.9.13, make-parameter returns a legacy parameter so that it
106 ;; won't break existing code. We'll switch it to make-shared-parameter
107 ;; in futuer release.
108 ;; Note that you also need to use parameterize/dynwind to get full
109 ;; backward compatibility. Using gauche.parameter guarantees it.
110 (define make-parameter make-legacy-parameter)
111
112 (define (parameter? obj)
113 (boolean (procedure-parameter obj)))
114
115 (define-cproc procedure-parameter (proc)
116 (if (and (SCM_SUBRP proc)
117 (SCM_PAIRP (SCM_PROCEDURE_INFO proc))
118 (SCM_EQ (SCM_CAR (SCM_PROCEDURE_INFO proc))
119 (Scm__GetParameterSymbol)))
120 (return (SCM_OBJ (SCM_SUBR_DATA proc)))
121 (return SCM_FALSE)))
122
123 (select-module gauche.internal)
124
125 (define-cproc %parameter-name (param)
126 (unless (SCM_PRIMITIVE_PARAMETER_P param)
127 (SCM_TYPE_ERROR param "<parameter>"))
128 (return (-> (SCM_PRIMITIVE_PARAMETER param) name)))
129
130 (define (%parameter-set! param val) ;called from general_param_proc
131 ((slot-ref param 'setter) val))
132
133 (define-method initialize ((self <parameter>) initargs)
134 (next-method)
135 (let ([filter (slot-ref self 'filter)]
136 [get (^[] (%primitive-parameter-ref self))]
137 [set (^v (%primitive-parameter-set! self v))])
138 ;; Those callback may be overwritten if hooks are set.
139 (slot-set! self 'setter
140 (if filter
141 (^v (rlet1 old (get)
142 (set (filter v))))
143 (^v (rlet1 old (get)
144 (set v)))))
145 (slot-set! self 'restorer ;bypass filter proc
146 (^v (rlet1 old (get)
147 (set v))))))
148
149 ;; restore parameter value after parameterize body. we need to bypass
150 ;; the filter procedure (fix for the bug reported by Joo ChurlSoo.
151 ;; NB: For historical reasons, PARAMETERIZE may be used with paremeter-like
152 ;; procedures.
153 (define (%restore-parameter param prev-val)
154 (cond
155 [(procedure-parameter param) =>
156 (^p (if (is-a? p <parameter>)
157 ((slot-ref p'restorer) prev-val)
158 ((with-module gauche.internal %primitive-parameter-set!) p prev-val)))]
159 ;; <parameter> and <primitive-parameter> should never be used directly,
160 ;; but for the backward compatibility:
161 [(is-a? param <parameter>) ((slot-ref param'restorer) prev-val)]
162 [(is-a? param <primitive-parameter>)
163 ((with-module gauche.internal %primitive-parameter-set!) param prev-val)]
164 [else (param prev-val)]))
165
166 ;; Actual processing of the parameterization.
167 ;; gauche.internal#%parameterize is embedded in the compiled code, so do not
168 ;; change the API across releases.
169 (define (%parameterize params orig-vals thunk compatible?)
170 ;; Returns list of filters if all params are parameter procedures.
171 ;; If not, we fallback to the old parameterize.
172 (define (gather-filters params)
173 (cond [(null? params) '()]
174 [(compatible-parameter (car params))
175 => (^p (and-let1 tail (gather-filters (cdr params))
176 (if (is-a? p <parameter>)
177 (cons (or (slot-ref p 'filter) identity) tail)
178 (cons identity tail))))]
179 [else #f]))
180 (define (compatible-parameter param)
181 (and-let* ([p (procedure-parameter param)]
182 [ (if (is-a? p <parameter>)
183 (and (not (slot-bound? p 'pre-observers))
184 (not (slot-bound? p 'post-observers)))
185 (is-a? p <primitive-parameter>)) ])
186 p))
187 (define (apply-filters filters vals)
188 (if (null? filters)
189 '()
190 (cons ((car filters) (car vals))
191 (apply-filters (cdr filters) (cdr vals)))))
192
193 (cond [(gather-filters params)
194 ;; SRFI-226 conformant parameters
195 => (^[filters]
196 (%with-parameterization (map procedure-parameter params)
197 (apply-filters filters orig-vals)
198 thunk))]
199 [compatible?
200 ;; Backward-compatibiltiy mode
201 (%parameterize/dynwind params orig-vals thunk)]
202 [else
203 (let1 p (find (complement compatible-parameter) params)
204 (if (procedure-parameter p)
205 (error "Incompatible parameter for SRFI-226 parameterize:" p)
206 (error "Non-parameter can't be used with SRFI-226 parameterize:" p)))]))
207
208 (define (%parameterize/dynwind params orig-vals thunk)
209 (let ([restarted #f]
210 [saved '()])
211 (dynamic-wind
212 (^[] (set! saved
213 (if restarted
214 (map (^[p v] (%restore-parameter p v)) params saved)
215 (map (^[p] (p)) params))))
216 (^[] (unless restarted
217 (set! saved (map (^[p v] (p v)) params orig-vals)))
218 (thunk))
219 (^[] (set! restarted #t)
220 (set! saved (map (^[p v] (%restore-parameter p v)) params saved))))))
221
222
223 (select-module gauche)
224
225 (define-syntax parameterize
226 (er-macro-transformer
227 (^[f r c]
228 (define %parameterize
229 ((with-module gauche.internal make-identifier)
230 '%parameterize
231 (find-module 'gauche.internal)
232 '()))
233 (match f
234 [(_ () . body) (quasirename r `(let () ,@body))]
235 ;; TODO: shortcut for single-parameter case
236 [(_ ((param val) ...) . body)
237 (quasirename r
238 `(,%parameterize (list ,@param) (list ,@val) (^[] ,@body) #t))]
239 [(_ . x) (error "Invalid parameterize form:" f)]))))
240
241 (define-syntax parameterize/dynwind
242 (er-macro-transformer
243 (^[f r c]
244 (define %parameterize/dynwind
245 ((with-module gauche.internal make-identifier)
246 '%parameterize/dynwind
247 (find-module 'gauche.internal)
248 '()))
249 (match f
250 [(_ () . body) (quasirename r `(let () ,@body))]
251 ;; TODO: shortcut for single-parameter case
252 [(_ ((param val) ...) . body)
253 (quasirename r
254 `(,%parameterize/dynwind (list ,@param) (list ,@val) (^[] ,@body)))]
255 [(_ . x) (error "Invalid parameterize form:" f)]))))
256
257 (define-cproc current-parameterization ()
258 Scm_CurrentParameterization)
259
260 (define-cproc parameterization? (obj) ::<boolean>
261 SCM_PARAMETERIZATIONP)
262
263 ;; SRFI-226
264 (define-syntax temporarily
265 (er-macro-transformer
266 (^[f r c]
267 (match f
268 [( () . body) (quasirename r `(let () ,@body))]
269 [(_ ((param-like val) ...) . body)
270 (let ([Ps (map (^_ (gensym)) param-like)]
271 [Vs (map (^_ (gensym)) val)])
272 (quasirename r
273 `(let (,@(map list Ps param-like)
274 ,@(map list Vs val))
275 (dynamic-wind
276 (^[] ,@(map (^[p v]
277 (quasirename r
278 `(let ((tmp (,p))) (,p ,v) (set! ,v tmp))))
279 Ps Vs))
280 (^[] ,@body)
281 (^[] ,@(map (^[p v]
282 (quasirename r
283 `(let ((tmp (,p))) (,p ,v) (set! ,v tmp))))
284 Ps Vs))))))]
285 [_ (error "Invalid temporarily form:" f)]))))
286
287
288 (define-cproc call-with-parameterization (parameterization::<parameterization>
289 thunk)
290 (Scm_InstallParameterization parameterization)
291 (return (Scm_VMApply0 thunk)))