Debian Codegraph @

tests/risky_ss/jermann98.mod

raw
1 // This is the Ramsey model with adjustment costs. Jermann(1998),JME 41, pages 257-275
2 // Olaf Weeken
3 // Bank of England, 13 June, 2005
4 // modified January 20, 2006 by Michel Juillard
5
6 //---------------------------------------------------------------------
7 // 1. Variable declaration
8 //---------------------------------------------------------------------
9
10 var c, d, erp1, i, k, m1, r1, rf1, w, y, z, mu;
11 varexo ez;
12
13 //---------------------------------------------------------------------
14 // 2. Parameter declaration and calibration
15 //---------------------------------------------------------------------
16
17 parameters alf, chihab, xi, delt, tau, g, rho, zbar, a1, a2, betstar, bet;
18
19 alf = 0.36; // capital share in production function
20 //chihab = 0.819; // habit formation parameter
21 chihab = 0.98; // habit formation parameter
22 xi = 1/4.3; // capital adjustment cost parameter
23 delt = 0.025; // quarterly deprecition rate
24 g = 1.005; //quarterly growth rate (note zero growth =>g=1)
25 tau = 5; // curvature parameter with respect to c
26 rho = 0.95; // AR(1) parameter for technology shock
27
28 a1 = (g-1+delt)^(1/xi);
29 a2 = (g-1+delt)-(((g-1+delt)^(1/xi))/(1-(1/xi)))*((g-1+delt)^(1-(1/xi)));
30 betstar = g/1.011138;
31 bet = betstar/(g^(1-tau));
32
33 //---------------------------------------------------------------------
34 // 3. Model declaration
35 //---------------------------------------------------------------------
36
37 model(use_dll);
38 g*k = (1-delt)*k(-1) + ((a1/(1-1/xi))*(g*i/k(-1))^(1-1/xi)+a2)*k(-1);
39 d = y - w - i;
40 w = (1-alf)*y;
41 y = z*g^(-alf)*k(-1)^alf;
42 c = w + d;
43 mu = (c-chihab*c(-1)/g)^(-tau)-chihab*bet*(c(+1)*g-chihab*c)^(-tau);
44 mu = (betstar/g)*mu(+1)*(a1*(g*i/k(-1))^(-1/xi))*(alf*z(+1)*g^(1-alf)*
45 (k^(alf-1))+((1-delt+(a1/(1-1/xi))*(g*i(+1)/k)^(1-1/xi)+a2))/
46 (a1*(g*i(+1)/k)^(-1/xi))-g*i(+1)/k);
47 log(z) = rho*log(z(-1)) + ez;
48
49 m1 = (betstar/g)*mu(+1)/mu;
50 rf1 = 1/m1;
51 r1 = (a1*(g*i/k(-1))^(-1/xi))*(alf*z(+1)*g^(1-alf)*(k^(alf-1))+
52 (1-delt+(a1/(1-1/xi))*(g*i(+1)/k)^(1-1/xi)+a2)/
53 (a1*(g*i(+1)/k)^(-1/xi))-g*i(+1)/k);
54 erp1 = r1 - rf1;
55
56 end;
57
58 //---------------------------------------------------------------------
59 // 4. Initial values and steady state
60 //---------------------------------------------------------------------
61
62 initval;
63 m1 = betstar/g;
64 rf1 = (1/m1);
65 r1 = (1/m1);
66 erp1 = r1-rf1;
67
68 z = 1;
69 k = (((g/betstar)-(1-delt))/(alf*g^(1-alf)))^(1/(alf-1));
70 y = (g^(-alf))*k^alf;
71 w = (1-alf)*y;
72 i = (1-(1/g)*(1-delt))*k;
73 d = y - w - i;
74 c = w + d;
75
76 mu = ((c-(chihab*c/g))^(-tau))-chihab*bet*((c*g-chihab*c)^(-tau));
77
78 ez = 0;
79 end;
80
81 resid;
82
83 steady;
84
85 //---------------------------------------------------------------------
86 // 5. Shock declaration
87 //
88 //---------------------------------------------------------------------
89
90 shocks;
91 var ez; stderr 0.001;
92 end;
93
94 options_.risky_steadystate = true;
95 stoch_simul (order=3,irf=0,periods=20000) erp1, rf1, m1, r1, y, z, c, d, mu, k;