| 1 |
// See fs2000.mod in the examples/ directory for details on the model |
| 2 |
// This file is the same than fs2000a.mod, except that it is written in non-stationary form |
| 3 |
// Notational changes: "m" and "dA" in fs2000a.mod are here called "gM" and "gA" |
| 4 |
|
| 5 |
var gM ${g^M}$ gA ${g^A}$; |
| 6 |
trend_var(growth_factor=gA) A; |
| 7 |
trend_var(growth_factor=gM) M; |
| 8 |
var(deflator=A) k c y; |
| 9 |
var(deflator=M(-1)/A) P; |
| 10 |
var(deflator=M(-1)) W l d; |
| 11 |
var R n; |
| 12 |
varexo e_a ${e^A}$ e_m ${e^M}$; |
| 13 |
|
| 14 |
parameters alp $\alpha$ bet $\beta$ gam $\gamma$ mst rho $\rho$ psi $\psi$ del $\delta$; |
| 15 |
|
| 16 |
alp = 0.33; |
| 17 |
bet = 0.99; |
| 18 |
gam = 0.003; |
| 19 |
mst = 1.011; |
| 20 |
rho = 0.7; |
| 21 |
psi = 0.787; |
| 22 |
del = 0.02; |
| 23 |
|
| 24 |
model; |
| 25 |
gA = exp(gam+e_a); |
| 26 |
log(gM) = (1-rho)*log(mst) + rho*log(gM(-1))+e_m; |
| 27 |
c+k = k(-1)^alp*(A*n)^(1-alp)+(1-del)*k(-1); |
| 28 |
P*c = M; |
| 29 |
P/(c(+1)*P(+1))=bet*P(+1)*(alp*k^(alp-1)*(A(+1)*n(+1))^(1-alp)+(1-del))/(c(+2)*P(+2)); |
| 30 |
(psi/(1-psi))*(c*P/(1-n))=W; |
| 31 |
R = P*(1-alp)*k(-1)^alp*A^(1-alp)*n^(-alp)/W; |
| 32 |
W = l/n; |
| 33 |
M-M(-1)+d = l; |
| 34 |
1/(c*P)=bet*R/(c(+1)*P(+1)); |
| 35 |
y = k(-1)^alp*(A*n)^(1-alp); |
| 36 |
end; |
| 37 |
|
| 38 |
steady_state_model; |
| 39 |
gA = exp(gam); |
| 40 |
gst = 1/gA; |
| 41 |
gM = mst; |
| 42 |
khst = ( (1-gst*bet*(1-del)) / (alp*gst^alp*bet) )^(1/(alp-1)); |
| 43 |
xist = ( ((khst*gst)^alp - (1-gst*(1-del))*khst)/mst )^(-1); |
| 44 |
nust = psi*mst^2/( (1-alp)*(1-psi)*bet*gst^alp*khst^alp ); |
| 45 |
n = xist/(nust+xist); |
| 46 |
P = xist + nust; |
| 47 |
k = khst*n; |
| 48 |
|
| 49 |
l = psi*mst*n/( (1-psi)*(1-n) ); |
| 50 |
c = mst/P; |
| 51 |
d = l - mst + 1; |
| 52 |
y = k^alp*n^(1-alp)*gst^alp; |
| 53 |
R = mst/bet; |
| 54 |
W = l/n; |
| 55 |
ist = y-c; |
| 56 |
q = 1 - d; |
| 57 |
|
| 58 |
e = 1; |
| 59 |
end; |
| 60 |
|
| 61 |
shocks; |
| 62 |
var e_a; stderr 0.014; |
| 63 |
var e_m; stderr 0.005; |
| 64 |
end; |
| 65 |
|
| 66 |
steady; |
| 67 |
|
| 68 |
check; |
| 69 |
|
| 70 |
write_latex_dynamic_model; |
| 71 |
|
| 72 |
stoch_simul(nograph); |