Debian Codegraph @

src/CMakeLists.txt

raw
1 if("${QT_VERSION_MAJOR}" STREQUAL "6")
2 find_package(Qt6 REQUIRED COMPONENTS Core Widgets WaylandClient)
3 else()
4 find_package(Qt5 REQUIRED COMPONENTS WaylandClient XkbCommonSupport)
5 endif()
6
7 add_library(${LIB_NAME} SHARED)
8
9 include(dbus/dbus.cmake)
10 include(filedrag/dfiledrag.cmake)
11 include(kernel/kernel.cmake)
12 include(private/private.cmake)
13 include(util/util.cmake)
14 include(plugins/plugins.cmake)
15
16 target_sources(${LIB_NAME} PRIVATE
17 ${dbus_SRC}
18 ${filedrag_SRC}
19 ${kernel_SRC}
20 ${util_SRC}
21 ${private_SRC}
22 )
23
24 target_include_directories(${LIB_NAME} PUBLIC
25 $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include/util>
26 $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include/global>
27 $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include/kernel>
28 $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include/filedrag>
29 $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/dbus>
30 $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/private>
31 $<BUILD_INTERFACE:${CMAKE_CURRENT_LIST_DIR}/util/private>
32 $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include/DtkGui>
33 )
34
35 target_link_libraries(${LIB_NAME}
36 PUBLIC
37 Qt${QT_VERSION_MAJOR}::Gui
38 Qt${QT_VERSION_MAJOR}::Network
39 Dtk${DTK_VERSION_MAJOR}::Core
40 PRIVATE
41 Qt${QT_VERSION_MAJOR}::GuiPrivate
42 Qt${QT_VERSION_MAJOR}::CorePrivate
43 Qt${QT_VERSION_MAJOR}::DBus
44 Qt${QT_VERSION_MAJOR}::WaylandClientPrivate
45 )
46
47 if("${QT_VERSION_MAJOR}" STREQUAL "5")
48 target_link_libraries(${LIB_NAME}
49 PRIVATE
50 Qt${QT_VERSION_MAJOR}::XkbCommonSupportPrivate
51 )
52 endif()
53
54 if(DTK_DISABLE_LIBRSVG)
55 find_package(Qt${QT_VERSION_MAJOR}Svg REQUIRED)
56 target_link_libraries(${LIB_NAME} PRIVATE Qt${QT_VERSION_MAJOR}::Svg)
57 else()
58 target_link_libraries(${LIB_NAME} PRIVATE PkgConfig::librsvg)
59 endif()
60
61 if(NOT DTK_DISABLE_EX_IMAGE_FORMAT AND EX_IMAGE_FORMAT_LIBS_FOUND)
62 target_link_libraries(${LIB_NAME} PRIVATE
63 ${libraw_LIBRARIES}
64 FreeImage::FreeImage
65 )
66 target_include_directories(${LIB_NAME} PRIVATE
67 ${libraw_INCLUDE_DIRS}
68 )
69 endif()
70
71 if(NOT DTK_DISABLE_LIBXDG)
72 target_link_libraries(${LIB_NAME} PRIVATE
73 Qt${QT_VERSION_MAJOR}XdgIconLoader
74 )
75 endif()
76
77 set_target_properties(${LIB_NAME} PROPERTIES
78 VERSION ${CMAKE_PROJECT_VERSION}
79 SOVERSION ${CMAKE_PROJECT_VERSION_MAJOR}
80 EXPORT_NAME Gui
81 )
82
83 target_include_directories(${LIB_NAME} INTERFACE
84 $<INSTALL_INTERFACE:${INCLUDE_INSTALL_DIR}>
85 )
86
87 target_link_directories(${LIB_NAME} INTERFACE
88 $<INSTALL_INTERFACE:${LIBRARY_INSTALL_DIR}>
89 )
90
91 install(TARGETS ${LIB_NAME} EXPORT Dtk${DTK_VERSION_MAJOR}GuiTargets DESTINATION "${LIBRARY_INSTALL_DIR}")
92 install(EXPORT Dtk${DTK_VERSION_MAJOR}GuiTargets NAMESPACE Dtk${DTK_VERSION_MAJOR}:: FILE Dtk${DTK_VERSION_MAJOR}GuiTargets.cmake DESTINATION "${CONFIG_INSTALL_DIR}")
93 install(DIRECTORY ../include/util/ DESTINATION "${INCLUDE_INSTALL_DIR}" FILES_MATCHING PATTERN "*")
94 install(DIRECTORY ../include/DtkGui/ DESTINATION "${INCLUDE_INSTALL_DIR}" FILES_MATCHING PATTERN "*")
95 install(DIRECTORY ../include/global/ DESTINATION "${INCLUDE_INSTALL_DIR}" FILES_MATCHING PATTERN "*")
96 install(DIRECTORY ../include/kernel/ DESTINATION "${INCLUDE_INSTALL_DIR}" FILES_MATCHING PATTERN "*")
97 install(DIRECTORY ../include/filedrag/ DESTINATION "${INCLUDE_INSTALL_DIR}" FILES_MATCHING PATTERN "*")
98
99 set(EnableCov CACHE BOOL OFF)
100 if (EnableCov)
101 dtk_setup_code_coverage(${LIB_NAME})
102 endif()