Debian Codegraph @

examples/pegintro.scm

raw
1 ;;
2 ;; Code in the manual section "PEG Walkthrough"
3 ;;
4
5 (use parser.peg)
6
7 (define digits ($many1 ($. #[\d])))
8 (define ws ($many_ ($. #[\s])))
9 (define separator ($seq ws ($. #\,) ws))
10
11 #|
12 (peg-parse-string digits "12345")
13 ;; => (#\1 #\2 #\3 #\4 #\5)
14 |#
15
16 (define integer
17 ($let ([ds digits])
18 ($return (x->integer (list->string ds)))))
19
20 #|
21 (peg-parse-string integer "12345")
22 ;; => 12345
23 |#
24
25 (define integers1 ($seq integer
26 ($many ($seq separator integer))))
27
28 #|
29 (peg-parse-string integers1 "123, 456, 789")
30 ;; => (456 789)
31 |#
32
33 (define integers2 ($let ([n integer]
34 [ns ($many ($seq separator integer))])
35 ($return (cons n ns))))
36
37
38 #|
39 (peg-parse-string integers2 "123, 456, 789")
40 ;; => (123 456 789)
41 |#
42
43 (define integers3 ($lift cons
44 integer
45 ($many ($seq separator integer))))
46
47 #|
48 (peg-parse-string integers3 "123, 456, 789")
49 ;; => (123 456 789)
50 |#
51
52 (define integers4 ($or ($let ([n integer]
53 [ns ($many ($seq separator integer))])
54 ($return (cons n ns)))
55 ($return '())))
56
57 #|
58 (peg-parse-string integers4 " ")
59 ;; => ()
60 |#
61
62 (define (sep-by stuff separator)
63 ($or ($let ([n stuff]
64 [ns ($many ($seq separator stuff))])
65 ($return (cons n ns)))
66 ($return '())))
67 (define integers5 (sep-by integer separator))
68
69 #|
70 (peg-parse-string integers5 "123, 456, 789, 0")
71 ;; => (123 456 789 0)
72 |#
73
74 (define paren ($. #\())
75 (define thesis ($. #\)))
76
77 #|
78 (peg-parse-string ($or ($seq paren ($."ab") thesis)
79 ($seq paren ($."cd") thesis))
80 "(cd)")
81 ;; => *** PARSE-ERROR: expecting ab at 1, but got #\c
82
83 (peg-parse-string ($seq paren
84 ($or ($."ab") ($."cd"))
85 thesis)
86 "(cd)")
87 ;; => #\)
88
89 (peg-parse-string ($or ($try ($seq paren ($."ab") thesis))
90 ($seq paren ($."cd") thesis))
91 "(cd)")
92 ;; => #\)
93 |#
94
95 (define begin-list
96 ($seq0 ($. #[\(\[\{]) ws))
97
98 (define (end-list opener)
99 ($seq ws (case opener
100 [(#\() ($. #\))]
101 [(#\[) ($. #\])]
102 [(#\{) ($. #\})])))
103
104 (define int-list
105 ($let* ([opener begin-list] ;*1
106 [ints ($sep-by integer separator)] ;*2
107 [ (end-list opener) ]) ;*3
108 ($return ints)))
109
110 #|
111 (peg-parse-string int-list "[123, 456, 789]")
112 ;; => (123 456 789)
113 (peg-parse-string int-list "{123, 456, 789}")
114 ;; => (123 456 789)
115 (peg-parse-string int-list "(123, 456, 789}")
116 ;; => *** PARSE-ERROR: expecting #\) at 14, but got #\@}
117 |#
118
119 (define nested-list
120 ($lazy
121 ($let* ([opener begin-list]
122 [ints ($sep-by elem separator)]
123 [ (end-list opener) ])
124 ($return ints))))
125 (define elem ($or integer nested-list))
126
127 #|
128 (peg-parse-string nested-list "(123, [456, {}, 789], 987)")
129 ;; => (123 (456 () 789) 987)
130 (peg-parse-string nested-list "(123, [456, {}, 789), 987)")
131 ;; => *** PARSE-ERROR: expecting one of (#[0-9] #\]) at 19
132 |#
133
134 (define (end-list2 opener)
135 (define expected
136 (assv-ref '((#\( . #\)) (#\[ . #\]) (#\{ . #\})) opener))
137 ($seq ws
138 ($let ([closer ($. #[\)\]\}])])
139 (if (eqv? closer expected)
140 ($return closer)
141 ($fail (format "Mismatched closing bracket. '~c' expected, but got '~c'"
142 expected closer))))))
143 (define nested-list2
144 ($lazy
145 ($let* ([opener begin-list]
146 [ints ($sep-by elem2 separator)]
147 [ (end-list2 opener) ])
148 ($return ints))))
149 (define elem2 ($or integer nested-list2))
150
151 #|
152 (peg-parse-string nested-list2 "(123, [456, {}, 789), 987)")
153 ;; => *** PARSE-ERROR: Mismatched closing bracket. ']' expected, but got ')' at 20
154 |#