Debian Codegraph @

src/fcml_intel_lexer.l

raw
1 /*
2 * FCML - Free Code Manipulation Library.
3 * Copyright (C) 2010-2020 Slawomir Wojtasiak
4 *
5 * This library is free software; you can redistribute it and/or
6 * modify it under the terms of the GNU Lesser General Public
7 * License as published by the Free Software Foundation; either
8 * version 2.1 of the License, or (at your option) any later version.
9 *
10 * This library is distributed in the hope that it will be useful,
11 * but WITHOUT ANY WARRANTY; without even the implied warranty of
12 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
13 * Lesser General Public License for more details.
14 *
15 * You should have received a copy of the GNU Lesser General Public
16 * License along with this library; if not, write to the Free Software
17 * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
18 */
19
20 %{
21 #include <stdio.h>
22 #include <stdlib.h>
23
24 #include "fcml_common_lex.h"
25 #include "fcml_intel_parser_def.h"
26 %}
27
28 %option noyywrap
29 %option nounput
30 %option noinput
31 %option noyyalloc
32 %option noyyrealloc
33 %option noyyfree
34 %option batch
35 %option nodefault
36 %option never-interactive
37 %option case-insensitive
38 %option 8bit
39 %option reentrant
40 %option bison-bridge
41 %option outfile="fcml_intel_lexer.c"
42 %option header-file="fcml_intel_lexer.h"
43 %option nounistd
44 %option prefix="intel_"
45 %option bison-locations
46 %option yylineno
47
48 %option extra-type="struct fcml_st_parser_data *"
49
50 %{
51 #define FCML_FM_SIZE_OPERAND(x) { \
52 yylval->size_operator.size = x; \
53 yylval->size_operator.multimedia = FCML_FALSE; \
54 return FCML_TK_SIZE_OPERATOR; }
55
56 #define FCML_FM_MULTIMEDIA_SIZE_OPERAND(x) { \
57 yylval->size_operator.size = x; \
58 yylval->size_operator.multimedia = FCML_TRUE; \
59 return FCML_TK_SIZE_OPERATOR; }
60 %}
61
62 /*White spaces.*/
63 WS [ \t]*
64 PTR (" ptr")?
65
66 %%
67
68 /* Decimal integers. */
69 [0-9]+d? { fcml_fn_pu_parse_integer( yytext, &(yylval->integer_value), 10 ); return FCML_TK_INTEGER; }
70
71 /* HEX integers. */
72 0x[0-9a-f]+ |
73 0[a-f][0-9a-f]+h |
74 [0-9][0-9a-f]*h { fcml_fn_pu_parse_integer( yytext, &(yylval->integer_value), 16 ); return FCML_TK_INTEGER; }
75
76 /* Floating-points in IEEE 754.
77 Floats are not supported yet.
78 ([0-9]*\.[0-9]+|[0-9]+\.)(e[-+]?[0-9]+)?f? |
79 [0-9]+(e[-+]?[0-9]+)f? { fcml_fn_pu_parse_float( yytext, &(yylval->float_value) ); return FCML_TK_FLOAT; }
80 */
81
82 /* GPR. */
83 "al" FCML_FM_GPRS_8_REG(FCML_REG_AL)
84 "cl" FCML_FM_GPRS_8_REG(FCML_REG_CL)
85 "dl" FCML_FM_GPRS_8_REG(FCML_REG_DL)
86 "bl" FCML_FM_GPRS_8_REG(FCML_REG_BL)
87 "ah" FCML_FM_GPRS_8_REG(FCML_REG_AH)
88 "ch" FCML_FM_GPRS_8_REG(FCML_REG_CH)
89 "dh" FCML_FM_GPRS_8_REG(FCML_REG_DH)
90 "bh" FCML_FM_GPRS_8_REG(FCML_REG_BH)
91 "r8l" FCML_FM_GPRS_8_REG(FCML_REG_R8L)
92 "r9l" FCML_FM_GPRS_8_REG(FCML_REG_R9L)
93 "r10l" FCML_FM_GPRS_8_REG(FCML_REG_R10L)
94 "r11l" FCML_FM_GPRS_8_REG(FCML_REG_R11L)
95 "r12l" FCML_FM_GPRS_8_REG(FCML_REG_R12L)
96 "r13l" FCML_FM_GPRS_8_REG(FCML_REG_R13L)
97 "r14l" FCML_FM_GPRS_8_REG(FCML_REG_R14L)
98 "r15l" FCML_FM_GPRS_8_REG(FCML_REG_R15L)
99
100 "spl" FCML_FM_GPRS_8_X_REG(FCML_REG_SPL)
101 "bpl" FCML_FM_GPRS_8_X_REG(FCML_REG_BPL)
102 "sil" FCML_FM_GPRS_8_X_REG(FCML_REG_SIL)
103 "dil" FCML_FM_GPRS_8_X_REG(FCML_REG_DIL)
104
105 "ax" FCML_FM_GPRS_16_REG(FCML_REG_AX)
106 "cx" FCML_FM_GPRS_16_REG(FCML_REG_CX)
107 "dx" FCML_FM_GPRS_16_REG(FCML_REG_DX)
108 "bx" FCML_FM_GPRS_16_REG(FCML_REG_BX)
109 "sp" FCML_FM_GPRS_16_REG(FCML_REG_SP)
110 "bp" FCML_FM_GPRS_16_REG(FCML_REG_BP)
111 "si" FCML_FM_GPRS_16_REG(FCML_REG_SI)
112 "di" FCML_FM_GPRS_16_REG(FCML_REG_DI)
113 "r8w" FCML_FM_GPRS_16_REG(FCML_REG_R8W)
114 "r9w" FCML_FM_GPRS_16_REG(FCML_REG_R9W)
115 "r10w" FCML_FM_GPRS_16_REG(FCML_REG_R10W)
116 "r11w" FCML_FM_GPRS_16_REG(FCML_REG_R11W)
117 "r12w" FCML_FM_GPRS_16_REG(FCML_REG_R12W)
118 "r13w" FCML_FM_GPRS_16_REG(FCML_REG_R13W)
119 "r14w" FCML_FM_GPRS_16_REG(FCML_REG_R14W)
120 "r15w" FCML_FM_GPRS_16_REG(FCML_REG_R15W)
121
122 "eax" FCML_FM_GPRS_32_REG(FCML_REG_EAX)
123 "ecx" FCML_FM_GPRS_32_REG(FCML_REG_ECX)
124 "edx" FCML_FM_GPRS_32_REG(FCML_REG_EDX)
125 "ebx" FCML_FM_GPRS_32_REG(FCML_REG_EBX)
126 "esp" FCML_FM_GPRS_32_REG(FCML_REG_ESP)
127 "ebp" FCML_FM_GPRS_32_REG(FCML_REG_EBP)
128 "esi" FCML_FM_GPRS_32_REG(FCML_REG_ESI)
129 "edi" FCML_FM_GPRS_32_REG(FCML_REG_EDI)
130 "r8d" FCML_FM_GPRS_32_REG(FCML_REG_R8D)
131 "r9d" FCML_FM_GPRS_32_REG(FCML_REG_R9D)
132 "r10d" FCML_FM_GPRS_32_REG(FCML_REG_R10D)
133 "r11d" FCML_FM_GPRS_32_REG(FCML_REG_R11D)
134 "r12d" FCML_FM_GPRS_32_REG(FCML_REG_R12D)
135 "r13d" FCML_FM_GPRS_32_REG(FCML_REG_R13D)
136 "r14d" FCML_FM_GPRS_32_REG(FCML_REG_R14D)
137 "r15d" FCML_FM_GPRS_32_REG(FCML_REG_R15D)
138
139 "rax" FCML_FM_GPRS_64_REG(FCML_REG_RAX)
140 "rcx" FCML_FM_GPRS_64_REG(FCML_REG_RCX)
141 "rdx" FCML_FM_GPRS_64_REG(FCML_REG_RDX)
142 "rbx" FCML_FM_GPRS_64_REG(FCML_REG_RBX)
143 "rsp" FCML_FM_GPRS_64_REG(FCML_REG_RSP)
144 "rbp" FCML_FM_GPRS_64_REG(FCML_REG_RBP)
145 "rsi" FCML_FM_GPRS_64_REG(FCML_REG_RSI)
146 "rdi" FCML_FM_GPRS_64_REG(FCML_REG_RDI)
147 "r8" FCML_FM_GPRS_64_REG(FCML_REG_R8)
148 "r9" FCML_FM_GPRS_64_REG(FCML_REG_R9)
149 "r10" FCML_FM_GPRS_64_REG(FCML_REG_R10)
150 "r11" FCML_FM_GPRS_64_REG(FCML_REG_R11)
151 "r12" FCML_FM_GPRS_64_REG(FCML_REG_R12)
152 "r13" FCML_FM_GPRS_64_REG(FCML_REG_R13)
153 "r14" FCML_FM_GPRS_64_REG(FCML_REG_R14)
154 "r15" FCML_FM_GPRS_64_REG(FCML_REG_R15)
155
156 /* SIMD-MMX */
157 "mm0" FCML_FM_SIMD_64_REG(FCML_REG_MM0)
158 "mm1" FCML_FM_SIMD_64_REG(FCML_REG_MM1)
159 "mm2" FCML_FM_SIMD_64_REG(FCML_REG_MM2)
160 "mm3" FCML_FM_SIMD_64_REG(FCML_REG_MM3)
161 "mm4" FCML_FM_SIMD_64_REG(FCML_REG_MM4)
162 "mm5" FCML_FM_SIMD_64_REG(FCML_REG_MM5)
163 "mm6" FCML_FM_SIMD_64_REG(FCML_REG_MM6)
164 "mm7" FCML_FM_SIMD_64_REG(FCML_REG_MM7)
165
166 /* SIMD-XMM */
167 "xmm0" FCML_FM_SIMD_128_REG(FCML_REG_XMM0)
168 "xmm1" FCML_FM_SIMD_128_REG(FCML_REG_XMM1)
169 "xmm2" FCML_FM_SIMD_128_REG(FCML_REG_XMM2)
170 "xmm3" FCML_FM_SIMD_128_REG(FCML_REG_XMM3)
171 "xmm4" FCML_FM_SIMD_128_REG(FCML_REG_XMM4)
172 "xmm5" FCML_FM_SIMD_128_REG(FCML_REG_XMM5)
173 "xmm6" FCML_FM_SIMD_128_REG(FCML_REG_XMM6)
174 "xmm7" FCML_FM_SIMD_128_REG(FCML_REG_XMM7)
175 "xmm8" FCML_FM_SIMD_128_REG(FCML_REG_XMM8)
176 "xmm9" FCML_FM_SIMD_128_REG(FCML_REG_XMM9)
177 "xmm10" FCML_FM_SIMD_128_REG(FCML_REG_XMM10)
178 "xmm11" FCML_FM_SIMD_128_REG(FCML_REG_XMM11)
179 "xmm12" FCML_FM_SIMD_128_REG(FCML_REG_XMM12)
180 "xmm13" FCML_FM_SIMD_128_REG(FCML_REG_XMM13)
181 "xmm14" FCML_FM_SIMD_128_REG(FCML_REG_XMM14)
182 "xmm15" FCML_FM_SIMD_128_REG(FCML_REG_XMM15)
183 "xmm16" FCML_FM_SIMD_128_REG(FCML_REG_XMM16)
184 "xmm17" FCML_FM_SIMD_128_REG(FCML_REG_XMM17)
185 "xmm18" FCML_FM_SIMD_128_REG(FCML_REG_XMM18)
186 "xmm19" FCML_FM_SIMD_128_REG(FCML_REG_XMM19)
187 "xmm20" FCML_FM_SIMD_128_REG(FCML_REG_XMM20)
188 "xmm21" FCML_FM_SIMD_128_REG(FCML_REG_XMM21)
189 "xmm22" FCML_FM_SIMD_128_REG(FCML_REG_XMM22)
190 "xmm23" FCML_FM_SIMD_128_REG(FCML_REG_XMM23)
191 "xmm24" FCML_FM_SIMD_128_REG(FCML_REG_XMM24)
192 "xmm25" FCML_FM_SIMD_128_REG(FCML_REG_XMM25)
193 "xmm26" FCML_FM_SIMD_128_REG(FCML_REG_XMM26)
194 "xmm27" FCML_FM_SIMD_128_REG(FCML_REG_XMM27)
195 "xmm28" FCML_FM_SIMD_128_REG(FCML_REG_XMM28)
196 "xmm29" FCML_FM_SIMD_128_REG(FCML_REG_XMM29)
197 "xmm30" FCML_FM_SIMD_128_REG(FCML_REG_XMM30)
198 "xmm31" FCML_FM_SIMD_128_REG(FCML_REG_XMM31)
199
200 /* SIMD-YMM */
201 "ymm0" FCML_FM_SIMD_256_REG(FCML_REG_YMM0)
202 "ymm1" FCML_FM_SIMD_256_REG(FCML_REG_YMM1)
203 "ymm2" FCML_FM_SIMD_256_REG(FCML_REG_YMM2)
204 "ymm3" FCML_FM_SIMD_256_REG(FCML_REG_YMM3)
205 "ymm4" FCML_FM_SIMD_256_REG(FCML_REG_YMM4)
206 "ymm5" FCML_FM_SIMD_256_REG(FCML_REG_YMM5)
207 "ymm6" FCML_FM_SIMD_256_REG(FCML_REG_YMM6)
208 "ymm7" FCML_FM_SIMD_256_REG(FCML_REG_YMM7)
209 "ymm8" FCML_FM_SIMD_256_REG(FCML_REG_YMM8)
210 "ymm9" FCML_FM_SIMD_256_REG(FCML_REG_YMM9)
211 "ymm10" FCML_FM_SIMD_256_REG(FCML_REG_YMM10)
212 "ymm11" FCML_FM_SIMD_256_REG(FCML_REG_YMM11)
213 "ymm12" FCML_FM_SIMD_256_REG(FCML_REG_YMM12)
214 "ymm13" FCML_FM_SIMD_256_REG(FCML_REG_YMM13)
215 "ymm14" FCML_FM_SIMD_256_REG(FCML_REG_YMM14)
216 "ymm15" FCML_FM_SIMD_256_REG(FCML_REG_YMM15)
217 "ymm16" FCML_FM_SIMD_256_REG(FCML_REG_YMM16)
218 "ymm17" FCML_FM_SIMD_256_REG(FCML_REG_YMM17)
219 "ymm18" FCML_FM_SIMD_256_REG(FCML_REG_YMM18)
220 "ymm19" FCML_FM_SIMD_256_REG(FCML_REG_YMM19)
221 "ymm20" FCML_FM_SIMD_256_REG(FCML_REG_YMM20)
222 "ymm21" FCML_FM_SIMD_256_REG(FCML_REG_YMM21)
223 "ymm22" FCML_FM_SIMD_256_REG(FCML_REG_YMM22)
224 "ymm23" FCML_FM_SIMD_256_REG(FCML_REG_YMM23)
225 "ymm24" FCML_FM_SIMD_256_REG(FCML_REG_YMM24)
226 "ymm25" FCML_FM_SIMD_256_REG(FCML_REG_YMM25)
227 "ymm26" FCML_FM_SIMD_256_REG(FCML_REG_YMM26)
228 "ymm27" FCML_FM_SIMD_256_REG(FCML_REG_YMM27)
229 "ymm28" FCML_FM_SIMD_256_REG(FCML_REG_YMM28)
230 "ymm29" FCML_FM_SIMD_256_REG(FCML_REG_YMM29)
231 "ymm30" FCML_FM_SIMD_256_REG(FCML_REG_YMM30)
232 "ymm31" FCML_FM_SIMD_256_REG(FCML_REG_YMM31)
233
234 /* SIMD-ZMM */
235 "zmm0" FCML_FM_SIMD_512_REG(FCML_REG_ZMM0)
236 "zmm1" FCML_FM_SIMD_512_REG(FCML_REG_ZMM1)
237 "zmm2" FCML_FM_SIMD_512_REG(FCML_REG_ZMM2)
238 "zmm3" FCML_FM_SIMD_512_REG(FCML_REG_ZMM3)
239 "zmm4" FCML_FM_SIMD_512_REG(FCML_REG_ZMM4)
240 "zmm5" FCML_FM_SIMD_512_REG(FCML_REG_ZMM5)
241 "zmm6" FCML_FM_SIMD_512_REG(FCML_REG_ZMM6)
242 "zmm7" FCML_FM_SIMD_512_REG(FCML_REG_ZMM7)
243 "zmm8" FCML_FM_SIMD_512_REG(FCML_REG_ZMM8)
244 "zmm9" FCML_FM_SIMD_512_REG(FCML_REG_ZMM9)
245 "zmm10" FCML_FM_SIMD_512_REG(FCML_REG_ZMM10)
246 "zmm11" FCML_FM_SIMD_512_REG(FCML_REG_ZMM11)
247 "zmm12" FCML_FM_SIMD_512_REG(FCML_REG_ZMM12)
248 "zmm13" FCML_FM_SIMD_512_REG(FCML_REG_ZMM13)
249 "zmm14" FCML_FM_SIMD_512_REG(FCML_REG_ZMM14)
250 "zmm15" FCML_FM_SIMD_512_REG(FCML_REG_ZMM15)
251 "zmm16" FCML_FM_SIMD_512_REG(FCML_REG_ZMM16)
252 "zmm17" FCML_FM_SIMD_512_REG(FCML_REG_ZMM17)
253 "zmm18" FCML_FM_SIMD_512_REG(FCML_REG_ZMM18)
254 "zmm19" FCML_FM_SIMD_512_REG(FCML_REG_ZMM19)
255 "zmm20" FCML_FM_SIMD_512_REG(FCML_REG_ZMM20)
256 "zmm21" FCML_FM_SIMD_512_REG(FCML_REG_ZMM21)
257 "zmm22" FCML_FM_SIMD_512_REG(FCML_REG_ZMM22)
258 "zmm23" FCML_FM_SIMD_512_REG(FCML_REG_ZMM23)
259 "zmm24" FCML_FM_SIMD_512_REG(FCML_REG_ZMM24)
260 "zmm25" FCML_FM_SIMD_512_REG(FCML_REG_ZMM25)
261 "zmm26" FCML_FM_SIMD_512_REG(FCML_REG_ZMM26)
262 "zmm27" FCML_FM_SIMD_512_REG(FCML_REG_ZMM27)
263 "zmm28" FCML_FM_SIMD_512_REG(FCML_REG_ZMM28)
264 "zmm29" FCML_FM_SIMD_512_REG(FCML_REG_ZMM29)
265 "zmm30" FCML_FM_SIMD_512_REG(FCML_REG_ZMM30)
266 "zmm31" FCML_FM_SIMD_512_REG(FCML_REG_ZMM31)
267
268 /* FPU */
269 st{WS}("("{WS}0{WS}")"|0) FCML_FM_FPU_REG(FCML_REG_ST0)
270 st{WS}("("{WS}1{WS}")"|1) FCML_FM_FPU_REG(FCML_REG_ST1)
271 st{WS}("("{WS}2{WS}")"|2) FCML_FM_FPU_REG(FCML_REG_ST2)
272 st{WS}("("{WS}3{WS}")"|3) FCML_FM_FPU_REG(FCML_REG_ST3)
273 st{WS}("("{WS}4{WS}")"|4) FCML_FM_FPU_REG(FCML_REG_ST4)
274 st{WS}("("{WS}5{WS}")"|5) FCML_FM_FPU_REG(FCML_REG_ST5)
275 st{WS}("("{WS}6{WS}")"|6) FCML_FM_FPU_REG(FCML_REG_ST6)
276 st{WS}("("{WS}7{WS}")"|7) FCML_FM_FPU_REG(FCML_REG_ST7)
277
278 /* Control registers. */
279 "cr0" FCML_FM_CR_REG(FCML_REG_CR0)
280 "cr2" FCML_FM_CR_REG(FCML_REG_CR2)
281 "cr3" FCML_FM_CR_REG(FCML_REG_CR3)
282 "cr4" FCML_FM_CR_REG(FCML_REG_CR4)
283 "cr8" FCML_FM_CR_REG(FCML_REG_CR8)
284
285 /* Debug registers. */
286 "dr0" FCML_FM_DR_REG(FCML_REG_DR0)
287 "dr1" FCML_FM_DR_REG(FCML_REG_DR1)
288 "dr2" FCML_FM_DR_REG(FCML_REG_DR2)
289 "dr3" FCML_FM_DR_REG(FCML_REG_DR3)
290 "dr4" FCML_FM_DR_REG(FCML_REG_DR4)
291 "dr5" FCML_FM_DR_REG(FCML_REG_DR5)
292 "dr6" FCML_FM_DR_REG(FCML_REG_DR6)
293 "dr7" FCML_FM_DR_REG(FCML_REG_DR7)
294
295 /* Segment registers. */
296 "es" FCML_FM_SEG_REG(FCML_REG_ES)
297 "cs" FCML_FM_SEG_REG(FCML_REG_CS)
298 "ss" FCML_FM_SEG_REG(FCML_REG_SS)
299 "ds" FCML_FM_SEG_REG(FCML_REG_DS)
300 "fs" FCML_FM_SEG_REG(FCML_REG_FS)
301 "gs" FCML_FM_SEG_REG(FCML_REG_GS)
302
303 /* Opmask registers. */
304 "k0" FCML_FM_OPMASK_REG(FCML_REG_K0)
305 "k1" FCML_FM_OPMASK_REG(FCML_REG_K1)
306 "k2" FCML_FM_OPMASK_REG(FCML_REG_K2)
307 "k3" FCML_FM_OPMASK_REG(FCML_REG_K3)
308 "k4" FCML_FM_OPMASK_REG(FCML_REG_K4)
309 "k5" FCML_FM_OPMASK_REG(FCML_REG_K5)
310 "k6" FCML_FM_OPMASK_REG(FCML_REG_K6)
311 "k7" FCML_FM_OPMASK_REG(FCML_REG_K7)
312
313 /* RIP */
314 "rip" FCML_FM_RIP
315
316 /* Size operators. */
317 "byte"{PTR} FCML_FM_SIZE_OPERAND( 8 )
318 "word"{PTR} FCML_FM_SIZE_OPERAND( 16 )
319 "dword"{PTR} FCML_FM_SIZE_OPERAND( 32 )
320 ("fword"|"pword"){PTR} FCML_FM_SIZE_OPERAND( 48 )
321 "qword"{PTR} FCML_FM_SIZE_OPERAND( 64 )
322 ("tbyte"|"tword"){PTR} FCML_FM_SIZE_OPERAND( 80 )
323 ("dqword"|"oword"){PTR} FCML_FM_SIZE_OPERAND( 128 )
324 "qqword"{PTR} FCML_FM_SIZE_OPERAND( 256 )
325 "mmword"{PTR} FCML_FM_MULTIMEDIA_SIZE_OPERAND( 64 )
326 ("xword"|"xmmword"){PTR} FCML_FM_MULTIMEDIA_SIZE_OPERAND( 128 )
327 ("yword"|"ymmword"){PTR} FCML_FM_MULTIMEDIA_SIZE_OPERAND( 256 )
328 ("zword"|"zmmword"){PTR} FCML_FM_MULTIMEDIA_SIZE_OPERAND( 512 )
329 ("14byte"){PTR} FCML_FM_SIZE_OPERAND( 14 * 8 )
330 ("28byte"){PTR} FCML_FM_SIZE_OPERAND( 28 * 8 )
331 ("94byte"){PTR} FCML_FM_SIZE_OPERAND( 94 * 8 )
332 ("108byte"){PTR} FCML_FM_SIZE_OPERAND( 108 * 8 )
333
334 /* opmask registers decorators. */
335 "{k1}" FCML_FM_OPMASK_REG_DECORATOR(1);
336 "{k2}" FCML_FM_OPMASK_REG_DECORATOR(2);
337 "{k3}" FCML_FM_OPMASK_REG_DECORATOR(3);
338 "{k4}" FCML_FM_OPMASK_REG_DECORATOR(4);
339 "{k5}" FCML_FM_OPMASK_REG_DECORATOR(5);
340 "{k6}" FCML_FM_OPMASK_REG_DECORATOR(6);
341 "{k7}" FCML_FM_OPMASK_REG_DECORATOR(7);
342
343 /* bcast decorators. */
344 "{1to2}" FCML_FM_BCAST_DECORATOR(2);
345 "{1to4}" FCML_FM_BCAST_DECORATOR(4);
346 "{1to8}" FCML_FM_BCAST_DECORATOR(8);
347 "{1to16}" FCML_FM_BCAST_DECORATOR(16);
348 "{1to32}" FCML_FM_BCAST_DECORATOR(32);
349 "{1to64}" FCML_FM_BCAST_DECORATOR(64);
350
351 /* embedded rounding. */
352 "{rn-sae}" FCML_FM_ER_DECORATOR(0);
353 "{rd-sae}" FCML_FM_ER_DECORATOR(1);
354 "{ru-sae}" FCML_FM_ER_DECORATOR(2);
355 "{rz-sae}" FCML_FM_ER_DECORATOR(3);
356
357 /* zeroying. */
358 "{z}" { return FCML_TK_DECORATOR_Z; }
359
360 /* Suppress all expression. */
361 "{sae}" { return FCML_TK_DECORATOR_SAE; }
362
363 /* Prefixes */
364
365 "lock" {
366 yylval->prefixes = FCML_PREFIX_LOCK;
367 return FCML_TK_PREFIX;
368 }
369
370 "repne"|"repnz" {
371 yylval->prefixes = FCML_PREFIX_REPNE;
372 return FCML_TK_PREFIX;
373 }
374
375 "repe"|"repz"|"rep" {
376 yylval->prefixes = FCML_PREFIX_REPE;
377 return FCML_TK_PREFIX;
378 }
379
380 "xacquire" {
381 yylval->prefixes = FCML_PREFIX_XACQUIRE;
382 return FCML_TK_PREFIX;
383 }
384
385 "xrelease" {
386 yylval->prefixes = FCML_PREFIX_XRELEASE;
387 return FCML_TK_PREFIX;
388 }
389
390 "branch" {
391 yylval->hints = FCML_PREFIX_BRANCH_HINT;
392 return FCML_TK_PREFIX;
393 }
394
395 "nobranch" {
396 yylval->hints = FCML_PREFIX_NOBRANCH_HINT;
397 return FCML_TK_PREFIX;
398 }
399
400 /* Hints */
401
402 "far" {
403 yylval->hints = FCML_HINT_FAR_POINTER;
404 return FCML_TK_HINTS;
405 }
406
407 "near" {
408 yylval->hints = FCML_HINT_NEAR_POINTER;
409 return FCML_TK_HINTS;
410 }
411
412 "long_form" {
413 yylval->hints = FCML_HINT_LONG_FORM_POINTER;
414 return FCML_TK_HINTS;
415 }
416
417 "indirect" {
418 yylval->hints = FCML_HINT_INDIRECT_POINTER;
419 return FCML_TK_HINTS;
420 }
421
422 "direct" {
423 yylval->hints = FCML_HINT_DIRECT_POINTER;
424 return FCML_TK_HINTS;
425 }
426
427 "rel" {
428 yylval->hints = FCML_OP_HINT_RELATIVE_ADDRESSING;
429 return FCML_TK_EAO_HINTS;
430 }
431
432 "abs" {
433 yylval->hints = FCML_OP_HINT_ABSOLUTE_ADDRESSING;
434 return FCML_TK_EAO_HINTS;
435 }
436
437 "sib" {
438 yylval->hints = FCML_OP_HINT_SIB_ENCODING;
439 return FCML_TK_SIB_HINT;
440 }
441
442 /* Identifiers. */
443 [a-z_][0-9a-z_]* {
444 yylval->symbol.text = (fcml_string)yytext;
445 yylval->symbol.length = (fcml_usize)yyleng;
446 return FCML_TK_SYMBOL;
447 }
448
449 /* Operators and parentheses. */
450 "," { return ','; }
451 "+" { return '+'; }
452 "-" { return '-'; }
453 "*" { return '*'; }
454 "/" { return '/'; }
455 "[" { return '['; }
456 "]" { return ']'; }
457 "(" { return '('; }
458 ")" { return ')'; }
459 ":" { return ':'; }
460
461 /* Ignore white spaces. */
462 {WS}
463
464 /* Anything else is not expected. */
465 . { return FCML_TK_UNEXPECTED; }
466
467 /* Ignore like white spaces. */
468 \n
469
470 %%
471