Debian Codegraph @

test/fuzz.fnl

raw
1 (local t (require :test.faith))
2 (local fennel (require :fennel))
3 (local generate (require :test.generate))
4 (local friend (require :fennel.friend))
5 (local unpack (or table.unpack _G.unpack))
6
7 ;; extend the generator function to produce ASTs
8 (table.insert generate.order 4 :sym)
9 (table.insert generate.order 1 :list)
10
11 (local keywords (icollect [k (pairs (doto (fennel.syntax)
12 (tset :eval-compiler nil)
13 (tset :lua nil)
14 (tset :macros nil)))] k))
15
16 (fn generate.generators.sym []
17 (case (: (generate.generators.string) :gsub "."
18 (fn [c] (if (not (fennel.sym-char? c)) "")))
19 "" (generate.generators.sym)
20 name (fennel.sym name)))
21
22 (fn generate.generators.list [gen depth]
23 (let [f (fennel.sym (. keywords (math.random (length keywords))))
24 contents (if (< 0.5 (math.random))
25 (generate.generators.sequence gen depth)
26 [])]
27 (fennel.list f (unpack contents))))
28
29 (local marker {})
30
31 (fn fuzz [verbose? seed]
32 (let [code (fennel.view (generate.generators.list generate.generate 1))
33 (ok err) (xpcall #(fennel.compile-string code {:useMetadata true
34 :compiler-env :strict})
35 #(if (= $ marker)
36 marker
37 (.. (tostring $) "\n" (debug.traceback))))]
38 (when verbose?
39 (print code))
40 (if (not ok)
41 ;; if we get an error, it must come from assert-compile; if we get
42 ;; a non-assertion error then it must be a compiler bug!
43 (t.= err marker (.. code "\n" (tostring err) "\nSeed: " seed)))))
44
45 (fn test-fuzz []
46 (let [verbose? (os.getenv "VERBOSE")
47 {: assert-compile : parse-error} friend
48 seed (os.time)]
49 (math.randomseed seed)
50 (set friend.assert-compile #(error marker))
51 (set friend.parse-error #(error marker))
52 (for [_ 1 (tonumber (or (os.getenv "FUZZ_COUNT") 256))]
53 (fuzz verbose? seed))
54 (set friend.assert-compile assert-compile)
55 (set friend.parse-error parse-error)))
56
57 {: test-fuzz}