Debian Codegraph @

3rdparty/dissection/src/freefem++-interface/examples++-load/BDD.edp

raw
1 // Interative Substructuring metod with Neumann-Neuman / BDD
2 // for tutorial by Japan SIAM, Tokyo, 4-5 Jun.2016, Atsushi Suzuki
3
4 bool withmetis=true;
5 if (withmetis) {
6 load "metis";
7 }
8 load "Dissection";
9 bool flagRAS=true;
10 bool twolevel = true;
11 int sizeoverlaps=1; // size off overlap
12 int nn=10,mm=10;
13
14 func bool SubdomainsPartitionUnity(mesh & Th, int nnpart, real[int] & partdof,
15 int sizeoverlaps, mesh[int] & aTh,
16 matrix[int] & Rih, matrix[int] & Dih)
17 {
18 fespace Vh(Th,P1);
19 fespace Ph(Th,P0);
20
21 mesh Thi=Th;
22 fespace Vhi(Thi,P1); // FreeFEM trick, formal definition
23 Vhi[int] pun(nnpart); // local fem functions Vh sun=0, unssd=0;
24 Vh sun = 0, unssd = 0;
25 Ph part;
26 part[]=partdof;
27 for(int i=0;i<nnpart;++i) {
28 Ph suppi= abs(part - i) < 0.1; // boolean 1 in the subdomain 0 elsewhere
29 Thi=aTh[i]=trunc(Th,suppi>0,label=10,split=1); // mesh interfaces label 10
30 Rih[i]=interpolate(Vhi,Vh,inside=true); // Restriction operator : Vh to Vhi
31 pun[i][] = 1.0;
32 sun[] += Rih[i]'*pun[i][]; // '
33 }
34 for(int i=0;i<nnpart;++i) {
35 Thi=aTh[i];
36 pun[i]= pun[i]/sun;
37 Dih[i]=pun[i][]; //diagonal matrix built from a vector if(verbosity > 1)
38 }
39 return true;
40 }
41
42 func int SkeltonIndex(mesh & Th, int nnpart, mesh[int] & Tha, matrix[int] & Rih,
43 matrix[int] & Dih, int[int] &skelindex)
44 {
45 fespace Vh(Th, P1);
46 int ndeg = 0;
47 mesh Thi = Th;
48 Vh sum = 0;
49 int[int] lindex(Vh.ndof);
50 for (int n = 0; n < nnpart; n++) {
51 real[int] bi(Tha[n].nv);
52 bi = 0.0;
53 for (int k = 0; k < Tha[n].nbe; k++) { // over boundary elements
54 if (Tha[n].be(k).label == 10) {
55 bi[Tha[n].be(k)[0]] = 1.0;
56 bi[Tha[n].be(k)[1]] = 1.0;
57 }
58 }
59 real[int] di = Dih[n]*bi;
60 Vh localone;
61 localone[] = Rih[n]'*di; // '
62 sum[] +=localone[];
63 }
64 for (int i = 0; i < Vh.ndof; i++) {
65 if (abs(sum[][i] - 1.0) < 0.1) {
66 lindex[ndeg++] = i;
67 }
68 }
69 skelindex = lindex;
70 return ndeg;
71 }
72
73 func int LocalIndexes(int nnpart, mesh[int] & Tha,
74 int[int] &num0, int[int,int] &idx0,
75 int[int] &num1, int[int,int] &idx1,
76 int[int] &num2, int[int,int] &idx2)
77 {
78 for (int n = 0; n < nnpart; n++) {
79 mesh Thi = Tha[n];
80 fespace Vhi(Thi, P1);
81 Vhi u;
82 u = 0.0;
83 for (int k = 0; k < Tha[n].nbe; k++) { // over boundary elements
84 if (Tha[n].be(k).label == 10) {
85 u[][Tha[n].be(k)[0]] = 1.0;
86 u[][Tha[n].be(k)[1]] = 1.0;
87 }
88 if (Tha[n].be(k).label == 1) {
89 u[][Tha[n].be(k)[0]] = -1.0;
90 u[][Tha[n].be(k)[1]] = -1.0;
91 }
92 }
93 int itmp0 = 0;
94 int itmp1 = 0;
95 int itmp2 = 0;
96 for (int i = 0; i < Vhi.ndof; i++) {
97 if (u[][i] == 0.0) {
98 idx0(n, itmp0++) = i;
99 }
100 else if (u[][i] == (-1.0)) {
101 idx2(n, itmp2++) = i;
102 }
103 else {
104 idx1(n, itmp1++) = i;
105 }
106 num0[n] = itmp0;
107 num1[n] = itmp1;
108 num2[n] = itmp2;
109 }
110 }
111 }
112
113 int withplot=3;
114 mesh Thg=square(160,160);
115 int[int] chlab=[1,1 ,2,1 ,3,1 ,4,1 ]; // Dirichlet b.c. segments w label 1
116 Thg=change(Thg,refe=chlab);
117 int npart= nn*mm;
118 fespace Ph(Thg,P0);
119 fespace Vh(Thg,P1);
120
121 Ph part;
122 Vh sun=0,unssd=0;
123 Ph xx=x,yy=y;
124 part = int(xx*nn)*mm + int(yy*mm);
125 //plot(part,wait=1);
126 if (withmetis) {
127 int[int] nupart(Thg.nt);
128 metisdual(nupart,Thg,npart);
129 for(int n=0;n<nupart.n; n++)
130 part[][n]=nupart[n];
131 }
132 if (withplot>1) {
133 plot(part,fill=1,cmm="subdomains",wait=1);
134 }
135
136 mesh[int] aTh(npart);
137 matrix[int] Rih(npart);
138 matrix[int] Dih(npart);
139
140 SubdomainsPartitionUnity(Thg, npart, part[],
141 sizeoverlaps, aTh,
142 Rih, Dih);
143
144 int nskel;
145 int[int] skelindexg(Vh.ndof);
146 nskel = SkeltonIndex(Thg, npart, aTh, Rih, Dih, skelindexg);
147 skelindexg.resize(nskel);
148 int[int] interiorn(npart);
149 int[int, int] interior(npart, Vh.ndof); // too large => max Vhi[n].ndof
150 int[int] interfn(npart);
151 int[int, int] interf(npart, Vh.ndof); // too large => max Vhi[n].nbe * 2
152 int[int] bcorign(npart);
153 int[int, int] bcorig(npart, Vh.ndof); // too large => max Vhi[n].nbe * 2
154
155 LocalIndexes(npart, aTh, interiorn, interior, interfn, interf,
156 bcorign, bcorig);
157
158 Vh sum=0,fctone=1;
159 for(int n=0; n < npart;n++) {
160 Vh localone;
161 real[int] bi = Rih[n]*fctone[]; // restriction to the local domain
162 real[int] di = Dih[n]*bi;
163 localone[] = Rih[n]'*di; // '
164 sum[] +=localone[];
165 cout << "# interior(" << n << ",) = " << interiorn[n] << " "
166 << "# interf(" << n << ",) =" << interfn[n]
167 << "# bcorig(" << n << ",) =" << bcorign[n]
168 << endl;
169 }
170
171 sum = 0;
172 for (int i = 0; i < nskel; i++) {
173 sum[][skelindexg[i]] = 1.0;
174 }
175 cout << "DOF skelton " << nskel << endl;
176 plot(sum, cmm="Skelton",wait=true);
177
178 macro Grad(u) [dx(u),dy(u)] // EOM
179
180 varf vBC(u,v)= on(1, u=1.0); // to treat original bc
181 func f = 1.0;
182 varf vexternal(u,v)=int2d(Thg)(f*v);
183 Vh fh, uglobal;
184 fh[] = vexternal(0, Vh);
185 real tgv = 1e+30;
186 real[int] bc = vBC(0, Vh, tgv=tgv);
187
188 matrix[int] AAD(npart);
189 matrix[int] AAN(npart);
190 Vh[int] Z(npart); // coarse space : only used as set of arrays
191 matrix E;
192
193 for (int n = 0; n < npart; n++) {
194 mesh Thi;
195 fespace Vhi(Thi, P1);
196 Thi = aTh[n];
197 Vhi u, v;
198 if (bcorign[n] == 0) { // floating subdomain
199 cout << n << " : floating subdomain" << endl;
200 varf aD(u,v)=int2d(Thi)(Grad(u)'*Grad(v)) + on(10, u=1.0); // '
201 varf aN(u,v)=int2d(Thi)(Grad(u)'*Grad(v)); // '
202 AAD[n] = aD(Vhi, Vhi, strategy=102,solver=sparsesolver,tolpivot=1.0e-16);
203 AAN[n] = aN(Vhi, Vhi, strategy=102,solver=sparsesolver,tolpivot=1.0e-2);
204 // Neumann matrix is singular
205 }
206 else {
207 varf aD(u,v)=int2d(Thi)(Grad(u)'*Grad(v)) + on(1,10, u=1.0); // '
208 varf aN(u,v)=int2d(Thi)(Grad(u)'*Grad(v)) + on(1, u=1.0); // '
209 AAD[n] = aD(Vhi, Vhi, strategy=102,solver=sparsesolver,tolpivot=1.0e-16);
210 AAN[n] = aN(Vhi, Vhi, strategy=102,solver=sparsesolver,tolpivot=1.0e-16);
211 }
212 }
213
214 func real[int] opS(real[int] &v)
215 {
216 real[int] s(v.n);
217 Vh vh, uh;
218 vh = 0.0;
219 for (int i = 0; i < nskel; i++) {
220 vh[][skelindexg[i]] = v[i];
221 }
222 uh = 0.0;
223 for (int n = 0; n < npart; n++) {
224 real[int] vi = Rih[n] * vh[];
225 for (int i = 0; i < interfn[n]; i++) {
226 vi[interf(n, i)] *= tgv; // tgv to treat Dirichlet data
227 }
228 for (int i = 0; i < bcorign[n]; i++) {
229 vi[bcorig(n, i)] = 0.0; // homogeneous Dirichlet data
230 }
231 real[int] ui = AAD[n]^-1 * vi; // solve local problem with Dirichlet data
232 real[int] wi = AAN[n] * ui;
233 uh[] += Rih[n]'*wi; //'
234 }
235 uh[] = bc ? 0.0 : uh[]; // set homogeneous Dirichlet on the original BC
236 for (int i = 0; i < nskel; i++) {
237 s[i] = uh[][skelindexg[i]];
238 }
239 return s;
240 }
241
242 func real[int] opNN(real[int] &v)
243 {
244 real[int] s(v.n);
245 Vh vh, uh;
246 vh = 0.0;
247 for (int i = 0; i < nskel; i++) {
248 vh[][skelindexg[i]] = v[i];
249 }
250 uh = 0.0;
251 for (int n = 0; n < npart; n++) {
252 real[int] vi = Rih[n] * vh[];
253 real[int] wi = Dih[n] * vi;
254 for (int i = 0; i < interiorn[n]; i++) {
255 wi[interior(n, i)] = 0.0;
256 }
257 for (int i = 0; i < bcorign[n]; i++) {
258 wi[bcorig(n, i)] = 0.0;
259 }
260 vi = AAN[n]^-1 * wi; // solve local problem with Dirichlet data
261 for (int i = 0; i < interiorn[n]; i++) {
262 vi[interior(n, i)] = 0.0;
263 }
264 wi = Dih[n] * vi;
265 uh[] += Rih[n]'*wi; //'
266 }
267 uh[] = bc ? 0.0 : uh[]; // set homogeneous Dirichlet on the original BC
268 for (int i = 0; i < nskel; i++) {
269 s[i] = uh[][skelindexg[i]];
270 }
271 return s;
272 }
273
274 func bool CoarseSpace(matrix &EE)
275 {
276 for (int n = 0; n < npart; n++) {
277 Z[n] = 1.0; // Z is kept on the whole domain
278 real[int] zit = Rih[n]*Z[n][];
279 real[int] zitemp = Dih[n]*zit; // with the partition of unity
280 Z[n][] = Rih[n]'*zitemp; //'
281 }
282 real[int,int] Ef(npart,npart); //
283 real[int] zz(nskel), vv(nskel);
284 Vh vh;
285 for(int m=0;m<npart;m++) {
286 for (int i = 0; i < nskel; i++) {
287 zz[i]= Z[m][][skelindexg[i]];
288 }
289 vv = opS(zz);
290 vh = 0;
291 for (int i = 0; i < nskel; i++) {
292 vh[][skelindexg[i]] = vv[i];
293 }
294 for(int n=0;n<npart;n++) {
295 Ef(m,n) = Z[n][]' * vh[]; // '
296 }
297 }
298 // symmetrize the matrix : lower -> upper
299 for(int n=0;n<npart;n++) {
300 for(int m=0;m<n;m++) {
301 Ef(m,n)=Ef(n,m);
302 }
303 }
304 EE = Ef;
305 set(EE,solver=sparsesolver,strategy=102,tolpivot=1e-2);
306 return true;
307 }
308
309 func real[int] opQ(real[int] &v) // CarseGrid solver
310 {
311 Vh vh, wh;
312 vh = 0.0;
313 for (int i = 0; i < nskel; i++) {
314 vh[][skelindexg[i]] = v[i];
315 }
316 real[int] vv(npart);
317 for(int n=0;n<npart;n++) {
318 vv[n]= Z[n][]'*vh[]; // '
319 }
320 real[int] zz=E^-1*vv;
321 wh = 0.0;
322 for(int n=0;n<npart;n++) {
323 wh[] +=zz[n]*Z[n][];
324 }
325 real[int] s(v.n);
326 for (int i = 0; i < nskel; i++) {
327 s[i] = wh[][skelindexg[i]];
328 }
329 return s;
330 }
331
332 func real[int] opP(real[int] &v) // S-orthogonal projection onto Z^T : I - SQ
333 {
334 real[int] w(v.n), sv(v.n);
335 w = opQ(v);
336 sv = opS(w);
337 w = v - sv;
338 return w;
339 }
340
341 func real[int] opPt(real[int] &v) // I - QS
342 {
343 real[int] w(v.n), sv(v.n);
344 sv = opS(v);
345 w = opQ(sv);
346 sv = v - w;
347 return sv;
348 }
349
350 func real[int] opBNN(real[int] &v)
351 {
352 real[int] s(v.n);
353 s = opQ(v);
354 real[int] ss(v.n);
355 ss = opP(v);
356 real[int] sss(v.n);
357 sss = opNN(ss);
358 ss = opPt(sss);
359 s += ss;
360 return s;
361 }
362
363 func bool plotSkelton(real[int] &v, string &str)
364 {
365 Vh uh;
366 uh = 0.0;
367 for (int i = 0; i < nskel; i++) {
368 uh[][skelindexg[i]]= v[i];
369 }
370 plot(uh,cmm=str, wait=true,value=true);
371 return true;
372 }
373
374 real[int] fskel(nskel);
375 real[int] uskel(nskel);
376 {
377 Vh vh,wh;
378 vh = 0.0;
379 fh[] = bc ? 0.0 : fh[];
380 for (int n = 0; n < npart; n++) {
381 real[int] vi = Rih[n] * fh[]; // load vector on the subdomain n
382 for (int i = 0; i < interfn[n]; i++) {
383 vi[interf(n,i)] = 0.0;
384 }
385 real[int] ui = AAD[n]^-1 * vi; // solve local problem with 0 Dirichlet
386 for (int i = 0; i < interfn[n]; i++) {
387 ui[interf(n, i)] = 0.0;
388 }
389 real[int] wi = AAN[n] * ui;
390 wh[] += Rih[n]'*wi; // '
391 }
392 wh = fh - wh; // f3 - A31 A11^-1 f1 - A32 A22^-1 f2
393 wh[] = bc ? 0.0 : wh[];
394 for (int i = 0; i < nskel; i++) {
395 fskel[i]= wh[][skelindexg[i]];
396 }
397 }
398
399 CoarseSpace(E);
400
401 string sttmp;
402 sttmp = "RHS on the skelton";
403 plotSkelton(fskel, sttmp);
404
405 uskel = 0.0;
406 LinearCG(opS, uskel, fskel, precon=opBNN,
407 nbiter=200, eps=1.e-10, verbosity=50);
408
409 sttmp = "solution on the skelton";
410 plotSkelton(uskel, sttmp);
411
412 {
413 Vh vh, wh, uh;
414 uh = 0.0;
415 for (int i = 0; i < nskel; i++) {
416 uh[][skelindexg[i]]= uskel[i];
417 }
418 uglobal = 0.0;
419 for (int n = 0; n < npart; n++) {
420 real[int] vi = Rih[n] * fh[]; // load vector on the subdomain n
421 real[int] wi = Rih[n] * uh[];
422 for (int i = 0; i < interfn[n]; i++) {
423 vi[interf(n, i)] = wi[interf(n, i)] *tgv; // tgv to treat Dirichlet data
424 }
425 real[int] ui = AAD[n]^-1 * vi; // solve local problem with Dirichlet data
426 real[int] di = Dih[n]*ui;
427 wh[] = Rih[n]'*di; // '
428 uglobal[] += wh[];
429 }
430 }
431 plot(uglobal,cmm="global", wait=true,value=true);