Debian Codegraph @

lib/control/cseq.scm

raw
1 ;;;
2 ;;; control.cseq - concurrent sequence
3 ;;;
4 ;;; Copyright (c) 2021-2024 Shiro Kawai <[email protected]>
5 ;;;
6 ;;; Redistribution and use in source and binary forms, with or without
7 ;;; modification, are permitted provided that the following conditions
8 ;;; are met:
9 ;;;
10 ;;; 1. Redistributions of source code must retain the above copyright
11 ;;; notice, this list of conditions and the following disclaimer.
12 ;;;
13 ;;; 2. Redistributions in binary form must reproduce the above copyright
14 ;;; notice, this list of conditions and the following disclaimer in the
15 ;;; documentation and/or other materials provided with the distribution.
16 ;;;
17 ;;; 3. Neither the name of the authors nor the names of its contributors
18 ;;; may be used to endorse or promote products derived from this
19 ;;; software without specific prior written permission.
20 ;;;
21 ;;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22 ;;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23 ;;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
24 ;;; A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
25 ;;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
26 ;;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
27 ;;; TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
28 ;;; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
29 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
30 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
31 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
32 ;;;
33
34 ;; EXPERIMENTAL
35
36 ;; cseq is like lseq, but producer and consumer run concurrently
37
38 (define-module control.cseq
39 (use gauche.generator)
40 (use gauche.threads)
41 (use data.queue)
42 (export generator->cseq
43 coroutine->cseq)
44 )
45 (select-module control.cseq)
46
47 (define (%concurrent-generator->lseq q thunk)
48 (define t (thread-start! (make-thread thunk)))
49 (generator->lseq (^[] (let1 r (dequeue/wait! q)
50 (when (eof-object? (car r))
51 (guard (e [(<uncaught-exception> e)
52 (raise (~ e 'reason))]
53 [else (raise e)])
54 (thread-join! t)))
55 (apply values r)))))
56
57 (define (generator->cseq producer :key (queue-length #f))
58 (define q (make-mtqueue :max-length (or queue-length 64)))
59 (define (thunk)
60 (guard [e (else (enqueue/wait! q (list (eof-object))) (raise e))]
61 (let loop ()
62 (receive (v . rest) (producer)
63 (enqueue/wait! q (cons v rest))
64 (unless (eof-object? v)
65 (loop))))))
66 (%concurrent-generator->lseq q thunk))
67
68 (define (coroutine->cseq proc :key (queue-length #f))
69 (define q (make-mtqueue :max-length (or queue-length 64)))
70 (define (yielder . vals) (enqueue/wait! q vals))
71
72 (define (thunk)
73 (guard [e (else (enqueue/wait! q (list (eof-object))) (raise e))]
74 (proc yielder)
75 (enqueue/wait! q (list (eof-object)))))
76 (%concurrent-generator->lseq q thunk))