Debian Codegraph @

tests/heterogeneity/hank_1a_steady_state.mod

raw
1 heterogeneity_dimension households;
2
3 var(heterogeneity=households)
4 c // consumption
5 n // labor supply
6 ns // effective labor supply
7 a // assets
8 ;
9
10 varexo(heterogeneity=households)
11 e // idiosyncratic efficiency
12 ;
13
14 var
15 Y L w pi Div Tax r
16 ;
17
18 varexo G markup rstar;
19
20 shocks;
21 var G; stderr 0.01;
22 var markup; stderr 0.01;
23 var rstar; stderr 0.01;
24 end;
25
26 parameters
27 beta vphi
28 eis frisch
29 rho_e sig_e
30 rho_Z sig_Z
31 mu kappa phi
32 Z B r_ss
33 ;
34
35 model(heterogeneity=households);
36 // Euler equation with borrowing constraint
37 c^(-1/eis) - beta * (1 + r(+1)) * c(+1)^(-1/eis) = 0 ⟂ a >= 0;
38
39 // Budget constraint
40 (1 + r) * a(-1) + w * n * e + (Div-Tax) * e - c - a;
41
42 // Intratemporal FOC for labor supply
43 vphi*n^(1/frisch) - w*e*c^(-1/eis);
44
45 // Definition of the effective labor supply
46 ns = n * e;
47 end;
48
49 model;
50 // Firm
51 L - Y / Z;
52 Div - (Y - w * L - mu / (mu - 1) / (2 * kappa) * log(1 + pi)^2 * Y);
53
54 // Monetary policy (Taylor rule)
55 (1 + r_ss + rstar(-1) + phi * pi(-1)) / (1 + pi) - 1 - r;
56
57 // Fiscal policy
58 Tax - (r * B) - G;
59
60 // NKPC
61 kappa * (w / Z - 1 / mu)
62 + Y(+1)/Y * log(1 + pi(+1)) / (1 + r(+1))
63 + markup
64 - log(1 + pi);
65
66 // Market clearing
67 [name='capital_market_clearing']
68 SUM(a) - B; // asset market
69 sum(ns) - L; // labor market
70 end;
71
72 load 'hank_1a_sp.mat';
73
74 param_names = fieldnames(steady_state.params);
75 for i=1:numel(param_names)
76 param = param_names{i};
77 set_param_value(param, steady_state.params.(param));
78 end
79
80 heterogeneity_compute_steady_state(filename=hank_1a_sp, calibration_target_equations=['capital_market_clearing'], time_iteration_solver_stop_on_error,time_iteration_verbosity=0,forward_verbosity=0);
81
82 heterogeneity_solve;
83
84 if max(abs(oo_.heterogeneity.mat.G(:))) > 1e-4
85 error('Aggregate-block residuals are too big!');
86 end
87 if max(abs(oo_.heterogeneity.mat.F(:))) > 1e-8
88 error('Heterogeneous-block residuals are too big');
89 end
90
91 heterogeneity_simulate;