Debian Codegraph @

qlite/src/upsert_builder.vala

raw
1 using Sqlite;
2
3 namespace Qlite {
4
5 public class UpsertBuilder : StatementBuilder {
6 // INTO [...]
7 private Table table;
8 private string table_name;
9
10 // VALUES [...]
11 private StatementBuilder.AbstractField[] keys = {};
12 private StatementBuilder.AbstractField[] fields = {};
13
14 internal UpsertBuilder(Database db, Table table) {
15 base(db);
16 this.table = table;
17 this.table_name = table.name;
18 }
19
20 public UpsertBuilder value<T>(Column<T> column, T value, bool key = false) {
21 if (key) {
22 keys += new Field<T>(column, value);
23 } else {
24 fields += new Field<T>(column, value);
25 }
26 return this;
27 }
28
29 public UpsertBuilder value_null<T>(Column<T> column, bool key = false) {
30 if (column.not_null) error("Can't set non-null column %s to null", column.name);
31 if (key) {
32 keys += new NullField<T>(column);
33 } else {
34 fields += new NullField<T>(column);
35 }
36 return this;
37 }
38
39 internal override Statement prepare() {
40 error("prepare() not available for upsert.");
41 }
42
43 internal Statement prepare_upsert() {
44 var unique_fields = new StringBuilder();
45 var unique_values = new StringBuilder();
46 var update_fields = new StringBuilder();
47 var update_values = new StringBuilder();
48 var update_fields_vals = new StringBuilder();
49
50 for (int i = 0; i < keys.length; i++) {
51 if (i != 0) {
52 unique_fields.append(", ");
53 unique_values.append(", ");
54 }
55 unique_fields.append(keys[i].column.name);
56 unique_values.append("?");
57 }
58
59 for (int i = 0; i < fields.length; i++) {
60 if (i != 0) {
61 update_fields.append(", ");
62 update_values.append(", ");
63 update_fields_vals.append(", ");
64 }
65 update_fields.append(fields[i].column.name);
66 update_values.append("?");
67 update_fields_vals.append(fields[i].column.name).append("=excluded.").append(fields[i].column.name);
68 }
69
70 string sql = @"INSERT INTO $table_name ($(unique_fields.str), $(update_fields.str)) VALUES ($(unique_values.str), $(update_values.str)) " +
71 @"ON CONFLICT ($(unique_fields.str)) DO UPDATE SET $(update_fields_vals.str)";
72
73 Statement stmt = db.prepare(sql);
74 for (int i = 0; i < keys.length; i++) {
75 keys[i].bind(stmt, i + 1);
76 }
77 for (int i = 0; i < fields.length; i++) {
78 fields[i].bind(stmt, i + keys.length + 1);
79 }
80
81 return stmt;
82 }
83
84 public int64 perform() {
85 if (prepare_upsert().step() != DONE) {
86 critical(@"SQLite error: %d - %s", db.errcode(), db.errmsg());
87 }
88 return db.last_insert_rowid();
89 }
90
91 }
92
93 }