Debian Codegraph @

cmake/link_to_faiss_lib.cmake

raw
1 # @lint-ignore-every LICENSELINT
2 # Copyright (c) Meta Platforms, Inc. and affiliates.
3 #
4 # This source code is licensed under the MIT license found in the
5 # LICENSE file in the root directory of this source tree.
6
7 function(link_to_faiss_lib target)
8 if(NOT FAISS_OPT_LEVEL STREQUAL "avx2" AND NOT FAISS_OPT_LEVEL STREQUAL "avx512" AND NOT FAISS_OPT_LEVEL STREQUAL "avx512_spr" AND NOT FAISS_OPT_LEVEL STREQUAL "sve")
9 target_link_libraries(${target} PRIVATE faiss)
10 endif()
11
12 if(FAISS_OPT_LEVEL STREQUAL "avx2")
13 if(NOT WIN32)
14 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-mavx2 -mfma>)
15 else()
16 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX2>)
17 endif()
18 target_link_libraries(${target} PRIVATE faiss_avx2)
19 endif()
20
21 if(FAISS_OPT_LEVEL STREQUAL "avx512")
22 if(NOT WIN32)
23 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-mavx2 -mfma -mavx512f -mavx512f -mavx512cd -mavx512vl -mavx512dq -mavx512bw>)
24 else()
25 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX512>)
26 endif()
27 target_link_libraries(${target} PRIVATE faiss_avx512)
28 endif()
29
30 if(FAISS_OPT_LEVEL STREQUAL "avx512_spr")
31 if(NOT WIN32)
32 # Architecture mode to support AVX512 extensions available since Intel (R) Sapphire Rapids.
33 # Ref: https://networkbuilders.intel.com/solutionslibrary/intel-avx-512-fp16-instruction-set-for-intel-xeon-processor-based-products-technology-guide
34 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-march=sapphirerapids -mtune=sapphirerapids>)
35 else()
36 target_compile_options(${target} PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX512>)
37 endif()
38 target_link_libraries(${target} PRIVATE faiss_avx512_spr)
39 endif()
40
41 if(FAISS_OPT_LEVEL STREQUAL "sve")
42 if(NOT WIN32)
43 if("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )-march=native")
44 # Do nothing, expect SVE to be enabled by -march=native
45 elseif("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )(-march=armv[0-9]+(\\.[1-9]+)?-[^+ ](\\+[^+$ ]+)*)")
46 # Add +sve
47 target_compile_options(${target} PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:DEBUG>>:${CMAKE_MATCH_2}+sve>)
48 elseif(NOT "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )-march=armv")
49 # No valid -march, so specify -march=armv8-a+sve as the default
50 target_compile_options(${target} PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:DEBUG>>:-march=armv8-a+sve>)
51 endif()
52 if("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )-march=native")
53 # Do nothing, expect SVE to be enabled by -march=native
54 elseif("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )(-march=armv[0-9]+(\\.[1-9]+)?-[^+ ](\\+[^+$ ]+)*)")
55 # Add +sve
56 target_compile_options(${target} PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:${CMAKE_MATCH_2}+sve>)
57 elseif(NOT "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )-march=armv")
58 # No valid -march, so specify -march=armv8-a+sve as the default
59 target_compile_options(${target} PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:-march=armv8-a+sve>)
60 endif()
61 else()
62 # TODO: support Windows
63 endif()
64 target_link_libraries(${target} PRIVATE faiss_sve)
65 endif()
66 endfunction()