Debian Codegraph @

xsl/mathml2/scripts.xsl

raw
1 <?xml version='1.0' encoding="UTF-8"?>
2 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3 xmlns:m="http://www.w3.org/1998/Math/MathML"
4 version='1.0'>
5
6 <!-- ====================================================================== -->
7 <!-- $Id
8 This file is part of the XSLT MathML Library distribution.
9 See ./README or http://www.raleigh.ru/MathML/mmltex for
10 copyright and other information -->
11 <!-- ====================================================================== -->
12
13 <xsl:template match="m:munderover">
14 <xsl:variable name="base" select="translate(./*[1],' ','')"/>
15 <xsl:variable name="under" select="translate(./*[2],' ','')"/>
16 <xsl:variable name="over" select="translate(./*[3],' ','')"/>
17 <xsl:choose>
18 <xsl:when test="$over='&#x000AF;'"> <!-- OverBar - over bar -->
19 <xsl:text>\overline{</xsl:text>
20 <xsl:call-template name="munder">
21 <xsl:with-param name="base" select="$base"/>
22 <xsl:with-param name="under" select="$under"/>
23 </xsl:call-template>
24 <xsl:text>}</xsl:text>
25 </xsl:when>
26 <xsl:when test="$over='&#x0FE37;'"> <!-- OverBrace - over brace -->
27 <xsl:text>\overbrace{</xsl:text>
28 <xsl:call-template name="munder">
29 <xsl:with-param name="base" select="$base"/>
30 <xsl:with-param name="under" select="$under"/>
31 </xsl:call-template>
32 <xsl:text>}</xsl:text>
33 </xsl:when>
34 <xsl:when test="$over='&#x02190;'"> <!--/leftarrow /gets A: =leftward arrow -->
35 <xsl:text>\overleftarrow{</xsl:text>
36 <xsl:call-template name="munder">
37 <xsl:with-param name="base" select="$base"/>
38 <xsl:with-param name="under" select="$under"/>
39 </xsl:call-template>
40 <xsl:text>}</xsl:text>
41 </xsl:when>
42 <xsl:when test="$over='&#x02192;'"> <!--/rightarrow /to A: =rightward arrow -->
43 <xsl:text>\overrightarrow{</xsl:text>
44 <xsl:call-template name="munder">
45 <xsl:with-param name="base" select="$base"/>
46 <xsl:with-param name="under" select="$under"/>
47 </xsl:call-template>
48 <xsl:text>}</xsl:text>
49 </xsl:when>
50 <xsl:when test="$over='&#x02194;'"> <!--/leftrightarrow A: l&r arrow -->
51 <xsl:text>\overleftrightarrow{</xsl:text>
52 <xsl:call-template name="munder">
53 <xsl:with-param name="base" select="$base"/>
54 <xsl:with-param name="under" select="$under"/>
55 </xsl:call-template>
56 <xsl:text>}</xsl:text>
57 </xsl:when>
58 <xsl:when test="$under='&#x00332;'"> <!-- UnderBar - combining low line -->
59 <xsl:text>\underline{</xsl:text>
60 <xsl:call-template name="mover">
61 <xsl:with-param name="base" select="$base"/>
62 <xsl:with-param name="over" select="$over"/>
63 <xsl:with-param name="pos_over" select="3"/>
64 </xsl:call-template>
65 <xsl:text>}</xsl:text>
66 </xsl:when>
67 <xsl:when test="$under='&#x0FE38;'"> <!-- UnderBrace - under brace -->
68 <xsl:text>\underbrace{</xsl:text>
69 <xsl:call-template name="mover">
70 <xsl:with-param name="base" select="$base"/>
71 <xsl:with-param name="over" select="$over"/>
72 <xsl:with-param name="pos_over" select="3"/>
73 </xsl:call-template>
74 <xsl:text>}</xsl:text>
75 </xsl:when>
76 <xsl:when test="$under='&#x02190;'"> <!--/leftarrow /gets A: =leftward arrow -->
77 <xsl:text>\underleftarrow{</xsl:text>
78 <xsl:call-template name="mover">
79 <xsl:with-param name="base" select="$base"/>
80 <xsl:with-param name="over" select="$over"/>
81 <xsl:with-param name="pos_over" select="3"/>
82 </xsl:call-template>
83 <xsl:text>}</xsl:text>
84 </xsl:when>
85 <xsl:when test="$under='&#x02192;'"> <!--/rightarrow /to A: =rightward arrow -->
86 <xsl:text>\underrightarrow{</xsl:text>
87 <xsl:call-template name="mover">
88 <xsl:with-param name="base" select="$base"/>
89 <xsl:with-param name="over" select="$over"/>
90 <xsl:with-param name="pos_over" select="3"/>
91 </xsl:call-template>
92 <xsl:text>}</xsl:text>
93 </xsl:when>
94 <xsl:when test="$under='&#x02194;'"> <!--/leftrightarrow A: l&r arrow -->
95 <xsl:text>\underleftrightarrow{</xsl:text>
96 <xsl:call-template name="mover">
97 <xsl:with-param name="base" select="$base"/>
98 <xsl:with-param name="over" select="$over"/>
99 <xsl:with-param name="pos_over" select="3"/>
100 </xsl:call-template>
101 <xsl:text>}</xsl:text>
102 </xsl:when>
103 <xsl:when test="translate($base,'&#x0220F;&#x02210;&#x022c2;&#x022c3;&#x02294;',
104 '&#x02211;&#x02211;&#x02211;&#x02211;&#x02211;')='&#x02211;'">
105 <!-- if $base is operator, such as
106 &#x02211; /sum L: summation operator
107 &#x0220F; /prod L: product operator
108 &#x02210; /coprod L: coproduct operator
109 &#x022c2; /bigcap
110 &#x022c3; /bigcup
111 &#x02294; /bigsqcup
112 -->
113 <xsl:apply-templates select="./*[1]"/>
114 <xsl:text>_{</xsl:text>
115 <xsl:apply-templates select="./*[2]"/>
116 <xsl:text>}^{</xsl:text>
117 <xsl:apply-templates select="./*[3]"/>
118 <xsl:text>}</xsl:text>
119 </xsl:when>
120 <xsl:otherwise>
121 <xsl:text>\underset{</xsl:text>
122 <xsl:apply-templates select="./*[2]"/>
123 <xsl:text>}{\overset{</xsl:text>
124 <xsl:apply-templates select="./*[3]"/>
125 <xsl:text>}{</xsl:text>
126 <xsl:apply-templates select="./*[1]"/>
127 <xsl:text>}}</xsl:text>
128 </xsl:otherwise>
129 </xsl:choose>
130 </xsl:template>
131
132 <xsl:template match="m:mover">
133 <xsl:call-template name="mover">
134 <xsl:with-param name="base" select="translate(./*[1],' ','')"/>
135 <xsl:with-param name="over" select="translate(./*[2],' ','')"/>
136 </xsl:call-template>
137 </xsl:template>
138
139 <xsl:template match="m:munder">
140 <xsl:call-template name="munder">
141 <xsl:with-param name="base" select="translate(./*[1],' ','')"/>
142 <xsl:with-param name="under" select="translate(./*[2],' ','')"/>
143 </xsl:call-template>
144 </xsl:template>
145
146 <xsl:template name="mover">
147 <xsl:param name="base"/>
148 <xsl:param name="over"/>
149 <xsl:param name="pos_over" select="2"/>
150 <xsl:choose>
151 <xsl:when test="$over='&#x000AF;'"> <!-- OverBar - over bar -->
152 <xsl:text>\overline{</xsl:text>
153 <xsl:apply-templates select="./*[1]"/>
154 <xsl:text>}</xsl:text>
155 </xsl:when>
156 <xsl:when test="$over='&#x0FE37;'"> <!-- OverBrace - over brace -->
157 <xsl:text>\overbrace{</xsl:text>
158 <xsl:apply-templates select="./*[1]"/>
159 <xsl:text>}</xsl:text>
160 </xsl:when>
161 <xsl:when test="$over='&#x02190;'"> <!--/leftarrow /gets A: =leftward arrow -->
162 <xsl:text>\overleftarrow{</xsl:text>
163 <xsl:apply-templates select="./*[1]"/>
164 <xsl:text>}</xsl:text>
165 </xsl:when>
166 <xsl:when test="$over='&#x02192;'"> <!--/rightarrow /to A: =rightward arrow -->
167 <xsl:text>\overrightarrow{</xsl:text>
168 <xsl:apply-templates select="./*[1]"/>
169 <xsl:text>}</xsl:text>
170 </xsl:when>
171 <xsl:when test="$over='&#x02194;'"> <!--/leftrightarrow A: l&r arrow -->
172 <xsl:text>\overleftrightarrow{</xsl:text>
173 <xsl:apply-templates select="./*[1]"/>
174 <xsl:text>}</xsl:text>
175 </xsl:when>
176 <xsl:when test="$over='&#x002DC;'"> <!-- small tilde -->
177 <xsl:text>\tilde{</xsl:text>
178 <xsl:apply-templates select="./*[1]"/>
179 <xsl:text>}</xsl:text>
180 </xsl:when>
181 <xsl:when test="$over='&#x02713;'"> <!-- /checkmark =tick, check mark -->
182 <xsl:text>\check{</xsl:text>
183 <xsl:apply-templates select="./*[1]"/>
184 <xsl:text>}</xsl:text>
185 </xsl:when>
186 <xsl:when test="$over='&#x002D9;'"> <!-- dot above -->
187 <xsl:text>\dot{</xsl:text>
188 <xsl:apply-templates select="./*[1]"/>
189 <xsl:text>}</xsl:text>
190 </xsl:when>
191 <xsl:when test="$over='&#x000A8;'"> <!-- DoubleDot - dieresis or umlaut mark -->
192 <xsl:text>\ddot{</xsl:text>
193 <xsl:apply-templates select="./*[1]"/>
194 <xsl:text>}</xsl:text>
195 </xsl:when>
196 <xsl:when test="$over='&#x00302;' or $over='&#x0005E;'"> <!-- Hat or circ - circumflex accent -->
197 <xsl:choose>
198 <xsl:when test="@accent='true'">
199 <xsl:text>\widehat{</xsl:text>
200 </xsl:when>
201 <xsl:otherwise>
202 <xsl:text>\hat{</xsl:text>
203 </xsl:otherwise>
204 </xsl:choose>
205 <xsl:apply-templates select="./*[1]"/><xsl:text>}</xsl:text>
206 </xsl:when>
207 <xsl:when test="translate($base,'&#x0220F;&#x02210;&#x022c2;&#x022c3;&#x02294;',
208 '&#x02211;&#x02211;&#x02211;&#x02211;&#x02211;')='&#x02211;'">
209 <!-- if $base is operator, such as
210 &#x02211; /sum L: summation operator
211 &#x0220F; /prod L: product operator
212 &#x02210; /coprod L: coproduct operator
213 &#x022c2; /bigcap
214 &#x022c3; /bigcup
215 &#x02294; /bigsqcup
216 -->
217 <xsl:apply-templates select="./*[1]"/>
218 <xsl:text>^{</xsl:text>
219 <xsl:apply-templates select="./*[$pos_over]"/>
220 <xsl:text>}</xsl:text>
221 </xsl:when>
222 <xsl:otherwise>
223 <xsl:text>\stackrel{</xsl:text>
224 <xsl:apply-templates select="./*[$pos_over]"/>
225 <xsl:text>}{</xsl:text>
226 <xsl:apply-templates select="./*[1]"/>
227 <xsl:text>}</xsl:text>
228 <!--
229 <xsl:text>\overset{</xsl:text>
230 <xsl:apply-templates select="./*[$pos_over]"/>
231 <xsl:text>}{</xsl:text>
232 <xsl:apply-templates select="./*[1]"/>
233 <xsl:text>}</xsl:text>-->
234 </xsl:otherwise>
235 </xsl:choose>
236 </xsl:template>
237
238 <xsl:template name="munder">
239 <xsl:param name="base"/>
240 <xsl:param name="under"/>
241 <xsl:choose>
242 <xsl:when test="$under='&#x00332;'"> <!-- UnderBar - combining low line -->
243 <xsl:text>\underline{</xsl:text>
244 <xsl:apply-templates select="./*[1]"/>
245 <xsl:text>}</xsl:text>
246 </xsl:when>
247 <xsl:when test="$under='&#x0FE38;'"> <!-- UnderBrace - under brace -->
248 <xsl:text>\underbrace{</xsl:text>
249 <xsl:apply-templates select="./*[1]"/>
250 <xsl:text>}</xsl:text>
251 </xsl:when>
252 <xsl:when test="$under='&#x02190;'"> <!--/leftarrow /gets A: =leftward arrow -->
253 <xsl:text>\underleftarrow{</xsl:text>
254 <xsl:apply-templates select="./*[1]"/>
255 <xsl:text>}</xsl:text>
256 </xsl:when>
257 <xsl:when test="$under='&#x02192;'"> <!--/rightarrow /to A: =rightward arrow -->
258 <xsl:text>\underrightarrow{</xsl:text>
259 <xsl:apply-templates select="./*[1]"/>
260 <xsl:text>}</xsl:text>
261 </xsl:when>
262 <xsl:when test="$under='&#x02194;'"> <!--/leftrightarrow A: l&r arrow -->
263 <xsl:text>\underleftrightarrow{</xsl:text>
264 <xsl:apply-templates select="./*[1]"/>
265 <xsl:text>}</xsl:text>
266 </xsl:when>
267 <xsl:when test="translate($base,'&#x0220F;&#x02210;&#x022c2;&#x022c3;&#x02294;',
268 '&#x02211;&#x02211;&#x02211;&#x02211;&#x02211;')='&#x02211;'">
269 <!-- if $base is operator, such as
270 &#x02211; /sum L: summation operator
271 &#x0220F; /prod L: product operator
272 &#x02210; /coprod L: coproduct operator
273 &#x022c2; /bigcap
274 &#x022c3; /bigcup
275 &#x02294; /bigsqcup
276 -->
277 <xsl:apply-templates select="./*[1]"/>
278 <xsl:text>_{</xsl:text>
279 <xsl:apply-templates select="./*[2]"/>
280 <xsl:text>}</xsl:text>
281 </xsl:when>
282 <xsl:otherwise>
283 <xsl:text>\underset{</xsl:text> <!-- Required AmsMath package -->
284 <xsl:apply-templates select="./*[2]"/>
285 <xsl:text>}{</xsl:text>
286 <xsl:apply-templates select="./*[1]"/>
287 <xsl:text>}</xsl:text>
288 </xsl:otherwise>
289 </xsl:choose>
290 </xsl:template>
291
292 <xsl:template match="m:msubsup">
293 <xsl:text>{</xsl:text>
294 <xsl:apply-templates select="./*[1]"/>
295 <xsl:text>}_{</xsl:text>
296 <xsl:apply-templates select="./*[2]"/>
297 <xsl:text>}^{</xsl:text>
298 <xsl:apply-templates select="./*[3]"/>
299 <xsl:text>}</xsl:text>
300 </xsl:template>
301
302 <xsl:template match="m:msup">
303 <xsl:text>{</xsl:text>
304 <xsl:apply-templates select="./*[1]"/>
305 <xsl:text>}^{</xsl:text>
306 <xsl:apply-templates select="./*[2]"/>
307 <xsl:text>}</xsl:text>
308 </xsl:template>
309
310 <xsl:template match="m:msub">
311 <xsl:text>{</xsl:text>
312 <xsl:apply-templates select="./*[1]"/>
313 <xsl:text>}_{</xsl:text>
314 <xsl:apply-templates select="./*[2]"/>
315 <xsl:text>}</xsl:text>
316 </xsl:template>
317
318 <xsl:template match="m:mmultiscripts" mode="mprescripts">
319 <xsl:for-each select="m:mprescripts/following-sibling::*">
320 <xsl:if test="position() mod 2 and local-name(.)!='none'">
321 <xsl:text>{}_{</xsl:text>
322 <xsl:apply-templates select="."/>
323 <xsl:text>}</xsl:text>
324 </xsl:if>
325 <xsl:if test="not(position() mod 2) and local-name(.)!='none'">
326 <xsl:text>{}^{</xsl:text>
327 <xsl:apply-templates select="."/>
328 <xsl:text>}</xsl:text>
329 </xsl:if>
330 </xsl:for-each>
331 <xsl:apply-templates select="./*[1]"/>
332 <xsl:for-each select="m:mprescripts/preceding-sibling::*[position()!=last()]">
333 <xsl:if test="position()>2 and local-name(.)!='none'">
334 <xsl:text>{}</xsl:text>
335 </xsl:if>
336 <xsl:if test="position() mod 2 and local-name(.)!='none'">
337 <xsl:text>_{</xsl:text>
338 <xsl:apply-templates select="."/>
339 <xsl:text>}</xsl:text>
340 </xsl:if>
341 <xsl:if test="not(position() mod 2) and local-name(.)!='none'">
342 <xsl:text>^{</xsl:text>
343 <xsl:apply-templates select="."/>
344 <xsl:text>}</xsl:text>
345 </xsl:if>
346 </xsl:for-each>
347 </xsl:template>
348
349 <xsl:template match="m:mmultiscripts">
350 <xsl:choose>
351 <xsl:when test="m:mprescripts">
352 <xsl:apply-templates select="." mode="mprescripts"/>
353 </xsl:when>
354 <xsl:otherwise>
355 <xsl:apply-templates select="./*[1]"/>
356 <xsl:for-each select="*[position()>1]">
357 <xsl:if test="position()>2 and local-name(.)!='none'">
358 <xsl:text>{}</xsl:text>
359 </xsl:if>
360 <xsl:if test="position() mod 2 and local-name(.)!='none'">
361 <xsl:text>_{</xsl:text>
362 <xsl:apply-templates select="."/>
363 <xsl:text>}</xsl:text>
364 </xsl:if>
365 <xsl:if test="not(position() mod 2) and local-name(.)!='none'">
366 <xsl:text>^{</xsl:text>
367 <xsl:apply-templates select="."/>
368 <xsl:text>}</xsl:text>
369 </xsl:if>
370 </xsl:for-each>
371 </xsl:otherwise>
372 </xsl:choose>
373 </xsl:template>
374
375 </xsl:stylesheet>