Debian Codegraph @

tests/kalman_filter_smoother/SOE.mod

raw
1 var pi_h y_hat i r_nat a y_star nu s y y_nat z z_star z_e dY_o dY_star_o dP_o I_o p_h e i_star de_o;
2
3 varexo eps_a eps_nu eps_star eps_z eps_z_star eps_z_e;
4
5 parameters alpha varphi beta theta gamma sigma eta rho_nu rho_a rho_star phi_pi phi_y sig_a sig_nu sig_star sig_z sig_z_e gY gY_star sig_z_star gP gi ge;
6
7 gY = 0.3783;
8 gY_star = 0.3783;
9 gP = 0.3845;
10 gi = 2.5197;
11 ge = 0;
12 beta = 0.99;
13 alpha = 0.53;
14 sigma = 0.7;
15 gamma = 1.6;
16 eta = 1.5;
17 varphi = 5;
18 theta = 3/4;
19 rho_nu = 0.5;
20 rho_a = 0.9;
21 rho_star = 0.5;
22 phi_pi = 1.5;
23 phi_y = 0.5/4;
24 sig_a = 0.0405;
25 sig_nu = 0.0031;
26 sig_star = 0.1;
27
28 sig_z = 0.0109;
29 sig_z_star = 0.0109;
30 sig_z_e = 0.0109;
31
32
33 model(linear);
34 #omega = sigma*gamma + (1-alpha)*(sigma*eta-1);
35 #lambda = (1-beta*theta)*(1-theta)/theta;
36 #sigma_alpha = sigma/(1+alpha*(omega-1));
37 #Theta = omega-1;
38 #Gamma_a = (1+varphi)/(sigma_alpha+varphi);
39 #Gamma_star = -alpha*Theta*sigma_alpha/(sigma_alpha+varphi);
40 #kappa_alpha = lambda*(sigma_alpha*varphi);
41
42
43 pi_h = beta*pi_h(+1) + kappa_alpha*y_hat; //NKPC
44 y_hat = y_hat(+1) - 1/sigma_alpha*(i-pi_h(+1)-r_nat); //DIS
45 r_nat = -sigma_alpha*Gamma_a*(1-rho_a)*a+alpha*Theta*sigma_alpha*varphi/(sigma_alpha+varphi)*(y_star(+1)-y_star); //Natural interest rate
46 a = rho_a*a(-1)+eps_a; //Technology
47 i = phi_pi*pi_h + phi_y*y_hat + nu; //Taylor rule
48 nu = rho_nu*nu(-1) + eps_nu; //Monetary shock
49 s = sigma_alpha*(y-y_star); //Equation 29
50 y_hat = y - y_nat; //Output gap
51 y_nat = Gamma_a*a + Gamma_star*y_star; //Natural output
52 y_star = rho_star*y_star(-1)+eps_star; //Foreign GDP growth
53 e = s + p_h; //PPP
54 //e-e(-1) = s - s(-1) + pi_h; //PPP Modified
55 pi_h = p_h - 0.9999999*p_h(-1); //Definition of inflation. If coef = 1, problem of singularity and estimation doesn't work
56 i = i_star + e(+1) - e; //UIP
57
58 //Observables
59 dY_o = gY + 100*(y - y(-1) + z) ;
60 z = eps_z;
61 dY_star_o = gY_star + 100*(y_star - y_star(-1) + z_star) ;
62 z_star = eps_z_star;
63 dP_o = gP + 100*pi_h ;
64 I_o = gi + 400*i ;
65 de_o = ge + 100*(e - e(-1) + z_e);
66 z_e = eps_z_e;
67
68 end;
69
70
71 shocks;
72 var eps_a=sig_a^2;
73 var eps_nu=sig_nu^2;
74 var eps_star=sig_star^2;
75 var eps_z = sig_z^2;
76 var eps_z_star = sig_z_star^2;
77 var eps_z_e = sig_z_e^2;
78 end;
79
80 steady;
81
82 varobs dY_o dY_star_o dP_o I_o de_o;
83
84 estimated_params;
85
86 gY, normal_pdf, 0.3783, 0.10 ;
87 gY_star, normal_pdf, 0.3783, 0.10 ;
88 gP, normal_pdf, 0.3845, 0.10;
89 gi, normal_pdf, 2.5197, 0.50;
90 ge, normal_pdf, 0, 0.1;
91 sigma, normal_pdf, 0.7, 0.1 ;
92 gamma, normal_pdf, 1.6, 0.3 ;
93 eta, normal_pdf, 1.5, 0.3;
94 varphi, normal_pdf, 2.05, 0.6;
95 theta, beta_pdf, 3/4, 0.05;
96 rho_nu, beta_pdf, 0.5, 0.1;
97 rho_a, beta_pdf, 0.7, 0.1;
98 rho_star, beta_pdf, 0.5, 0.1;
99 phi_pi, normal_pdf, 1.5, 0.1;
100 phi_y, normal_pdf, 0.125, 0.05;
101 stderr eps_a, uniform_pdf, , , 0, 0.1;
102 stderr eps_z, uniform_pdf, , , 0, 0.2;
103 stderr eps_nu, uniform_pdf, , , 0, 0.1;
104 stderr eps_star, uniform_pdf, , , 0, 0.1;
105 stderr eps_z_star, uniform_pdf, , , 0, 0.1;
106 stderr eps_z_e, uniform_pdf, , , 0, 0.1;
107
108 end;
109
110 options_.diffuse_filter=1;
111 stoch_simul(nograph);
112 calib_smoother(datafile=SOE_data_file,smoothed_state_uncertainty) dY_o dY_star_o dP_o I_o de_o;