| 1 |
# Copyright (c) Meta Platforms, Inc. and affiliates. |
| 2 |
# |
| 3 |
# This source code is licensed under the MIT license found in the |
| 4 |
# LICENSE file in the root directory of this source tree. |
| 5 |
|
| 6 |
cmake_minimum_required(VERSION 3.17 FATAL_ERROR) |
| 7 |
|
| 8 |
project(faiss_c_library LANGUAGES C CXX) |
| 9 |
|
| 10 |
set(CMAKE_C_STANDARD 11) |
| 11 |
|
| 12 |
set(FAISS_C_SRC |
| 13 |
AutoTune_c.cpp |
| 14 |
Clustering_c.cpp |
| 15 |
IndexFlat_c.cpp |
| 16 |
IndexIVFFlat_c.cpp |
| 17 |
IndexIVF_c.cpp |
| 18 |
IndexLSH_c.cpp |
| 19 |
IndexPreTransform_c.cpp |
| 20 |
VectorTransform_c.cpp |
| 21 |
IndexShards_c.cpp |
| 22 |
IndexReplicas_c.cpp |
| 23 |
Index_c.cpp |
| 24 |
IndexBinary_c.cpp |
| 25 |
IndexBinaryIVF_c.cpp |
| 26 |
IndexScalarQuantizer_c.cpp |
| 27 |
MetaIndexes_c.cpp |
| 28 |
clone_index_c.cpp |
| 29 |
error_impl.cpp |
| 30 |
index_factory_c.cpp |
| 31 |
index_io_c.cpp |
| 32 |
impl/AuxIndexStructures_c.cpp |
| 33 |
impl/io_c.cpp |
| 34 |
utils/distances_c.cpp |
| 35 |
utils/utils_c.cpp |
| 36 |
) |
| 37 |
|
| 38 |
add_library(faiss_c ${FAISS_C_SRC}) |
| 39 |
target_link_libraries(faiss_c PRIVATE faiss) |
| 40 |
|
| 41 |
add_library(faiss_c_avx2 ${FAISS_C_SRC}) |
| 42 |
target_link_libraries(faiss_c_avx2 PRIVATE faiss_avx2) |
| 43 |
if(NOT FAISS_OPT_LEVEL STREQUAL "avx2" AND NOT FAISS_OPT_LEVEL STREQUAL "avx512" AND NOT FAISS_OPT_LEVEL STREQUAL "avx512_spr") |
| 44 |
set_target_properties(faiss_c_avx2 PROPERTIES EXCLUDE_FROM_ALL TRUE) |
| 45 |
endif() |
| 46 |
if(NOT WIN32) |
| 47 |
target_compile_options(faiss_c_avx2 PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-mavx2 -mfma -mf16c -mpopcnt>) |
| 48 |
else() |
| 49 |
# MSVC enables FMA with /arch:AVX2; no separate flags for F16C, POPCNT |
| 50 |
# Ref. FMA (under /arch:AVX2): https://docs.microsoft.com/en-us/cpp/build/reference/arch-x64 |
| 51 |
# Ref. F16C (2nd paragraph): https://walbourn.github.io/directxmath-avx2/ |
| 52 |
# Ref. POPCNT: https://docs.microsoft.com/en-us/cpp/intrinsics/popcnt16-popcnt-popcnt64 |
| 53 |
target_compile_options(faiss_c_avx2 PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX2>) |
| 54 |
endif() |
| 55 |
|
| 56 |
add_library(faiss_c_avx512 ${FAISS_C_SRC}) |
| 57 |
target_link_libraries(faiss_c_avx512 PRIVATE faiss_avx512) |
| 58 |
if(NOT FAISS_OPT_LEVEL STREQUAL "avx512") |
| 59 |
set_target_properties(faiss_c_avx512 PROPERTIES EXCLUDE_FROM_ALL TRUE) |
| 60 |
endif() |
| 61 |
if(NOT WIN32) |
| 62 |
# All modern CPUs support F, CD, VL, DQ, BW extensions. |
| 63 |
# Ref: https://en.wikipedia.org/wiki/AVX512 |
| 64 |
target_compile_options(faiss_c_avx512 PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-mavx2 -mfma -mf16c -mavx512f -mavx512cd -mavx512vl -mavx512dq -mavx512bw -mpopcnt>) |
| 65 |
else() |
| 66 |
target_compile_options(faiss_c_avx512 PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX512>) |
| 67 |
endif() |
| 68 |
|
| 69 |
add_library(faiss_c_avx512_spr ${FAISS_C_SRC}) |
| 70 |
target_link_libraries(faiss_c_avx512_spr PRIVATE faiss_avx512_spr) |
| 71 |
if(NOT FAISS_OPT_LEVEL STREQUAL "avx512_spr") |
| 72 |
set_target_properties(faiss_c_avx512_spr PROPERTIES EXCLUDE_FROM_ALL TRUE) |
| 73 |
endif() |
| 74 |
if(NOT WIN32) |
| 75 |
# Architecture mode to support AVX512 extensions available since Intel(R) Sapphire Rapids. |
| 76 |
# Ref: https://networkbuilders.intel.com/solutionslibrary/intel-avx-512-fp16-instruction-set-for-intel-xeon-processor-based-products-technology-guide |
| 77 |
target_compile_options(faiss_c_avx512_spr PRIVATE $<$<COMPILE_LANGUAGE:CXX>:-march=sapphirerapids -mtune=sapphirerapids>) |
| 78 |
else() |
| 79 |
target_compile_options(faiss_c_avx512_spr PRIVATE $<$<COMPILE_LANGUAGE:CXX>:/arch:AVX512>) |
| 80 |
endif() |
| 81 |
|
| 82 |
add_library(faiss_c_sve ${FAISS_C_SRC}) |
| 83 |
target_link_libraries(faiss_c_sve PRIVATE faiss_sve) |
| 84 |
if(NOT FAISS_OPT_LEVEL STREQUAL "sve") |
| 85 |
set_target_properties(faiss_c_sve PROPERTIES EXCLUDE_FROM_ALL TRUE) |
| 86 |
endif() |
| 87 |
if(NOT WIN32) |
| 88 |
if("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )-march=native") |
| 89 |
# Do nothing, expect SVE to be enabled by -march=native |
| 90 |
elseif("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )(-march=armv[0-9]+(\\.[1-9]+)?-[^+ ](\\+[^+$ ]+)*)") |
| 91 |
# Add +sve |
| 92 |
target_compile_options(faiss_c_sve PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:DEBUG>>:${CMAKE_MATCH_2}+sve>) |
| 93 |
elseif(NOT "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG} " MATCHES "(^| )-march=armv") |
| 94 |
# No valid -march, so specify -march=armv8-a+sve as the default |
| 95 |
target_compile_options(faiss_c_sve PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:DEBUG>>:-march=armv8-a+sve>) |
| 96 |
endif() |
| 97 |
if("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )-march=native") |
| 98 |
# Do nothing, expect SVE to be enabled by -march=native |
| 99 |
elseif("${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )(-march=armv[0-9]+(\\.[1-9]+)?-[^+ ](\\+[^+$ ]+)*)") |
| 100 |
# Add +sve |
| 101 |
target_compile_options(faiss_c_sve PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:${CMAKE_MATCH_2}+sve>) |
| 102 |
elseif(NOT "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE} " MATCHES "(^| )-march=armv") |
| 103 |
# No valid -march, so specify -march=armv8-a+sve as the default |
| 104 |
target_compile_options(faiss_c_sve PRIVATE $<$<AND:$<COMPILE_LANGUAGE:CXX>,$<CONFIG:RELEASE>>:-march=armv8-a+sve>) |
| 105 |
endif() |
| 106 |
endif() |
| 107 |
|
| 108 |
function(faiss_install_headers headers p) |
| 109 |
foreach(h ${headers}) |
| 110 |
get_filename_component(f ${h} DIRECTORY) |
| 111 |
install(FILES ${h} |
| 112 |
DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/faiss/${p}/${f} |
| 113 |
) |
| 114 |
endforeach() |
| 115 |
endfunction() |
| 116 |
|
| 117 |
file(GLOB FAISS_C_API_HEADERS |
| 118 |
RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} |
| 119 |
"*.h" |
| 120 |
"impl/*.h" |
| 121 |
"utils/*.h") |
| 122 |
|
| 123 |
faiss_install_headers("${FAISS_C_API_HEADERS}" c_api) |
| 124 |
|
| 125 |
install(TARGETS faiss_c |
| 126 |
EXPORT faiss-targets |
| 127 |
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 128 |
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 129 |
) |
| 130 |
if(FAISS_OPT_LEVEL STREQUAL "avx2") |
| 131 |
install(TARGETS faiss_c_avx2 |
| 132 |
EXPORT faiss-targets |
| 133 |
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 134 |
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 135 |
) |
| 136 |
endif() |
| 137 |
if(FAISS_OPT_LEVEL STREQUAL "avx512") |
| 138 |
install(TARGETS faiss_c_avx2 faiss_c_avx512 |
| 139 |
EXPORT faiss-targets |
| 140 |
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 141 |
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 142 |
) |
| 143 |
endif() |
| 144 |
if(FAISS_OPT_LEVEL STREQUAL "avx512_spr") |
| 145 |
install(TARGETS faiss_c_avx2 faiss_c_avx512_spr |
| 146 |
EXPORT faiss-targets |
| 147 |
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 148 |
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 149 |
) |
| 150 |
endif() |
| 151 |
if(FAISS_OPT_LEVEL STREQUAL "sve") |
| 152 |
install(TARGETS faiss_c_sve |
| 153 |
EXPORT faiss-targets |
| 154 |
ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 155 |
LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} |
| 156 |
) |
| 157 |
endif() |
| 158 |
|
| 159 |
add_executable(example_c EXCLUDE_FROM_ALL example_c.c) |
| 160 |
target_link_libraries(example_c PRIVATE faiss_c) |
| 161 |
|
| 162 |
if(FAISS_ENABLE_GPU) |
| 163 |
add_subdirectory(gpu) |
| 164 |
endif() |