Debian Codegraph @

tests/differentiate_forward_vars/RBC_differentiate_forward.mod

raw
1 /*
2 * This model shows how to use the differentiate_forward_vars option to simulate
3 * perfect foresight models when the steady state is unknown
4 * or when the model is very persistent. In this file, we consider an RBC model
5 * with a CES technology and very persistent productivity shock. We set the
6 * autoregressive parameter of this exogenous productivity to 0.999, so that
7 * in period 400 the level of productivity, after an initial one percent shock,
8 * is still 0.67\% above its steady state level.
9 *
10 * Written by Stéphane Adjemian. For more information, see
11 * http://gitlab.ithaca.fr/Dynare/differentiate-forward-variables
12 */
13 var Capital, Output, Labour, Consumption, Efficiency, efficiency, ExpectedTerm;
14
15 varexo EfficiencyInnovation;
16
17 parameters beta, theta, tau, alpha, psi, delta, rho, effstar, sigma;
18
19 /*
20 ** Calibration
21 */
22
23 beta = 0.990;
24 theta = 0.357;
25 tau = 30.000;
26 alpha = 0.450;
27 psi = -1.000; // So that the elasticity of substitution between inputs is 1/(1-psi)=1/10
28 delta = 0.020;
29 rho = 0.999;
30 effstar = 1.000;
31 sigma = 0.010;
32
33 model(differentiate_forward_vars);
34
35 // Eq. n°1:
36 efficiency = rho*efficiency(-1) + sigma*EfficiencyInnovation;
37
38 // Eq. n°2:
39 Efficiency = effstar*exp(efficiency);
40
41 // Eq. n°3:
42 Output = Efficiency*(alpha*(Capital(-1)^psi)+(1-alpha)*(Labour^psi))^(1/psi);
43
44 // Eq. n°4:
45 Consumption + Capital - Output - (1-delta)*Capital(-1);
46
47 // Eq. n°5:
48 ((1-theta)/theta)*(Consumption/(1-Labour)) - (1-alpha)*(Output/Labour)^(1-psi);
49
50 // Eq. n°6:
51 (((Consumption^theta)*((1-Labour)^(1-theta)))^(1-tau))/Consumption - ExpectedTerm(1);
52
53 // Eq. n°7:
54 ExpectedTerm = beta*((((Consumption^theta)*((1-Labour)^(1-theta)))^(1-tau))/Consumption)*(alpha*((Output/Capital(-1))^(1-psi))+1-delta);
55
56 end;
57
58 steady_state_model;
59
60 efficiency = 0;
61 Efficiency = effstar;
62
63 // Compute some steady state ratios.
64 Output_per_unit_of_Capital=((1/beta-1+delta)/alpha)^(1/(1-psi));
65 Consumption_per_unit_of_Capital=Output_per_unit_of_Capital-delta;
66 Labour_per_unit_of_Capital=(((Output_per_unit_of_Capital/Efficiency)^psi-alpha)/(1-alpha))^(1/psi);
67 Output_per_unit_of_Labour=Output_per_unit_of_Capital/Labour_per_unit_of_Capital;
68 Consumption_per_unit_of_Labour=Consumption_per_unit_of_Capital/Labour_per_unit_of_Capital;
69
70 // Compute steady state share of capital.
71 ShareOfCapital=alpha/(alpha+(1-alpha)*Labour_per_unit_of_Capital^psi);
72
73 // Compute steady state of the endogenous variables.
74 Labour=1/(1+Consumption_per_unit_of_Labour/((1-alpha)*theta/(1-theta)*Output_per_unit_of_Labour^(1-psi)));
75 Consumption = Consumption_per_unit_of_Labour*Labour;
76 Capital = Labour/Labour_per_unit_of_Capital;
77 Output = Output_per_unit_of_Capital*Capital;
78 ExpectedTerm = beta*((((Consumption^theta)*((1-Labour)^(1-theta)))^(1-tau))/Consumption)*(alpha*((Output/Capital)^(1-psi))+1-delta);
79
80 end;
81
82
83 shocks;
84 var EfficiencyInnovation;
85 periods 1;
86 values 1;
87 end;
88
89 steady;
90 check;
91 model_info;
92
93 perfect_foresight_setup(periods=500);
94 perfect_foresight_solver;