Debian Codegraph @

lib/srfi/197.scm

raw
1 ;;;
2 ;;; Srfi-197 Pipeline operators
3 ;;;
4 ;;; The code is taken from the reference implementation,
5 ;;; and adapted to Gauche module.
6 ;;;
7
8 ;;;
9 ;;; Copyright (c) 2020 Adam Nelson.
10 ;;;
11 ;;; Permission is hereby granted, free of charge, to any person obtaining
12 ;;; a copy of this software and associated documentation
13 ;;; files (the "Software"), to deal in the Software without restriction,
14 ;;; including without limitation the rights to use, copy, modify, merge,
15 ;;; publish, distribute, sublicense, and/or sell copies of the Software,
16 ;;; and to permit persons to whom the Software is furnished to do so,
17 ;;; subject to the following conditions:
18 ;;;
19 ;;; The above copyright notice and this permission notice (including the
20 ;;; next paragraph) shall be included in all copies or substantial
21 ;;; portions of the Software.
22 ;;;
23 ;;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
24 ;;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
25 ;;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
26 ;;; NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
27 ;;; LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
28 ;;; OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
29 ;;; WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
30 ;;;
31
32 (define-module srfi.197
33 (export chain chain-and chain-when chain-lambda nest nest-reverse))
34 (select-module srfi.197)
35
36 (define-syntax chain
37 (syntax-rules ...1 ()
38 ((_ initial-value) initial-value)
39 ((_ initial-value (step ...1) ...1)
40 (chain initial-value _ ... (step ...1) ...1))
41 ((_ initial-value placeholder (step ...1) ...1)
42 (chain initial-value placeholder ... (step ...1) ...1))
43 ((_ initial-value placeholder ellipsis (first-step ...1) (next-step ...1) ...1)
44 (let ()
45 (define-syntax %chain
46 (syntax-rules ...2 (placeholder ellipsis)
47 ; (_ in-step out-step in-vars out-vars in-steps out-steps)
48 ((_ () () () ((var) ...2) () (step ...2 last-step))
49 (let* ((var step) ...2) last-step))
50 ((_ () () () (vars ...2) () (step ...2 last-step))
51 (let*-values ((vars step) ...2) last-step))
52 ((_ () () () out-vars (step . in-steps) out-steps)
53 (%chain step () () out-vars in-steps out-steps))
54 ((_ () step () (out-vars ...2) in-steps (out-steps ...2))
55 (%chain () () () (out-vars ...2 ignored) in-steps (out-steps ...2 step)))
56 ((_ () step vars (out-vars ...2) in-steps (out-steps ...2))
57 (%chain () () () (out-vars ...2 vars) in-steps (out-steps ...2 step)))
58 ((_ (placeholder ellipsis) (step ...2) () (out-vars ...2) in-steps (out-steps ...2))
59 (%chain () () () (out-vars ...2 chain-rest-var) in-steps (out-steps ...2 (apply step ...2 chain-rest-var))))
60 ((_ (placeholder ellipsis) (step ...2) (vars ...2) (out-vars ...2) in-steps (out-steps ...2))
61 (%chain () () () (out-vars ...2 (vars ...2 . chain-rest-var)) in-steps (out-steps ...2 (apply step ...2 chain-rest-var))))
62 ((_ (placeholder ellipsis . rest) . _)
63 (syntax-error "_ ... can only be used as a final argument"))
64 ((_ (placeholder . in-step) (out-step ...2) (vars ...2) . rest)
65 (%chain in-step (out-step ...2 chain-var) (vars ...2 chain-var) . rest))
66 ((_ (x . in-step) (out-step ...2) . rest)
67 (%chain in-step (out-step ...2 x) . rest))))
68 (%chain (first-step ...1) () () () ((next-step ...1) ...1) (initial-value))))))
69
70 (define-syntax chain-and
71 (syntax-rules ...1 ()
72 ((_ initial-value) initial-value)
73 ((_ initial-value (step ...1) ...1) (chain-and initial-value _ (step ...1) ...1))
74 ((_ initial-value placeholder (first-step ...1) (next-step ...1) ...1)
75 (let ()
76 (define-syntax %chain-and
77 (syntax-rules ...2 (placeholder)
78 ; (_ in-step out-step in-vars out-vars in-steps out-steps)
79 ((_ () () () (var ...2) () (step ...2 last-step))
80 (and-let* ((var step) ...2) last-step))
81 ((_ () () () out-vars (step . in-steps) out-steps)
82 (%chain-and step () () out-vars in-steps out-steps))
83 ((_ () step () (out-vars ...2) in-steps (out-steps ...2))
84 (%chain-and () () () (out-vars ...2 ignored) in-steps (out-steps ...2 step)))
85 ((_ () step (var) (out-vars ...2) in-steps (out-steps ...2))
86 (%chain-and () () () (out-vars ...2 var) in-steps (out-steps ...2 step)))
87 ((_ (placeholder . in-step) (out-step ...2) () . rest)
88 (%chain-and in-step (out-step ...2 chain-var) (chain-var) . rest))
89 ((_ (placeholder . excess) . rest)
90 (syntax-error "chain-and does not support multiple _ in a single step"))
91 ((_ (x . in-step) (out-step ...2) . rest)
92 (%chain-and in-step (out-step ...2 x) . rest))))
93 (%chain-and (first-step ...1) () () () ((next-step ...1) ...1) (initial-value))))))
94
95 (define-syntax chain-when
96 (syntax-rules ...1 ()
97 ((_ initial-value) initial-value)
98 ((_ initial-value (guard? (step ...1)) ...1)
99 (chain-when initial-value _ (guard? (step ...1)) ...1))
100 ((_ initial-value placeholder (first-guard? (first-step ...1)) (next-guard? (next-step ...1)) ...1)
101 (let ()
102 (define-syntax %chain-when
103 (syntax-rules ...2 (placeholder)
104 ; (_ in-step out-step guard? chain-var in-steps out-expr)
105 ((_ () () _1 _2 () out-expr) out-expr)
106 ((_ () () _1 _2 ((guard? step) . in-steps) out-expr)
107 (%chain-when step () guard? #f in-steps out-expr))
108 ((_ () step guard? #f in-steps out-expr)
109 (%chain-when () () #f #f in-steps
110 (let ((chain-var out-expr))
111 (if guard? step chain-var))))
112 ((_ () step guard? chain-var in-steps out-expr)
113 (%chain-when () () #f #f in-steps
114 (let ((chain-var out-expr))
115 (if guard? step chain-var))))
116 ((_ (placeholder . in-step) (out-step ...2) guard? #f . rest)
117 (%chain-when in-step (out-step ...2 chain-var) guard? chain-var . rest))
118 ((_ (placeholder . excess) . rest)
119 (syntax-error "chain-when does not support multiple _ in a single step"))
120 ((_ (x . in-step) (out-step ...2) . rest)
121 (%chain-when in-step (out-step ...2 x) . rest))))
122 (%chain-when (first-step ...1) () first-guard? #f ((next-guard? (next-step ...1)) ...1) initial-value)))))
123
124 (define-syntax chain-lambda
125 (syntax-rules ...1 ()
126 ((_ (step ...1) ...1) (chain-lambda _ ... (step ...1) ...1))
127 ((_ placeholder (step ...1) ...1) (chain-lambda placeholder ... (step ...1) ...1))
128 ((_ placeholder ellipsis (first-step ...1) (next-step ...1) ...1)
129 (let ()
130 (define-syntax %chain-lambda
131 (syntax-rules ...2 (placeholder ellipsis)
132 ; (_ in-step out-step args rest-of-steps)
133 ((_ () step args ())
134 (lambda args step))
135 ((_ () step args steps)
136 (lambda args
137 (chain step placeholder ellipsis . steps)))
138 ((_ (placeholder ellipsis) (step ...2) () ())
139 (lambda chain-rest-var (apply step ...2 chain-rest-var)))
140 ((_ (placeholder ellipsis) (step ...2) () steps)
141 (lambda chain-rest-var
142 (chain (apply step ...2 chain-rest-var) placeholder ellipsis . steps)))
143 ((_ (placeholder ellipsis) (step ...2) (args ...2) ())
144 (lambda (args ...2 . chain-rest-var) (apply step ...2 chain-rest-var)))
145 ((_ (placeholder ellipsis) (step ...2) (args ...2) steps)
146 (lambda (args ...2 . chain-rest-var)
147 (chain (apply step ...2 chain-rest-var) placeholder ellipsis . steps)))
148 ((_ (placeholder ellipsis . excess) . rest)
149 (syntax-error "_ ... can only be used as a final argument"))
150 ((_ (placeholder . in-step) (out-step ...2) (args ...2) . rest)
151 (%chain-lambda in-step (out-step ...2 chain-var) (args ...2 chain-var) . rest))
152 ((_ (x . in-step) (out-step ...2) . rest)
153 (%chain-lambda in-step (out-step ...2 x) . rest))))
154 (%chain-lambda (first-step ...1) () () ((next-step ...1) ...1))))))
155
156 (define-syntax nest
157 (syntax-rules ...1 (_)
158 ((nest last) last)
159 ((nest (step ...1) ...1 last) (nest _ (step ...1) ...1 last))
160 ((nest placeholder (extra-step ...1) ...1 (first-step ...1) last)
161 (let ()
162 ; let-syntax is buggy in some Schemes, define-syntax is more reliable
163 (define-syntax %nest
164 (syntax-rules ...2 (placeholder)
165 ((%nest result () placeholder ()) result)
166 ((%nest result () placeholder (rest ...2 step))
167 (%nest () step result (rest ...2)))
168 ((%nest result () accum steps)
169 (syntax-error "nest: step must contain _"))
170 ((%nest result (placeholder . rest) placeholder steps)
171 (syntax-error "nest: only one _ allowed per step"))
172 ((%nest (result ...2) (placeholder . rest) accum steps)
173 (%nest (result ...2 accum) rest placeholder steps))
174 ((%nest (result ...2) (element . rest) accum steps)
175 (%nest (result ...2 element) rest accum steps))))
176 (%nest () (first-step ...1) last ((extra-step ...1) ...1))))
177 ((nest placeholder last) last)))
178
179 (define-syntax nest-reverse
180 (syntax-rules ...1 (_)
181 ((nest-reverse first) first)
182 ((nest-reverse first (step ...1) ...1) (nest-reverse first _ (step ...1) ...1))
183 ((nest-reverse first placeholder (first-step ...1) (extra-step ...1) ...1)
184 (let ()
185 (define-syntax %nest
186 (syntax-rules ...2 (placeholder)
187 ((%nest result () placeholder ()) result)
188 ((%nest result () placeholder (step . rest))
189 (%nest () step result rest))
190 ((%nest result () accum steps)
191 (syntax-error "nest-reverse: step must contain _"))
192 ((%nest result (placeholder . rest) placeholder steps)
193 (syntax-error "nest-reverse: only one _ allowed per step"))
194 ((%nest (result ...2) (placeholder . rest) accum steps)
195 (%nest (result ...2 accum) rest placeholder steps))
196 ((%nest (result ...2) (element . rest) accum steps)
197 (%nest (result ...2 element) rest accum steps))))
198 (%nest () (first-step ...1) first ((extra-step ...1) ...1))))
199 ((nest-reverse first placeholder) first)))