Debian Codegraph @

project/bundles/vcpkg/installer/digikam.nsi

raw
1 ;; ============================================================
2 ;
3 ; This file is a part of digiKam project
4 ; https://www.digikam.org
5 ;
6 ; Date : 2010-11-08
7 ; Description : Null Soft Windows Installer based for digiKam.
8 ; Note: NSIS >= 3 is required to be compatible with Windows 10.
9 ;
10 ; SPDX-FileCopyrightText: 2010 by Julien Narboux <julien at narboux dot fr>
11 ; SPDX-FileCopyrightText: 2011-2014 by Ananta Palani <anantapalani at gmail dot com>
12 ; SPDX-FileCopyrightText: 2010-2026 by Gilles Caulier <caulier dot gilles at gmail dot com>
13 ;
14 ; Script arguments:
15 ; VERSION : the digiKam version [string].
16 ; BUNDLEPATH : the path where whole digiKam bundle is installed [string].
17 ; DEBUG_SYMB : the bundle includes binary debug symbols (.pdb) [boolean].
18 ; OUTPUT : the output installer file name [string].
19 ;
20 ; Example: makensis -DVERSION=8.5.0 -DBUNDLEPATH=../bundle -DDEBUG_SYMB digikam.nsi
21 ;
22 ; NSIS script reference can be found at this url:
23 ; https://nsis.sourceforge.net/Docs/Chapter4.html
24 ;
25 ; SPDX-License-Identifier: GPL-2.0-or-later
26 ;
27 ; ============================================================ ;;
28
29 ;-------------------------------------------------------------------------------
30 ;Verbose level (no script)
31
32 !verbose 4
33
34 ;-------------------------------------------------------------------------------
35 ; Compression rules optimizations
36 ; We will use LZMA compression as 7Zip, with a dictionary size of 96Mb (to reproduce 7Zip Ultra compression mode)
37
38 SetCompress force
39 SetCompressor lzma
40 SetDatablockOptimize on
41 SetCompressorDictSize 96
42
43 ;-------------------------------------------------------------------------------
44 ;Include Modern UI
45
46 ; Turn on UTF-8 strings encoding support.
47 Unicode true
48
49 ; Add support to hdpi screen. This require NSIS >= 3.x
50 ManifestDPIAware true
51
52 !include "MUI2.nsh"
53 !define MY_PRODUCT "digiKam"
54 !define PRODUCT_HOMEPAGE "https://www.digikam.org"
55 !define SUPPORT_HOMEPAGE "https://www.digikam.org/support"
56 !define ABOUT_HOMEPAGE "https://www.digikam.org/about"
57 !define OUTFILE "${OUTPUT}"
58
59 ;-------------------------------------------------------------------------------
60 ;General Setup
61
62 ;Name and file
63
64 Name "${MY_PRODUCT} ${VERSION}"
65 Icon "digikam-installer.ico"
66 BrandingText "digiKam Project (https://www.digikam.org)"
67 UninstallIcon "digikam-uninstaller.ico"
68 OutFile "${OUTFILE}"
69
70 ; Add Installer Windows file properties
71
72 VIProductVersion ${VERSION}.0
73 VIAddVersionKey /LANG=0 "ProductName" "${MY_PRODUCT}"
74 VIAddVersionKey /LANG=0 "ProductVersion" "${VERSION}"
75 VIAddVersionKey /LANG=0 "Comments" "Professional Photo Management with the Power of Open Source"
76 VIAddVersionKey /LANG=0 "CompanyName" "digiKam.org"
77 VIAddVersionKey /LANG=0 "InternalName" "${MY_PRODUCT}"
78 VIAddVersionKey /LANG=0 "LegalTrademarks" "https://www.digikam.org"
79 VIAddVersionKey /LANG=0 "LegalCopyright" "digiKam developers team"
80 VIAddVersionKey /LANG=0 "FileDescription" "digiKam Application Installer for Windows"
81 VIAddVersionKey /LANG=0 "FileVersion" "${VERSION}"
82 VIAddVersionKey /LANG=0 "PrivateBuild" "VCPKG Toolchain"
83 VIAddVersionKey /LANG=0 "SpecialBuild" "MSVC Compiler"
84
85 ;Request application privileges for Windows Vista and upper versions
86
87 RequestExecutionLevel admin
88
89 !include x64.nsh
90
91 ;Get installation folder from registry if available
92
93 InstallDirRegKey HKLM "Software\${MY_PRODUCT}" ""
94
95 !include "LogicLib.nsh"
96 !include "StrFunc.nsh"
97 ${StrRep}
98 ${StrStr}
99 ${StrStrAdv}
100
101 ;Extra local scripts
102
103 !include "process_running.nsh"
104 !include "reboot_required.nsh"
105 !include "readme_page.nsh"
106 !include "events_functions.nsh"
107 !include "snorenotify.nsh"
108
109 ;-------------------------------------------------------------------------------
110 ;Interface Configuration
111
112 !define MUI_HEADERIMAGE
113 !define MUI_HEADERIMAGE_BITMAP "digikam_header.bmp"
114 !define MUI_WELCOMEFINISHPAGE_BITMAP "digikam_welcome.bmp"
115 !define MUI_UNWELCOMEFINISHPAGE_BITMAP "digikam_welcome.bmp"
116 !define MUI_ABORTWARNING
117 !define MUI_ICON "digikam-installer.ico"
118 !define MUI_UNICON "digikam-uninstaller.ico"
119 !define MUI_FINISHPAGE_SHOWREADME_NOTCHECKED
120 !define MUI_FINISHPAGE_SHOWREADME "$instdir\releasenotes.html"
121 !define MUI_FINISHPAGE_RUN
122 !define MUI_FINISHPAGE_RUN_NOTCHECKED
123 !define MUI_FINISHPAGE_RUN_TEXT "Start digiKam"
124 !define MUI_FINISHPAGE_RUN_FUNCTION functionFinishRun
125 !define MUI_FINISHPAGE_LINK "Visit digiKam project website"
126 !define MUI_FINISHPAGE_LINK_LOCATION "https://www.digikam.org"
127
128 ;-------------------------------------------------------------------------------
129 ;SnoreToast Configuration
130
131 !define SnoreToastExe "$INSTDIR\SnoreToast.exe"
132
133 ;-------------------------------------------------------------------------------
134 ;Page Definitions
135
136 ;Variable for the folder of the start menu
137
138 Var StartMenuFolder
139
140 !insertmacro MUI_PAGE_WELCOME
141 !insertmacro MUI_PAGE_README "ABOUT.txt"
142 !insertmacro MUI_PAGE_LICENSE "GPL.txt"
143 !define MUI_PAGE_CUSTOMFUNCTION_LEAVE DirectoryLeave
144 !insertmacro MUI_PAGE_DIRECTORY
145
146 ;Start Menu Folder Page Configuration
147
148 !define MUI_STARTMENUPAGE_REGISTRY_ROOT "HKLM"
149 !define MUI_STARTMENUPAGE_REGISTRY_KEY "Software\${MY_PRODUCT}"
150 !define MUI_STARTMENUPAGE_REGISTRY_VALUENAME "Start Menu Folder"
151 !insertmacro MUI_PAGE_STARTMENU Application $StartMenuFolder
152
153 !insertmacro MUI_PAGE_INSTFILES
154 !insertmacro MUI_PAGE_FINISH
155 !insertmacro MUI_UNPAGE_WELCOME
156 !insertmacro MUI_UNPAGE_CONFIRM
157 !insertmacro MUI_UNPAGE_INSTFILES
158
159 ;-------------------------------------------------------------------------------
160 ;Languages List
161
162 !insertmacro MUI_LANGUAGE "English"
163 !insertmacro MUI_LANGUAGE "French"
164 !insertmacro MUI_LANGUAGE "German"
165 !insertmacro MUI_LANGUAGE "Spanish"
166 !insertmacro MUI_LANGUAGE "SpanishInternational"
167 !insertmacro MUI_LANGUAGE "SimpChinese"
168 !insertmacro MUI_LANGUAGE "TradChinese"
169 !insertmacro MUI_LANGUAGE "Japanese"
170 !insertmacro MUI_LANGUAGE "Korean"
171 !insertmacro MUI_LANGUAGE "Italian"
172 !insertmacro MUI_LANGUAGE "Dutch"
173 !insertmacro MUI_LANGUAGE "Danish"
174 !insertmacro MUI_LANGUAGE "Swedish"
175 !insertmacro MUI_LANGUAGE "Norwegian"
176 !insertmacro MUI_LANGUAGE "NorwegianNynorsk"
177 !insertmacro MUI_LANGUAGE "Finnish"
178 !insertmacro MUI_LANGUAGE "Greek"
179 !insertmacro MUI_LANGUAGE "Russian"
180 !insertmacro MUI_LANGUAGE "Portuguese"
181 !insertmacro MUI_LANGUAGE "PortugueseBR"
182 !insertmacro MUI_LANGUAGE "Polish"
183 !insertmacro MUI_LANGUAGE "Ukrainian"
184 !insertmacro MUI_LANGUAGE "Czech"
185 !insertmacro MUI_LANGUAGE "Slovak"
186 !insertmacro MUI_LANGUAGE "Croatian"
187 !insertmacro MUI_LANGUAGE "Bulgarian"
188 !insertmacro MUI_LANGUAGE "Hungarian"
189 !insertmacro MUI_LANGUAGE "Thai"
190 !insertmacro MUI_LANGUAGE "Romanian"
191 !insertmacro MUI_LANGUAGE "Latvian"
192 !insertmacro MUI_LANGUAGE "Macedonian"
193 !insertmacro MUI_LANGUAGE "Estonian"
194 !insertmacro MUI_LANGUAGE "Turkish"
195 !insertmacro MUI_LANGUAGE "Lithuanian"
196 !insertmacro MUI_LANGUAGE "Slovenian"
197 !insertmacro MUI_LANGUAGE "Serbian"
198 !insertmacro MUI_LANGUAGE "SerbianLatin"
199 !insertmacro MUI_LANGUAGE "Arabic"
200 !insertmacro MUI_LANGUAGE "Farsi"
201 !insertmacro MUI_LANGUAGE "Hebrew"
202 !insertmacro MUI_LANGUAGE "Indonesian"
203 !insertmacro MUI_LANGUAGE "Mongolian"
204 !insertmacro MUI_LANGUAGE "Luxembourgish"
205 !insertmacro MUI_LANGUAGE "Albanian"
206 !insertmacro MUI_LANGUAGE "Breton"
207 !insertmacro MUI_LANGUAGE "Belarusian"
208 !insertmacro MUI_LANGUAGE "Icelandic"
209 !insertmacro MUI_LANGUAGE "Malay"
210 !insertmacro MUI_LANGUAGE "Bosnian"
211 !insertmacro MUI_LANGUAGE "Kurdish"
212 !insertmacro MUI_LANGUAGE "Irish"
213 !insertmacro MUI_LANGUAGE "Uzbek"
214 !insertmacro MUI_LANGUAGE "Galician"
215 !insertmacro MUI_LANGUAGE "Afrikaans"
216 !insertmacro MUI_LANGUAGE "Catalan"
217 !insertmacro MUI_LANGUAGE "Esperanto"
218
219 ;-------------------------------------------------------------------------------
220 ;Installer Sections
221
222 Section "digiKam" SecDigiKam
223
224 ;Check running processes prior to install
225
226 Call CheckDigikamRunning
227 Call CheckShowfotoRunning
228
229 ;See bug #437813: be sure that all background sub-process are done
230
231 nsExec::ExecToLog /TIMEOUT=2000 'taskkill.exe /F /T /IM exiftool.exe'
232 nsExec::ExecToLog /TIMEOUT=2000 'taskkill.exe /F /T /IM QtWebEngineProcess.exe'
233
234 SetOutPath "$INSTDIR"
235
236 File "..\data\releasenotes.html"
237 File "digikam-uninstaller.ico"
238
239 ;Copy only required directories
240 ;The SetOutPath is required because otherwise NSIS will assume all files are
241 ;in the same folder even though they are sourced from different folders
242 ;The \*.* is required for File /r because without it, NSIS would add every
243 ;folder with the name 'bin' in all subdirectories of ${BUNDLEPATH}
244
245 SetOutPath "$INSTDIR\"
246 File "${BUNDLEPATH}\*.exe"
247 File "${BUNDLEPATH}\*.conf"
248 File "${BUNDLEPATH}\*.rcc"
249 File "${BUNDLEPATH}\*.dll"
250 File "${BUNDLEPATH}\*.txt"
251
252 !ifdef DEBUG_SYMB
253 File "${BUNDLEPATH}\*.pdb"
254 !endif
255
256 SetOutPath "$INSTDIR\data"
257 File /r "${BUNDLEPATH}\data\*.*"
258
259 SetOutPath "$INSTDIR\share"
260 File /r "${BUNDLEPATH}\share\*.*"
261
262 SetOutPath "$INSTDIR\plugins"
263 File /r "${BUNDLEPATH}\plugins\*.*"
264
265 SetOutPath "$INSTDIR\resources"
266 File /r "${BUNDLEPATH}\resources\*.*"
267
268 SetOutPath "$INSTDIR\translations"
269 File /r "${BUNDLEPATH}\translations\*.*"
270
271 SetOutPath "$INSTDIR\exiftool_files"
272 File /r "${BUNDLEPATH}\exiftool_files\*.*"
273
274 ;Store installation folder
275
276 WriteRegStr HKLM "Software\${MY_PRODUCT}" "" $INSTDIR
277
278 ;Create uninstaller
279
280 WriteUninstaller "$INSTDIR\Uninstall.exe"
281
282 ;Register uninstaller in windows registry with only the option to uninstall (no repair nor modify)
283
284 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "Comments" "${MY_PRODUCT} ${VERSION}"
285 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "DisplayIcon" '"$INSTDIR\digikam.exe"'
286 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "DisplayName" "${MY_PRODUCT} ${VERSION}"
287 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "DisplayVersion" "${VERSION}"
288 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "HelpLink" "${SUPPORT_HOMEPAGE}"
289 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "InstallLocation" "$INSTDIR"
290 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "Publisher" "The digiKam team"
291 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "Readme" '"$INSTDIR\releasenotes.html"'
292 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "UninstallString" '"$INSTDIR\Uninstall.exe"'
293 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "URLInfoAbout" "${ABOUT_HOMEPAGE}"
294 WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "URLUpdateInfo" "${PRODUCT_HOMEPAGE}"
295
296 ;Calculate the install size so that it can be shown in the uninstall interface in Windows
297 ;see http://nsis.sourceforge.net/Add_uninstall_information_to_Add/Remove_Programs
298 ;this isn't the most accurate method but it is very fast and is accurate enough for an estimate
299
300 push $0
301 SectionGetSize ${SecDigiKam} $0
302 WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "EstimatedSize" "$0"
303 pop $0
304
305 WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "NoModify" "1"
306 WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}" "NoRepair" "1"
307
308 ;Add start menu items to All Users
309
310 SetShellVarContext all
311 !insertmacro MUI_STARTMENU_WRITE_BEGIN Application
312
313 ;Create shortcuts
314
315 SetOutPath "$INSTDIR"
316 ;CreateDirectory "$SMPROGRAMS\$StartMenuFolder"
317 ;CreateShortCut "$SMPROGRAMS\$StartMenuFolder\${MY_PRODUCT}.lnk" "$INSTDIR\digikam.exe"
318 ;CreateShortCut "$SMPROGRAMS\$StartMenuFolder\Showfoto.lnk" "$INSTDIR\showfoto.exe"
319
320 !insertmacro SnoreShortcut "$SMPROGRAMS\$StartMenuFolder\${MY_PRODUCT}.lnk" "$INSTDIR\digikam.exe" "digikam"
321 !insertmacro SnoreShortcut "$SMPROGRAMS\$StartMenuFolder\Showfoto.lnk" "$INSTDIR\showfoto.exe" "showfoto"
322
323 WriteINIStr "$SMPROGRAMS\$StartMenuFolder\The ${MY_PRODUCT} HomePage.url" "InternetShortcut" "URL" "${PRODUCT_HOMEPAGE}"
324 WriteINIStr "$SMPROGRAMS\$StartMenuFolder\The ${MY_PRODUCT} HomePage.url" "InternetShortcut" "IconIndex" "12"
325 WriteINIStr "$SMPROGRAMS\$StartMenuFolder\The ${MY_PRODUCT} HomePage.url" "InternetShortcut" "IconFile" "$windir\explorer.exe"
326
327 !insertmacro MUI_STARTMENU_WRITE_END
328
329 SectionEnd
330
331 ;-------------------------------------------------------------------------------
332 ;Uninstaller Section
333
334 Section "Uninstall"
335
336 ;Check running processes prior to uninstall
337
338 Call un.CheckDigikamRunning
339 Call un.CheckShowfotoRunning
340
341 ;See bug #437813: be sure that all background sub-process are done
342
343 nsExec::ExecToLog /TIMEOUT=2000 'taskkill.exe /F /T /IM exiftool.exe'
344 nsExec::ExecToLog /TIMEOUT=2000 'taskkill.exe /F /T /IM QtWebEngineProcess.exe'
345
346 Delete "$INSTDIR\*.exe"
347 Delete "$INSTDIR\*.conf"
348 Delete "$INSTDIR\*.rcc"
349 Delete "$INSTDIR\*.dll"
350 Delete "$INSTDIR\*.txt"
351
352 !ifdef DEBUG_SYMB
353 Delete "$INSTDIR\*.pdb"
354 !endif
355
356 Delete "$INSTDIR\Uninstall.exe"
357 Delete "$INSTDIR\releasenotes.html"
358 Delete "$INSTDIR\digikam-uninstaller.ico"
359
360 RMDir /r "$INSTDIR\data"
361 RMDir /r "$INSTDIR\share"
362 RMDir /r "$INSTDIR\plugins"
363 RMDir /r "$INSTDIR\resources"
364 RMDir /r "$INSTDIR\translations"
365 RMDir /r "$INSTDIR\exiftool_files"
366
367 ;MXE Legacy
368 Delete "$INSTDIR\*.yes"
369 RMDir /r "$INSTDIR\etc"
370 RMDir /r "$INSTDIR\bin"
371 RMDir /r "$INSTDIR\libgphoto2"
372 RMDir /r "$INSTDIR\libgphoto2_port"
373
374 ;Do not do a recursive removal of $INSTDIR because user may have accidentally installed into system critical directory!
375
376 RMDir "$INSTDIR"
377
378 ;Remove start menu items
379
380 SetShellVarContext all
381 !insertmacro MUI_STARTMENU_GETFOLDER Application $StartMenuFolder
382
383 Delete "$SMPROGRAMS\$StartMenuFolder\Uninstall.lnk"
384 Delete "$SMPROGRAMS\$StartMenuFolder\${MY_PRODUCT}.lnk"
385 Delete "$SMPROGRAMS\$StartMenuFolder\Showfoto.lnk"
386 Delete "$SMPROGRAMS\$StartMenuFolder\The ${MY_PRODUCT} HomePage.url"
387
388 RMDir "$SMPROGRAMS\$StartMenuFolder"
389
390 ;Remove registry entries
391
392 DeleteRegValue HKLM "Software\${MY_PRODUCT}" ""
393 DeleteRegValue HKLM "Software\${MY_PRODUCT}" "Start Menu Folder"
394 DeleteRegKey /ifempty HKLM "Software\${MY_PRODUCT}"
395 DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${MY_PRODUCT}"
396
397 SectionEnd