Debian Codegraph @

qt5/dbusaddons/CMakeLists.txt

raw
1 ecm_setup_version(${FcitxQt5_VERSION} VARIABLE_PREFIX FCITXQT5DBUSADDONS
2 VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/fcitxqtdbusaddons_version.h"
3 PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/FcitxQt5DBusAddonsConfigVersion.cmake"
4 SOVERSION 1)
5
6 # create a Config.cmake and a ConfigVersion.cmake file and install them
7 set(CMAKECONFIG_INSTALL_DIR "${CMAKE_INSTALL_LIBDIR}/cmake/FcitxQt5DBusAddons")
8
9 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/FcitxQt5DBusAddonsConfig.cmake.in"
10 "${CMAKE_CURRENT_BINARY_DIR}/FcitxQt5DBusAddonsConfig.cmake"
11 INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
12 )
13
14 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/FcitxQt5DBusAddonsConfig.cmake"
15 "${CMAKE_CURRENT_BINARY_DIR}/FcitxQt5DBusAddonsConfigVersion.cmake"
16 DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
17 COMPONENT Devel )
18
19 install(EXPORT FcitxQt5DBusAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE FcitxQt5DBusAddonsTargets.cmake NAMESPACE FcitxQt5:: )
20
21 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fcitxqtdbusaddons_version.h
22 DESTINATION ${FcitxQt5_INCLUDE_INSTALL_DIR} COMPONENT Devel )
23
24 set(dbusaddons_SOURCES
25 fcitxqtconnection.cpp
26 fcitxqtformattedpreedit.cpp
27 fcitxqtinputcontextproxy.cpp
28 fcitxqtinputmethodproxy.cpp
29 fcitxqtkeyboardlayout.cpp
30 fcitxqtkeyboardproxy.cpp
31 fcitxqtinputmethoditem.cpp
32 )
33
34 set(dbusaddons_HEADERS
35 fcitxqtconnection.h
36 fcitxqtformattedpreedit.h
37 fcitxqtinputcontextproxy.h
38 fcitxqtinputmethodproxy.h
39 fcitxqtkeyboardlayout.h
40 fcitxqtkeyboardproxy.h
41 fcitxqtinputmethoditem.h
42 )
43
44 set(fcitxqtdbusaddons_INCLUDE_DIRS
45 ${CMAKE_CURRENT_BINARY_DIR}
46 ${CMAKE_CURRENT_SOURCE_DIR}
47 )
48
49 add_library(FcitxQt5DBusAddons SHARED ${dbusaddons_SOURCES})
50 generate_export_header(FcitxQt5DBusAddons BASE_NAME FcitxQtDBusAddons)
51 add_library(FcitxQt5::DBusAddons ALIAS FcitxQt5DBusAddons)
52
53 target_include_directories(FcitxQt5DBusAddons PUBLIC "$<BUILD_INTERFACE:${fcitxqtdbusaddons_INCLUDE_DIRS}>")
54 target_include_directories(FcitxQt5DBusAddons INTERFACE "$<INSTALL_INTERFACE:${FcitxQt5_INCLUDE_INSTALL_DIR}/FcitxQtDBusAddons>")
55
56 set_target_properties(FcitxQt5DBusAddons
57 PROPERTIES VERSION 1.0
58 AUTOMOC TRUE
59 SOVERSION 1
60 COMPILE_FLAGS "-fvisibility=hidden"
61 LINK_FLAGS "-Wl,--no-undefined"
62 EXPORT_NAME DBusAddons
63 )
64
65 target_link_libraries(
66 FcitxQt5DBusAddons
67 PUBLIC
68 Qt5::Core
69 Qt5::DBus
70 )
71
72 install(TARGETS FcitxQt5DBusAddons EXPORT FcitxQt5DBusAddonsTargets LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}")
73
74 install(FILES ${dbusaddons_HEADERS}
75 ${CMAKE_CURRENT_BINARY_DIR}/fcitxqtdbusaddons_export.h
76 DESTINATION "${FcitxQt5_INCLUDE_INSTALL_DIR}/FcitxQtDBusAddons")
77
78