Debian Codegraph @

src/djview.pro

raw
1 #C- -*- shell-script -*-
2 #C- -------------------------------------------------------------------
3 #C- DjView4
4 #C- Copyright (c) 2006 Leon Bottou
5 #C-
6 #C- This software is subject to, and may be distributed under, the
7 #C- GNU General Public License. The license should have
8 #C- accompanied the software or you may obtain a copy of the license
9 #C- from the Free Software Foundation at http:#www.fsf.org .
10 #C-
11 #C- This program is distributed in the hope that it will be useful,
12 #C- but WITHOUT ANY WARRANTY; without even the implied warranty of
13 #C- MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14 #C- GNU General Public License for more details.
15 #C- ------------------------------------------------------------------
16
17
18 TEMPLATE = app
19 TARGET = djview
20 CONFIG += qt thread warn_on
21 QT += network opengl
22
23 # -- QT5 modules
24 greaterThan(QT_MAJOR_VERSION, 4) {
25 QT += widgets printsupport
26 }
27
28 # -- QT6 modules
29 greaterThan(QT_MAJOR_VERSION, 5) {
30 QT += core5compat
31 }
32
33 # -- find libraries
34 CONFIG(autoconf) {
35 # for use with autoconf
36 DEFINES += AUTOCONF
37 # Autoconf calls qmake with the following variables
38 # LIBS += ...
39 # QMAKE_CXXFLAGS += ...
40 # QMAKE_CFLAGS += ...
41 # QMAKE_LFLAGS += ...
42 } else {
43 # customize below
44 #INCLUDEPATH += /usr/include
45 #LIBS += -L/usr/local/lib -ldjvulibre -ljpeg
46 #QMAKE_CXXFLAGS +=
47 #QMAKE_CFLAGS +=
48 #QMAKE_LFLAGS +=
49 #DEFINES +=
50 }
51
52
53 # -- no debug in release mode
54 CONFIG(release,debug|release) {
55 DEFINES += NDEBUG QT_NO_DEBUG QT_NO_DEBUG_STREAM
56 }
57
58 # -- mac stuff
59 macx {
60 ICON = images/DjVuApp.icns
61 VERSION = $$PACKAGE_VERSION
62 RESOURCES.path = Contents/Resources
63 RESOURCES.files = images/DjVu.icns
64 QMAKE_BUNDLE_DATA += RESOURCES
65 QMAKE_INFO_PLIST = djview.plist
66 # QMAKE_APPLE_DEVICE_ARCHS="x86_64 arm64"
67 }
68
69 # --- windows stuff
70 win32 {
71 RC_FILE = djview.rc
72 }
73
74 # --- djviewplugin logic
75 greaterThan(QT_MAJOR_VERSION, 4) {
76 DEFINES *= WITH_DJVIEWPLUGIN
77 } else:macx:contains(DEFINES,__USE_WS_X11__) {
78 DEFINES *= WITH_DJVIEWPLUGIN
79 } else:win32:contains(DEFINES,_WIN32_X11_) {
80 DEFINES *= WITH_DJVIEWPLUGIN
81 } else:!macx:!win32 {
82 DEFINES *= WITH_DJVIEWPLUGIN
83 }
84 contains(DEFINES,WITH_DJVIEWPLUGIN) {
85 greaterThan(QT_MAJOR_VERSION, 4) {
86 } else {
87 DEFINES *= WITH_X11
88 CONFIG += x11
89 }
90 }
91
92
93 # -- djvu files
94 HEADERS += qdjvu.h
95 HEADERS += qdjvunet.h
96 HEADERS += qdjvuwidget.h
97 SOURCES += qdjvu.cpp
98 SOURCES += qdjvunet.cpp
99 SOURCES += qdjvuwidget.cpp
100 RESOURCES += qdjvuwidget.qrc
101
102 # -- djview files
103 HEADERS += qdjviewprefs.h
104 HEADERS += qdjviewsidebar.h
105 HEADERS += qdjviewdialogs.h
106 HEADERS += qdjviewexporters.h
107 HEADERS += qdjview.h
108 HEADERS += djview.h
109 HEADERS += version.h
110 SOURCES += qdjviewprefs.cpp
111 SOURCES += qdjviewsidebar.cpp
112 SOURCES += qdjviewdialogs.cpp
113 SOURCES += qdjviewexporters.cpp
114 SOURCES += qdjview.cpp
115 SOURCES += djview.cpp
116 RESOURCES += qdjview.qrc
117 FORMS += qdjviewerrordialog.ui
118 FORMS += qdjviewauthdialog.ui
119 FORMS += qdjviewinfodialog.ui
120 FORMS += qdjviewmetadialog.ui
121 FORMS += qdjviewsavedialog.ui
122 FORMS += qdjviewprintdialog.ui
123 FORMS += qdjviewexportdialog.ui
124 FORMS += qdjviewexportps1.ui
125 FORMS += qdjviewexportps2.ui
126 FORMS += qdjviewexportps3.ui
127 FORMS += qdjviewexporttiff.ui
128 FORMS += qdjviewexportprn.ui
129 FORMS += qdjviewprefsdialog.ui
130 contains(DEFINES,WITH_DJVIEWPLUGIN) {
131 HEADERS += qdjviewplugin.h
132 SOURCES += qdjviewplugin.cpp
133 }
134
135 # -- helper files
136 HEADERS += tiff2pdf.h
137 SOURCES += tiff2pdf.c
138
139 # -- transations
140 TRANSLATIONS += djview_fr.ts
141 TRANSLATIONS += djview_uk.ts
142 TRANSLATIONS += djview_de.ts
143 TRANSLATIONS += djview_cs.ts
144 TRANSLATIONS += djview_ru.ts
145 TRANSLATIONS += djview_es.ts
146 TRANSLATIONS += djview_zh_cn.ts
147 TRANSLATIONS += djview_zh_tw.ts
148 TRANSLATIONS += djview_pl.ts