Debian Codegraph @

ext/dbm/gdbm.scm

raw
1 ;;;
2 ;;; gdbm - gdbm interface
3 ;;;
4 ;;; Copyright (c) 2000-2024 Shiro Kawai <[email protected]>
5 ;;;
6 ;;; Redistribution and use in source and binary forms, with or without
7 ;;; modification, are permitted provided that the following conditions
8 ;;; are met:
9 ;;;
10 ;;; 1. Redistributions of source code must retain the above copyright
11 ;;; notice, this list of conditions and the following disclaimer.
12 ;;;
13 ;;; 2. Redistributions in binary form must reproduce the above copyright
14 ;;; notice, this list of conditions and the following disclaimer in the
15 ;;; documentation and/or other materials provided with the distribution.
16 ;;;
17 ;;; 3. Neither the name of the authors nor the names of its contributors
18 ;;; may be used to endorse or promote products derived from this
19 ;;; software without specific prior written permission.
20 ;;;
21 ;;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22 ;;; "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23 ;;; LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
24 ;;; A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
25 ;;; OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
26 ;;; SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
27 ;;; TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
28 ;;; PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
29 ;;; LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
30 ;;; NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
31 ;;; SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
32 ;;;
33
34 (define-module dbm.gdbm
35 (extend dbm)
36 (export <gdbm>
37 ;; low-level functions
38 gdbm-open gdbm-close gdbm-closed?
39 gdbm-store gdbm-fetch gdbm-delete
40 gdbm-firstkey gdbm-nextkey gdbm-reorganize
41 gdbm-sync gdbm-exists? gdbm-strerror
42 gdbm-setopt gdbm-version gdbm-file-of
43 gdbm-errno
44 GDBM_READER GDBM_WRITER GDBM_WRCREAT
45 GDBM_NEWDB GDBM_FAST GDBM_SYNC
46 GDBM_NOLOCK GDBM_INSERT GDBM_REPLACE
47 GDBM_CACHESIZE GDBM_FASTMODE GDBM_SYNCMODE
48 GDBM_CENTFREE GDBM_COALESCEBLKS)
49 )
50 (select-module dbm.gdbm)
51
52 ;;;
53 ;;; High-level dbm interface
54 ;;;
55
56 (define-class <gdbm-meta> (<dbm-meta>)
57 ())
58
59 (define-class <gdbm> (<dbm>)
60 ((gdbm-file :accessor gdbm-file-of :initform #f)
61 (sync :init-keyword :sync :initform #f)
62 (nolock :init-keyword :nolock :initform #f)
63 (bsize :init-keyword :bsize :initform 0)
64 )
65 :metaclass <gdbm-meta>)
66
67 (define-method dbm-open ((self <gdbm>))
68 (next-method)
69 (unless (slot-bound? self 'path)
70 (error "path must be set to open gdbm database"))
71 (when (gdbm-file-of self)
72 (errorf "gdbm ~S already opened" self))
73 (let* ([path (slot-ref self 'path)]
74 [rwmode (slot-ref self 'rw-mode)]
75 [sync (slot-ref self 'sync)]
76 [nolock (slot-ref self 'nolock)]
77 [rwopt (case rwmode
78 [(:read) GDBM_READER]
79 [(:write) (+ GDBM_WRCREAT
80 (if sync GDBM_SYNC 0)
81 (if nolock GDBM_NOLOCK 0))]
82 [(:create) (+ GDBM_NEWDB
83 (if sync GDBM_SYNC 0)
84 (if nolock GDBM_NOLOCK 0))])]
85 [fp (gdbm-open path
86 (slot-ref self 'bsize)
87 rwopt
88 (slot-ref self 'file-mode))])
89 (slot-set! self 'gdbm-file fp)
90 self))
91
92 ;;
93 ;; close operation
94 ;;
95
96 (define-method dbm-close ((self <gdbm>))
97 (let1 gdbm (gdbm-file-of self)
98 (and gdbm (gdbm-close gdbm))))
99
100 (define-method dbm-closed? ((self <gdbm>))
101 (let1 gdbm (gdbm-file-of self)
102 (or (not gdbm) (gdbm-closed? gdbm))))
103
104 ;;
105 ;; accessors
106 ;;
107
108 (define-method dbm-put! ((self <gdbm>) key value)
109 (next-method)
110 (when (positive? (gdbm-store (gdbm-file-of self)
111 (%dbm-k2s self key)
112 (%dbm-v2s self value)
113 GDBM_REPLACE))
114 (error "dbm-put! failed" self)))
115
116 (define-method dbm-get ((self <gdbm>) key . args)
117 (next-method)
118 (cond [(gdbm-fetch (gdbm-file-of self) (%dbm-k2s self key))
119 => (cut %dbm-s2v self <>)]
120 [(pair? args) (car args)] ;fall-back value
121 [else (errorf "gdbm: no data for key ~s in database ~s"
122 key (gdbm-file-of self))]))
123
124 (define-method dbm-exists? ((self <gdbm>) key)
125 (next-method)
126 (gdbm-exists? (gdbm-file-of self) (%dbm-k2s self key)))
127
128 (define-method dbm-delete! ((self <gdbm>) key)
129 (next-method)
130 (when (positive? (gdbm-delete (gdbm-file-of self) (%dbm-k2s self key)))
131 (errorf "dbm-delete!: deleteting key ~s from ~s failed" key self)))
132
133 ;;
134 ;; Iterations
135 ;;
136
137 (define-method dbm-fold ((self <gdbm>) proc knil)
138 (let1 gdbm (gdbm-file-of self)
139 (let loop ([key (gdbm-firstkey gdbm)] [r knil])
140 (if key
141 (let1 val (gdbm-fetch gdbm key)
142 (loop (gdbm-nextkey gdbm key)
143 (proc (%dbm-s2k self key) (%dbm-s2v self val) r)))
144 r))))
145
146 ;;
147 ;; Metaoperations
148 ;;
149
150 (autoload file.util copy-file move-file)
151
152 (define (%with-gdbm-locking path thunk)
153 (let1 db (gdbm-open path 0 GDBM_READER #o664) ;; put read-lock
154 (unwind-protect (thunk) (gdbm-close db))))
155
156 (define-method dbm-db-exists? ((class <gdbm-meta>) name)
157 (file-exists? name))
158
159 (define-method dbm-db-remove ((class <gdbm-meta>) name)
160 (sys-unlink name))
161
162 (define-method dbm-db-copy ((class <gdbm-meta>) from to . keys)
163 (%with-gdbm-locking from
164 (^[] (apply copy-file from to :safe #t keys))))
165
166 (define-method dbm-db-move ((class <gdbm-meta>) from to . keys)
167 (%with-gdbm-locking from
168 (^[] (apply move-file from to :safe #t keys))))
169
170 ;;;
171 ;;; Low-level bindings
172 ;;;
173
174 (inline-stub
175 (declcode
176 (.include <gdbm.h>)
177 (.include <stdlib.h>)
178 (.include <gauche/priv/configP.h>))
179
180 (define-ctype ScmGdbmFile::(.struct
181 (SCM_HEADER :: ""
182 name
183 dbf::GDBM_FILE ; NULL if closed
184 )))
185
186 (define-cclass <gdbm-file> :private ScmGdbmFile* "Scm_GdbmFileClass" ()
187 ()
188 [printer
189 (Scm_Printf port "#<gdbm-file %S>" (-> (SCM_GDBM_FILE obj) name))])
190
191 (define-cfn gdbm_finalize (obj _::void*) ::void :static
192 (let* ((g :: ScmGdbmFile* (SCM_GDBM_FILE obj)))
193 (when (-> g dbf)
194 (gdbm_close (-> g dbf))
195 (set! (-> g dbf) NULL))))
196
197 ;; data conversion macros
198 (define-cise-stmt TO_DATUM
199 [(_ datum scm)
200 (let ((tmp (gensym)))
201 `(let* ((,tmp :: (const ScmStringBody*) (SCM_STRING_BODY ,scm)))
202 (set! (ref ,datum dptr) (cast char* (SCM_STRING_BODY_START ,tmp)))
203 (set! (ref ,datum dsize) (SCM_STRING_BODY_SIZE ,tmp))))])
204
205 (define-cise-stmt FROM_DATUM
206 [(_ scm datum)
207 `(cond [(ref ,datum dptr)
208 (set! ,scm (Scm_MakeString (ref ,datum dptr) (ref ,datum dsize)
209 -1 SCM_STRING_COPYING))
210 (free (ref ,datum dptr))]
211 [else
212 (set! ,scm SCM_FALSE)])])
213
214 (define-cise-stmt CHECK_GDBM
215 [(_ g)
216 `(unless (-> ,g dbf) (Scm_Error "gdbm file already closed: %S" ,g))])
217
218 ;; Those symbols may not be defined in the older gdbm
219 (.unless (defined GDBM_SYNC) (.define GDBM_SYNC 0))
220 (.unless (defined GDBM_NOLOCK) (.define GDBM_NOLOCK 0))
221 (.unless (defined GDBM_SYNCMODE) (.define GDBM_SYNCMODE 0))
222 (.unless (defined GDBM_CENTFREE) (.define GDBM_CENTFREE 0))
223 (.unless (defined GDBM_COALESCEBLKS) (.define GDBM_COALESCEBLKS 0))
224
225 (define-cproc gdbm-open
226 (name::<string> :optional (size::<fixnum> 0)
227 (rwmode::<fixnum> (c "SCM_MAKE_INT(GDBM_READER)"))
228 (fmode::<fixnum> (c "SCM_MAKE_INT(0666)")))
229 (let* ([z::ScmGdbmFile* (SCM_NEW ScmGdbmFile)])
230 (SCM_SET_CLASS z (& Scm_GdbmFileClass))
231 (Scm_RegisterFinalizer (SCM_OBJ z) gdbm_finalize NULL)
232 (set! (-> z name) (SCM_OBJ name))
233 (set! (-> z dbf) (gdbm_open (Scm_GetString name) size rwmode fmode NULL))
234 (when (== (-> z dbf) NULL)
235 (Scm_Error "couldn't open gdbm file %S (gdbm_errno=%d)" name gdbm_errno))
236 (return (SCM_OBJ z))))
237
238 (define-cproc gdbm-close (gdbm::<gdbm-file>) ::<void>
239 (when (-> gdbm dbf)
240 (gdbm_close (-> gdbm dbf))
241 (set! (-> gdbm dbf) NULL)))
242
243 (define-cproc gdbm-closed? (gdbm::<gdbm-file>) ::<boolean>
244 (return (== (-> gdbm dbf) NULL)))
245
246 (define-cproc gdbm-store (gdbm::<gdbm-file>
247 key::<string> val::<string>
248 :optional (flags::<fixnum> 0))
249 ::<int>
250 (let* ([dkey::datum] [dval::datum])
251 (CHECK_GDBM gdbm)
252 (TO_DATUM dkey key)
253 (TO_DATUM dval val)
254 (return (gdbm_store (-> gdbm dbf) dkey dval flags))))
255
256 (define-cproc gdbm-fetch (gdbm::<gdbm-file> key::<string>)
257 (let* ([dkey::datum] [dval::datum])
258 (CHECK_GDBM gdbm)
259 (TO_DATUM dkey key)
260 (set! dval (gdbm_fetch (-> gdbm dbf) dkey))
261 (FROM_DATUM SCM_RESULT dval)))
262
263 (define-cproc gdbm-delete (gdbm::<gdbm-file> key::<string>) ::<int>
264 (let* ([dkey::datum])
265 (CHECK_GDBM gdbm)
266 (TO_DATUM dkey key)
267 (return (gdbm_delete (-> gdbm dbf) dkey))))
268
269 (define-cproc gdbm-firstkey (gdbm::<gdbm-file>)
270 (let* ([dkey::datum (gdbm_firstkey (-> gdbm dbf))])
271 (FROM_DATUM SCM_RESULT dkey)))
272
273 (define-cproc gdbm-nextkey (gdbm::<gdbm-file> key::<string>)
274 (let* ([dkey::datum] [dnkey::datum])
275 (CHECK_GDBM gdbm)
276 (TO_DATUM dkey key)
277 (set! dnkey (gdbm_nextkey (-> gdbm dbf) dkey))
278 (FROM_DATUM SCM_RESULT dnkey)))
279
280 (define-cproc gdbm-reorganize (gdbm::<gdbm-file>) ::<int>
281 (CHECK_GDBM gdbm)
282 (return (gdbm_reorganize (-> gdbm dbf))))
283
284 (define-cproc gdbm-sync (gdbm::<gdbm-file>) ::<void>
285 (CHECK_GDBM gdbm)
286 (gdbm_sync (-> gdbm dbf)))
287
288 (define-cproc gdbm-exists? (gdbm::<gdbm-file> key::<string>) ::<boolean>
289 (let* ([dkey::datum])
290 (CHECK_GDBM gdbm)
291 (TO_DATUM dkey key)
292 (return (gdbm_exists (-> gdbm dbf) dkey))))
293
294 (define-cproc gdbm-strerror (err_num::<fixnum>)
295 (return (SCM_MAKE_STR_IMMUTABLE (gdbm_strerror err_num))))
296
297 (define-cproc gdbm-setopt (gdbm::<gdbm-file> option::<fixnum> val) ::<int>
298 (let* ([ival::int])
299 (CHECK_GDBM gdbm)
300 (if (SCM_EXACTP val)
301 (set! ival (Scm_GetUInteger val))
302 (set! ival (not (SCM_FALSEP val))))
303 (return (gdbm_setopt (-> gdbm dbf) option (& ival) (sizeof (int))))))
304
305 (define-cproc gdbm-version ()
306 (return (SCM_MAKE_STR_IMMUTABLE gdbm_version)))
307
308 (define-cproc gdbm-errno () ::<int>
309 (let* ([r::int gdbm_errno])
310 (set! gdbm_errno 0)
311 (return r)))
312
313 (define-enum GDBM_READER)
314 (define-enum GDBM_WRITER)
315 (define-enum GDBM_WRCREAT)
316 (define-enum GDBM_NEWDB)
317 (define-enum GDBM_FAST)
318 (define-enum GDBM_SYNC)
319 (define-enum GDBM_NOLOCK)
320 (define-enum GDBM_INSERT)
321 (define-enum GDBM_REPLACE)
322 (define-enum GDBM_CACHESIZE)
323 (define-enum GDBM_FASTMODE)
324 (define-enum GDBM_SYNCMODE)
325 (define-enum GDBM_CENTFREE)
326 (define-enum GDBM_COALESCEBLKS)
327 )