Debian Codegraph @

m4/pkg-config.m4

raw
1 # name, version, show-in-help?, optional?, help-text, [am-cond]
2 AC_DEFUN([AC_FLMSG_PKG_CHECK], [
3
4 m4_define([PKG_NAME_UC], m4_translit([$1], [a-z], [A-Z]))
5
6 m4_if([$3], [yes],
7 [ AC_ARG_WITH($1, AC_HELP_STRING([--with-[]$1], [$5]),
8 [case "${withval}" in
9 yes|no) ac_cv_want_[]$1="${withval}" ;;
10 *) AC_MSG_ERROR([bad value "${withval}" for --with-[]$1]) ;;
11 esac],
12 [ac_cv_want_[]$1=check])
13 ])
14 m4_if([$4], [no], [ac_cv_want_[]$1=yes])
15
16 test "x$ac_cv_want_[]$1" = "x" && ac_cv_want_[]$1="check"
17 case "x$ac_cv_want_[]$1" in
18 "xno")
19 ac_cv_[]$1=no
20 ;;
21 "xcheck")
22 PKG_CHECK_MODULES(PKG_NAME_UC, [$2], [ac_cv_[]$1=yes], [ac_cv_[]$1=no])
23 ;;
24 "xyes")
25 PKG_CHECK_MODULES(PKG_NAME_UC, [$2])
26 # if we get here the test has succeeded
27 ac_cv_[]$1=yes
28 ;;
29 esac
30
31 if test "x$ac_cv_[]$1" = "xyes"; then
32 AC_DEFINE([USE_]PKG_NAME_UC, 1, [Define to 1 if we are using $1])
33 pkg_[]$1_version=`$PKG_CONFIG --modversion "$2" 2>/dev/null`
34 else
35 AC_DEFINE([USE_]PKG_NAME_UC, 0, [Define to 1 if we are using $1])
36 pkg_[]$1_version=""
37 fi
38
39 AC_SUBST(PKG_NAME_UC[_CFLAGS])
40 AC_SUBST(PKG_NAME_UC[_LIBS])
41 AC_DEFINE_UNQUOTED(PKG_NAME_UC[_BUILD_VERSION], ["$pkg_[]$1_version"], [$1 version])
42
43 m4_ifval([$6], [ AM_CONDITIONAL([$6], [test "x$ac_cv_[]$1" = "xyes"]) ], [:])
44 ])