Debian Codegraph @

m4/glut.m4

raw
1 dnl FTGL_CHECK_GLUT()
2 dnl Check for GLUT development environment
3 dnl
4 AC_DEFUN([FTGL_CHECK_GLUT],
5 [dnl
6 AC_REQUIRE([AC_PROG_CC])dnl
7 AC_REQUIRE([AC_PATH_X])dnl
8 AC_REQUIRE([AC_PATH_XTRA])dnl
9 AC_REQUIRE([FTGL_CHECK_GL])dnl
10
11 AC_ARG_WITH([--with-glut-inc],
12 AC_HELP_STRING([--with-glut-inc=DIR],[Directory where GL/glut.h is installed (optional)]))
13 AC_ARG_WITH([--with-glut-lib],
14 AC_HELP_STRING([--with-glut-lib=DIR],[Directory where GLUT libraries are installed (optional)]))
15
16 AC_LANG_SAVE
17 AC_LANG_C
18
19 GLUT_SAVE_CPPFLAGS="$CPPFLAGS"
20 GLUT_SAVE_LIBS="$LIBS"
21
22 if test "$no_x" != "yes"; then
23 GLUT_CFLAGS="$X_CFLAGS"
24 GLUT_X_LIBS="$X_PRE_LIBS $X_LIBS -lX11 -lXext -lXmu $X_EXTRA_LIBS"
25 fi
26
27 if test "$with_glut_inc" != "none"; then
28 if test -d "$with_glut_inc"; then
29 GLUT_CFLAGS="-I$with_glut_inc"
30 else
31 GLUT_CFLAGS="$with_glut_inc"
32 fi
33 else
34 GLUT_CFLAGS=""
35 fi
36
37 # Check for GLUT headers
38 CPPFLAGS="$GLUT_CFLAGS"
39 AC_CHECK_HEADERS([GL/glut.h], [ac_cv_have_glut=yes],
40 [AC_CHECK_HEADERS([GLUT/glut.h], [ac_cv_have_glut=yes],
41 [ac_cv_have_glut=no])])
42
43 # Check for GLUT libraries
44 if test "$ac_cv_have_glut" = "yes"; then
45 AC_MSG_CHECKING([for GLUT library])
46 if test "$with_glut_lib" != ""; then
47 if test -d "$with_glut_lib"; then
48 LIBS="-L$with_glut_lib -lglut"
49 else
50 LIBS="$with_glut_lib"
51 fi
52 else
53 LIBS="-lglut"
54 fi
55
56 AC_LINK_IFELSE(
57 [AC_LANG_CALL([],[glutInit])],
58 [ac_cv_have_glut=yes],
59 [ac_cv_have_glut=no])
60 if test "$ac_cv_have_glut" = "no"; then
61 # Try again with the GL libs
62 LIBS="-lglut $GL_LIBS"
63 AC_LINK_IFELSE(
64 [AC_LANG_CALL([],[glutInit])],
65 [ac_cv_have_glut=yes],
66 [ac_cv_have_glut=no])
67 fi
68
69 if test "$ac_cv_have_glut" = "no" && test "$GLUT_X_LIBS" != ""; then
70 # Try again with the GL and X11 libs
71 LIBS="-lglut $GL_LIBS $GLUT_X_LIBS"
72 AC_LINK_IFELSE(
73 [AC_LANG_CALL([],[glutInit])],
74 [ac_cv_have_glut=yes],
75 [ac_cv_have_glut=no])
76 fi
77
78 if test "$ac_cv_have_glut" = "no"; then
79 # Try again with GLUT framework
80 LIBS="-Xlinker -framework -Xlinker OpenGL -Xlinker -framework -Xlinker GLUT"
81 AC_LINK_IFELSE(
82 [AC_LANG_CALL([],[glutInit])],
83 [ac_cv_have_glut=yes],
84 [ac_cv_have_glut=no])
85 fi
86
87 if test "$ac_cv_have_glut" = "yes"; then
88 AC_MSG_RESULT([yes])
89 GLUT_LIBS="$LIBS"
90 else
91 AC_MSG_RESULT([no])
92 fi
93 fi
94
95 if test "$ac_cv_have_glut" = "no"; then
96 AC_MSG_WARN([GLUT headers not available, example program won't be compiled.])
97 fi
98
99 AM_CONDITIONAL(HAVE_GLUT, [test "$ac_cv_have_glut" = "yes"])
100
101 AC_SUBST(GLUT_CFLAGS)
102 AC_SUBST(GLUT_LIBS)
103 AC_LANG_RESTORE
104
105 CPPFLAGS="$GLUT_SAVE_CPPFLAGS"
106 LIBS="$GLUT_SAVE_LIBS"
107 GLUT_X_CFLAGS=
108 GLUT_X_LIBS=
109 ])
110